git.m6w6.name Git - m6w6/libmemcached/blob - src/libmemcached/CMakeLists.txt

   1
   2 find_package(FLEX)
   3 find_package(BISON 2.3)
   4
   5 if("${BISON_VERSION}" VERSION_GREATER_EQUAL 3.0)
   6         set(BISON_WARNINGS -Wno-deprecated)
   7 endif()
   8
   9 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/csl)
  10 bison_target(CSL_PARSER csl/parser.yy ${CMAKE_CURRENT_BINARY_DIR}/csl/parser.cc
  11         DEFINES_FILE ${CMAKE_CURRENT_BINARY_DIR}/csl/parser.h
  12         COMPILE_FLAGS ${BISON_WARNINGS}
  13         )
  14 set_source_files_properties(${BISON_CSL_PARSER_OUTPUTS} PROPERTIES SKIP_UNITY_BUILD_INCLUSION ON)
  15 flex_target(CSL_SCANNER csl/scanner.l ${CMAKE_CURRENT_BINARY_DIR}/csl/scanner.cc
  16         DEFINES_FILE ${CMAKE_CURRENT_BINARY_DIR}/csl/scanner.h
  17         )
  18 set_source_files_properties(${FLEX_CSL_SCANNER_OUTPUTS} PROPERTIES SKIP_UNITY_BUILD_INCLUSION ON)
  19 add_flex_bison_dependency(CSL_SCANNER CSL_PARSER)
  20
  21 set(LIBMEMCACHED_SOURCES
  22         csl/context.cc
  23         ${BISON_CSL_PARSER_OUTPUTS}
  24         ${FLEX_CSL_SCANNER_OUTPUTS}
  25         allocators.cc
  26         analyze.cc
  27         array.c
  28         auto.cc
  29         backtrace.cc
  30         behavior.cc
  31         byteorder.cc
  32         callback.cc
  33         common.h
  34         connect.cc
  35         delete.cc
  36         do.cc
  37         dump.cc
  38         encoding_key.cc
  39         error.cc
  40         exist.cc
  41         fetch.cc
  42         flag.cc
  43         flush.cc
  44         flush_buffers.cc
  45         get.cc
  46         hash.cc
  47         hosts.cc
  48         initialize_query.cc
  49         instance.cc
  50         io.cc
  51         key.cc
  52         memcached.cc
  53         namespace.cc
  54         options.cc
  55         parse.cc
  56         poll.cc
  57         purge.cc
  58         quit.cc
  59         response.cc
  60         result.cc
  61         sasl.cc
  62         server.cc
  63         server_list.cc
  64         stats.cc
  65         storage.cc
  66         strerror.cc
  67         string.cc
  68         touch.cc
  69         udp.cc
  70         verbosity.cc
  71         version.cc
  72         virtual_bucket.c)
  73
  74 check_cxx_compiler_flag(-Wno-deprecated-register W_NO_DEPRECATED_REGISTER)
  75
  76 if(W_NO_DEPRECATED_REGISTER)
  77         set_source_files_properties(
  78                 ${FLEX_CSL_SCANNER_OUTPUTS}
  79                 ${BISON_CSL_PARSER_OUTPUTS}
  80                 PROPERTIES COMPILE_OPTIONS -Wno-deprecated-register
  81         )
  82 endif()
  83
  84 add_library(libmemcached SHARED
  85         ${LIBMEMCACHED_SOURCES})
  86 add_library(memcached ALIAS libmemcached)
  87 set_target_properties(libmemcached PROPERTIES
  88         LIBRARY_OUTPUT_NAME memcached
  89         LIBRARY_OUTPUT_NAME_DEBUG memcached-dbg
  90         SOVERSION ${LIBMEMCACHED_SO_VERSION}
  91         VERSION v${LIBMEMCACHED_VERSION})
  92 target_compile_definitions(libmemcached PRIVATE -DBUILDING_LIBMEMCACHED)
  93 target_link_libraries(libmemcached PUBLIC libhashkit Threads::Threads ${CMAKE_DL_LIBS} ${Backtrace_LIBRARIES})
  94 if(LIBSASL_FOUND)
  95     if(PKG_CONFIG_FOUND)
  96         target_link_libraries(libmemcached PUBLIC PkgConfig::LIBSASL)
  97     else()
  98         target_link_libraries(libmemcached PUBLIC ${LIBSASL_LIBRARIES})
  99         target_include_directories(libmemcached PUBLIC ${LIBSASL_INCLUDEDIR})
 100     endif()
 101 endif()
 102 target_include_directories(libmemcached PRIVATE ${Backtrace_INCLUDE_DIR})
 103 target_include_directories(libmemcached PRIVATE
 104         ${CMAKE_SOURCE_DIR}/src
 105         ${CMAKE_BINARY_DIR}/src
 106         ${CMAKE_BINARY_DIR})
 107 target_include_directories(libmemcached PUBLIC
 108         $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/include>
 109         $<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/include>
 110         $<INSTALL_INTERFACE:include>)
 111
 112 enable_dtrace_for(libmemcached libmemcached_probes.d dtrace_probes.h)
 113
 114 install(TARGETS libmemcached EXPORT libmemcached-targets
 115         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
 116 export(EXPORT libmemcached-targets NAMESPACE libmemcached::)
 117 install(EXPORT libmemcached-targets NAMESPACE libmemcached:: DESTINATION ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/cmake)
 118
 119 install_public_headers(
 120         libmemcached
 121
 122         memcached.h
 123         memcached.hpp
 124         util.h
 125         )
 126
 127 add_library(libmemcachedinternal STATIC
 128         ${LIBMEMCACHED_SOURCES})
 129 add_library(memcachedinternal ALIAS libmemcachedinternal)
 130 set_target_properties(libmemcachedinternal PROPERTIES LIBRARY_OUTPUT_NAME memcachedinternal)
 131 target_compile_definitions(libmemcachedinternal PRIVATE -DBUILDING_LIBMEMCACHEDINTERNAL)
 132 target_link_libraries(libmemcachedinternal PUBLIC libhashkit Threads::Threads ${LIBSASL_LIBRARIES} ${CMAKE_DL_LIBS} ${Backtrace_LIBRARIES})
 133 target_include_directories(libmemcachedinternal PRIVATE ${Backtrace_INCLUDE_DIR})
 134 target_include_directories(libmemcachedinternal PRIVATE
 135         ${CMAKE_SOURCE_DIR}/src
 136         ${CMAKE_BINARY_DIR}/src
 137         ${CMAKE_BINARY_DIR})
 138 target_include_directories(libmemcachedinternal PUBLIC ${LIBSASL_INCLUDEDIR})
 139 target_include_directories(libmemcachedinternal PUBLIC
 140         $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/include>
 141         $<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/include>
 142         $<INSTALL_INTERFACE:include>)
 143
 144 enable_dtrace_for(libmemcachedinternal libmemcached_probes.d dtrace_probes.h)
 145
 146 # let libmemcached depend on libmemcachedinternal to ensure that they do not
 147 # compete for the same generated dependencies
 148 add_dependencies(libmemcached libmemcachedinternal)