git.m6w6.name Git - m6w6/libmemcached/blob - test/CMakeLists.txt

   1 if(NOT BUILD_TESTING OR NOT CMAKE_PROJECT_NAME STREQUAL PROJECT_NAME)
   2     return()
   3 endif()
   4
   5 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMake")
   6 include(Catch)
   7 include(CheckTbb)
   8
   9 check_decl(pipe2 unistd.h)
  10 check_decl(SOCK_NONBLOCK sys/socket.h)
  11 check_decl(SOCK_CLOEXEC sys/socket.h)
  12 check_header(sys/wait.h)
  13 check_decl(waitid sys/wait.h)
  14 if(HAVE_WAITID)
  15     check_compiles(HAVE_WAITID_NOWAIT "
  16             siginfo_t s;
  17             waitid(P_ALL, 0, &s, WNOWAIT|WEXITED);"
  18             sys/types.h sys/wait.h)
  19 endif()
  20 if(NOT HAVE_SYS_WAIT_H)
  21     message(SEND_ERROR "Could not find header <sys/wait.h>")
  22     set(ENV{INVALID_CONFIGURATION} 1)
  23 endif()
  24
  25 # parallelism
  26 if(NOT (thread IN_LIST ENABLE_SANITIZERS))
  27     check_tbb()
  28 endif()
  29
  30 # memcached(1)
  31 if(NOT MEMCACHED_BINARY)
  32     find_package(Memcached)
  33     set(MEMCACHED_BINARY ${MEMCACHED_EXECUTABLE})
  34 endif()
  35 if(NOT MEMCACHED_BINARY)
  36     message(SEND_ERROR "Could not find memcached(1) binary")
  37     set(ENV{INVALID_CONFIGURATION} 1)
  38 endif()
  39
  40 file(GLOB_RECURSE TESTING_SRC RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} *.cpp)
  41 set(TESTING_ROOT ${CMAKE_CURRENT_BINARY_DIR})
  42 set(SOURCES_ROOT ${CMAKE_SOURCE_DIR})
  43 set_source_files_properties(main.cpp PROPERTIES SKIP_UNITY_BUILD_INCLUSION ON)
  44 add_executable(runtests ${TESTING_SRC})
  45 set_target_properties(runtests PROPERTIES CXX_STANDARD 17)
  46 target_include_directories(runtests PRIVATE
  47         ${CMAKE_SOURCE_DIR}
  48         ${CMAKE_BINARY_DIR}
  49         ${CMAKE_SOURCE_DIR}/src
  50         ${CMAKE_BINARY_DIR}/src)
  51 target_link_libraries(runtests PRIVATE libhashkit libmemcachedinternal libmemcachedutil)
  52
  53 if(HAVE_TBB)
  54     target_link_libraries(runtests PRIVATE ${LIBTBB})
  55 endif()
  56
  57 add_dependencies(runtests ${CLIENTS})
  58 if(TARGET memaslap)
  59     set(HAVE_MEMASLAP 1)
  60     add_dependencies(runtests memaslap)
  61 endif()
  62
  63 configure_file(conf.h.in conf.h @ONLY)
  64
  65 catch_discover_tests(runtests
  66         TEST_SPEC "lib*")
  67 catch_discover_tests(runtests
  68         TEST_SPEC "hashkit*")
  69 catch_discover_tests(runtests
  70         TEST_SPEC "memcached*")
  71 catch_discover_tests(runtests
  72         TEST_SPEC "bin/*")