git.m6w6.name Git - m6w6/ext-ircclient/blob - config.m4

   1 PHP_ARG_WITH(ircclient, for ircclient support,
   2         [  --with-ircclient[=LIBIRCCLIENTDIR]   Include ircclient support])
   3
   4 if test "$PHP_IRCCLIENT" != "no"; then
   5         AC_PROG_EGREP
   6         AC_PROG_SED
   7
   8         AC_MSG_CHECKING([for libircclient/libircclient.h])
   9         for d in $PHP_IRCCLIENT /usr /usr/local /opt; do
  10                 if test -f $d/include/libircclient/libircclient.h; then
  11                         AC_MSG_RESULT([found in $d])
  12                         IRCCLIENT_DIR=$d
  13                         break
  14                 fi
  15         done
  16         if test "x$IRCCLIENT_DIR" = "x"; then
  17                 AC_MSG_ERROR([not found])
  18         fi
  19         if test -f "$IRCCLIENT_DIR/include/libircclient/libirc_params.h"; then
  20                 PHP_IRCCLIENT_LIBIRCCLIENT_VERSION_HIGH=`$EGREP "define LIBIRC_VERSION_HIGH" $IRCCLIENT_DIR/include/libircclient/libirc_params.h | $SED -e 's/[[^0-9\x]]//g'`
  21                 PHP_IRCCLIENT_LIBIRCCLIENT_VERSION_LOW=`$EGREP "define LIBIRC_VERSION_LOW" $IRCCLIENT_DIR/include/libircclient/libirc_params.h | $SED -e 's/[[^0-9\x]]//g'`
  22         else
  23                 PHP_IRCCLIENT_LIBIRCCLIENT_VERSION_HIGH=0
  24                 PHP_IRCCLIENT_LIBIRCCLIENT_VERSION_LOW=0
  25         fi
  26         AC_DEFINE_UNQUOTED([PHP_IRCCLIENT_LIBIRCCLIENT_VERSION_HIGH], [$PHP_IRCCLIENT_LIBIRCCLIENT_VERSION_HIGH], [ ])
  27         AC_DEFINE_UNQUOTED([PHP_IRCCLIENT_LIBIRCCLIENT_VERSION_LOW], [$PHP_IRCCLIENT_LIBIRCCLIENT_VERSION_LOW], [ ])
  28
  29         PHP_ADD_INCLUDE($IRCCLIENT_DIR/include)
  30         AC_CHECK_MEMBER([irc_callbacks_t.event_channel_notice], [
  31                 AC_DEFINE(HAVE_LIBIRCCLIENT_EVENT_CHANNEL_NOTICE, 1, [ ])
  32         ], [], [
  33                 [#include <libircclient/libircclient.h>]
  34         ])
  35         PHP_CHECK_LIBRARY(ircclient, irc_create_session,
  36         [
  37                 PHP_ADD_LIBRARY_WITH_PATH(ircclient, $IRCCLIENT_DIR/lib, IRCCLIENT_SHARED_LIBADD)
  38                 AC_DEFINE(HAVE_LIBIRCCLIENT,1,[ ])
  39         ],[
  40                 AC_MSG_ERROR([libircclient not found])
  41         ],[
  42                 -L$IRCCLIENT_DIR/lib -lm
  43         ])
  44         PHP_SUBST([IRCCLIENT_SHARED_LIBADD])
  45         PHP_NEW_EXTENSION([ircclient], [php_ircclient.c], [$ext_shared])
  46 fi