git.m6w6.name Git - m6w6/libmemcached/blob - test/CMakeLists.txt

   1 if(NOT BUILD_TESTING OR NOT CMAKE_PROJECT_NAME STREQUAL PROJECT_NAME)
   2     return()
   3 endif()
   4
   5 include(CMake/Catch.cmake)
   6
   7 if(NOT MEMCACHED_BINARY)
   8     message(SEND_ERROR "Could not find memcached(1) binary")
   9     set(ENV{INVALID_CONFIGURATION} 1)
  10 endif()
  11
  12 check_decl(pipe2 unistd.h)
  13 check_decl(SOCK_NONBLOCK sys/socket.h)
  14 check_decl(SOCK_CLOEXEC sys/socket.h)
  15
  16 check_header(execution)
  17
  18 # TBBConfig only sets TBB_FOUND to FALSE
  19 set(TBB_FOUND TRUE)
  20 set(TBB_FIND_RELEASE_ONLY TRUE)
  21 find_package(TBB)
  22
  23 file(GLOB_RECURSE TESTING_SRC RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} *.cpp)
  24 set(TESTING_ROOT ${CMAKE_CURRENT_BINARY_DIR})
  25 set_source_files_properties(main.cpp PROPERTIES SKIP_UNITY_BUILD_INCLUSION ON)
  26 configure_file(conf.h.in conf.h @ONLY)
  27 add_executable(runtests ${TESTING_SRC})
  28 set_target_properties(runtests PROPERTIES CXX_STANDARD 17)
  29 target_include_directories(runtests PRIVATE
  30         ${CMAKE_SOURCE_DIR}
  31         ${CMAKE_BINARY_DIR}
  32         ${CMAKE_SOURCE_DIR}/src
  33         ${CMAKE_BINARY_DIR}/src)
  34 target_link_libraries(runtests PRIVATE libhashkit libmemcachedinternal libmemcachedutil)
  35 if(TBB_FOUND AND HAVE_EXECUTION)
  36     target_link_libraries(runtests PRIVATE TBB::tbb)
  37 else()
  38     set(HAVE_EXECUTION 0)
  39 endif()
  40 add_dependencies(runtests ${CLIENTS})
  41 if(HAVE_MEMASLAP)
  42     add_dependencies(runtests memaslap)
  43 endif()
  44
  45 catch_discover_tests(runtests
  46         TEST_SPEC "lib*")
  47 catch_discover_tests(runtests
  48         TEST_SPEC "hashkit*")
  49 catch_discover_tests(runtests
  50         TEST_SPEC "memcached*")
  51 catch_discover_tests(runtests
  52         TEST_SPEC "bin/*")