git.m6w6.name Git - m6w6/libmemcached/blob - test/CMakeLists.txt

   1 if(NOT BUILD_TESTING OR NOT CMAKE_PROJECT_NAME STREQUAL PROJECT_NAME)
   2     return()
   3 endif()
   4
   5 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMake")
   6 include(Catch)
   7 include(CheckTbb)
   8
   9 if(NOT MEMCACHED_BINARY)
  10     message(SEND_ERROR "Could not find memcached(1) binary")
  11     set(ENV{INVALID_CONFIGURATION} 1)
  12 endif()
  13
  14 check_decl(pipe2 unistd.h)
  15 check_decl(SOCK_NONBLOCK sys/socket.h)
  16 check_decl(SOCK_CLOEXEC sys/socket.h)
  17 check_decl(waitid sys/wait.h)
  18 if(HAVE_WAITID)
  19     check_compiles(HAVE_WAITID_NOWAIT "siginfo_t s; waitid(P_ALL, 0, &s, WNOWAIT|WEXITED);" sys/types.h sys/wait.h)
  20 endif()
  21
  22 file(GLOB_RECURSE TESTING_SRC RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} *.cpp)
  23 set(TESTING_ROOT ${CMAKE_CURRENT_BINARY_DIR})
  24 set_source_files_properties(main.cpp PROPERTIES SKIP_UNITY_BUILD_INCLUSION ON)
  25 configure_file(conf.h.in conf.h @ONLY)
  26 add_executable(runtests ${TESTING_SRC})
  27 set_target_properties(runtests PROPERTIES CXX_STANDARD 17)
  28 target_include_directories(runtests PRIVATE
  29         ${CMAKE_SOURCE_DIR}
  30         ${CMAKE_BINARY_DIR}
  31         ${CMAKE_SOURCE_DIR}/src
  32         ${CMAKE_BINARY_DIR}/src)
  33 target_link_libraries(runtests PRIVATE libhashkit libmemcachedinternal libmemcachedutil)
  34
  35 check_tbb()
  36 if(HAVE_TBB)
  37     target_link_libraries(runtests PRIVATE ${LIBTBB})
  38 endif()
  39
  40 add_dependencies(runtests ${CLIENTS})
  41 if(HAVE_MEMASLAP)
  42     add_dependencies(runtests memaslap)
  43 endif()
  44
  45 catch_discover_tests(runtests
  46         TEST_SPEC "lib*")
  47 catch_discover_tests(runtests
  48         TEST_SPEC "hashkit*")
  49 catch_discover_tests(runtests
  50         TEST_SPEC "memcached*")
  51 catch_discover_tests(runtests
  52         TEST_SPEC "bin/*")