git.m6w6.name Git - m6w6/libmemcached/blob - test/CMakeLists.txt

   1 if(NOT BUILD_TESTING OR NOT CMAKE_PROJECT_NAME STREQUAL PROJECT_NAME)
   2     return()
   3 endif()
   4
   5 configure_init(${CMAKE_CURRENT_BINARY_DIR}/conf.h)
   6 configure_append("#define MEMCACHED_BINARY getenv_else(\"MEMCACHED_BINARY\", \"@MEMCACHED_BINARY@\")\n")
   7 configure_define_string(TESTING_ROOT)
   8 configure_define_string(SOURCES_ROOT)
   9 configure_define_string(LIBMEMCACHED_WITH_SASL_PWDB)
  10 configure_define_string(LIBMEMCACHED_WITH_SASL_CONF)
  11
  12 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMake")
  13 include(Catch)
  14
  15 add_definitions(-D_GNU_SOURCE)
  16 set(CMAKE_REQUIRED_DEFINITIONS -D_GNU_SOURCE)
  17 check_symbol(pipe2 unistd.h)
  18 check_symbol(SOCK_NONBLOCK sys/socket.h)
  19 check_symbol(SOCK_CLOEXEC sys/socket.h)
  20 check_include(sys/wait.h)
  21 check_symbol(waitid sys/wait.h)
  22 if(HAVE_WAITID)
  23     check_c_source("
  24             #include <sys/types.h>
  25             #include <sys/wait.h>
  26             int main() {
  27                 siginfo_t s;
  28                 return waitid(P_ALL, 0, &s, WNOWAIT|WEXITED);
  29             }"
  30             HAVE_WAITID_NOWAIT
  31     )
  32 endif()
  33 if(NOT HAVE_SYS_WAIT_H)
  34     message(SEND_ERROR "Could not find header <sys/wait.h>")
  35     set(ENV{INVALID_CONFIGURATION} 1)
  36 endif()
  37
  38 # memcached(1)
  39 if(NOT MEMCACHED_BINARY)
  40     find_package(Memcached)
  41     set(MEMCACHED_BINARY ${MEMCACHED_EXECUTABLE})
  42 endif()
  43 if(NOT MEMCACHED_BINARY)
  44     message(SEND_ERROR "Could not find memcached(1) binary")
  45     set(ENV{INVALID_CONFIGURATION} 1)
  46 endif()
  47
  48 file(GLOB_RECURSE TESTING_SRC RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} *.cpp)
  49 set(TESTING_ROOT "${CMAKE_CURRENT_BINARY_DIR}")
  50 set(SOURCES_ROOT "${CMAKE_SOURCE_DIR}")
  51 set_source_files_properties(main.cpp PROPERTIES SKIP_UNITY_BUILD_INCLUSION ON)
  52 add_executable(runtests ${TESTING_SRC})
  53 set_target_properties(runtests PROPERTIES CXX_STANDARD 17)
  54 target_include_directories(runtests PRIVATE
  55         ${CMAKE_SOURCE_DIR}
  56         ${CMAKE_BINARY_DIR}
  57         ${CMAKE_SOURCE_DIR}/src
  58         ${CMAKE_BINARY_DIR}/src)
  59 target_link_libraries(runtests PRIVATE libhashkit libmemcachedinternal libmemcachedutil)
  60
  61 # parallelism
  62 if(NOT (thread IN_LIST ENABLE_SANITIZERS))
  63     include(CheckCpp17Parallelism)
  64     if(HAVE_CPP17_PARALLELISM)
  65         target_link_libraries(runtests PRIVATE cpp17::parallelism)
  66     endif()
  67 endif()
  68
  69 add_dependencies(runtests ${CLIENTS})
  70 if(TARGET memaslap)
  71     configure_set(HAVE_MEMASLAP 1)
  72     add_dependencies(runtests memaslap)
  73 endif()
  74
  75 configure_file(${CONFIGURE_FILE_IN} ${CONFIGURE_FILE_OUT} @ONLY)
  76
  77 catch_discover_tests(runtests TEST_SPEC "lib*,hashkit*,memcached*,bin/*")