git.m6w6.name Git - m6w6/libmemcached/blob - src/libmemcached/CMakeLists.txt

   1
   2 find_package(FLEX)
   3 find_package(BISON 2.3)
   4
   5 if("${BISON_VERSION}" VERSION_GREATER_EQUAL 3.0)
   6         set(BISON_WARNINGS -Wno-deprecated)
   7 endif()
   8
   9 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/csl)
  10 bison_target(CSL_PARSER csl/parser.yy ${CMAKE_CURRENT_BINARY_DIR}/csl/parser.cc
  11         DEFINES_FILE ${CMAKE_CURRENT_BINARY_DIR}/csl/parser.h
  12         COMPILE_FLAGS ${BISON_WARNINGS}
  13         )
  14 set_source_files_properties(${BISON_CSL_PARSER_OUTPUTS} PROPERTIES SKIP_UNITY_BUILD_INCLUSION ON)
  15 if(NOT HAVE_UNISTD_H)
  16         set(FLEX_FLAGS --nounistd)
  17 endif()
  18 flex_target(CSL_SCANNER csl/scanner.l ${CMAKE_CURRENT_BINARY_DIR}/csl/scanner.cc
  19         DEFINES_FILE ${CMAKE_CURRENT_BINARY_DIR}/csl/scanner.h
  20         COMPILE_FLAGS "${FLEX_FLAGS}"
  21         )
  22 set_source_files_properties(${FLEX_CSL_SCANNER_OUTPUTS} PROPERTIES SKIP_UNITY_BUILD_INCLUSION ON)
  23 add_flex_bison_dependency(CSL_SCANNER CSL_PARSER)
  24
  25 set(LIBMEMCACHED_SOURCES
  26         csl/context.cc
  27         ${BISON_CSL_PARSER_OUTPUTS}
  28         ${FLEX_CSL_SCANNER_OUTPUTS}
  29         allocators.cc
  30         analyze.cc
  31         array.c
  32         auto.cc
  33         backtrace.cc
  34         behavior.cc
  35         byteorder.cc
  36         callback.cc
  37         common.h
  38         connect.cc
  39         delete.cc
  40         do.cc
  41         dump.cc
  42         encoding_key.cc
  43         error.cc
  44         exist.cc
  45         fetch.cc
  46         flag.cc
  47         flush.cc
  48         flush_buffers.cc
  49         get.cc
  50         hash.cc
  51         hosts.cc
  52         initialize_query.cc
  53         instance.cc
  54         io.cc
  55         key.cc
  56         memcached.cc
  57         namespace.cc
  58         options.cc
  59         parse.cc
  60         purge.cc
  61         quit.cc
  62         response.cc
  63         result.cc
  64         sasl.cc
  65         server.cc
  66         server_list.cc
  67         stats.cc
  68         storage.cc
  69         strerror.cc
  70         string.cc
  71         touch.cc
  72         udp.cc
  73         verbosity.cc
  74         version.cc
  75         virtual_bucket.c)
  76
  77 check_cxx_compiler_flag(-Wno-deprecated-register W_NO_DEPRECATED_REGISTER)
  78
  79 if(W_NO_DEPRECATED_REGISTER)
  80         set_source_files_properties(
  81                 ${FLEX_CSL_SCANNER_OUTPUTS}
  82                 ${BISON_CSL_PARSER_OUTPUTS}
  83                 PROPERTIES COMPILE_OPTIONS -Wno-deprecated-register
  84         )
  85 endif()
  86
  87 add_library(libmemcached SHARED
  88         ${LIBMEMCACHED_SOURCES})
  89 add_library(memcached ALIAS libmemcached)
  90 set_target_properties(libmemcached PROPERTIES
  91         CXX_STANDARD ${CXX_STANDARD}
  92         LIBRARY_OUTPUT_NAME memcached
  93         LIBRARY_OUTPUT_NAME_DEBUG memcached-dbg
  94         SOVERSION ${LIBMEMCACHED_SO_VERSION})
  95 target_compile_definitions(libmemcached PRIVATE -DBUILDING_LIBMEMCACHED)
  96 target_link_libraries(libmemcached PUBLIC libhashkit Threads::Threads ${CMAKE_DL_LIBS})
  97 target_link_libraries(libmemcached PRIVATE p9y)
  98 if(MSVC)
  99     target_link_libraries(libmemcached PUBLIC wsock32 ws2_32)
 100 endif()
 101 if(HAVE_BACKTRACE)
 102     target_link_libraries(libmemcached PUBLIC ${BACKTRACE})
 103 endif()
 104 if(HAVE_LIBSASL)
 105     target_link_libraries(libmemcached PUBLIC ${LIBSASL})
 106 endif()
 107 if(CMAKE_CXX_COMPILER_ID STREQUAL "SunPro")
 108     # see https://docs.oracle.com/cd/E77782_01/html/E77789/bkamq.html#OSSCPgrxeu
 109     target_link_libraries(libmemcached INTERFACE stdc++ gcc_s CrunG3 c)
 110 endif()
 111 target_include_directories(libmemcached PRIVATE
 112         ${CMAKE_SOURCE_DIR}/src
 113         ${CMAKE_BINARY_DIR}/src
 114         ${CMAKE_BINARY_DIR})
 115 target_include_directories(libmemcached PUBLIC
 116         $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/include>
 117         $<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/include>
 118         $<INSTALL_INTERFACE:include>)
 119
 120 enable_dtrace_for(libmemcached libmemcached_probes.d dtrace_probes.h)
 121
 122 install(TARGETS libmemcached EXPORT libmemcached-targets
 123         RUNTIME COMPONENT bin DESTINATION ${CMAKE_INSTALL_BINDIR}
 124         LIBRARY COMPONENT lib DESTINATION ${CMAKE_INSTALL_LIBDIR}
 125         ${TARGET_NAMELINK_COMPONENT}
 126         )
 127 export(EXPORT libmemcached-targets NAMESPACE libmemcached::)
 128 install(EXPORT libmemcached-targets NAMESPACE libmemcached::
 129         COMPONENT dev
 130         DESTINATION ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/cmake)
 131
 132 install_public_headers(
 133         libmemcached
 134
 135         memcached.h
 136         memcached.hpp
 137         util.h
 138         )
 139
 140 add_library(libmemcachedinternal STATIC
 141         ${LIBMEMCACHED_SOURCES})
 142 add_library(memcachedinternal ALIAS libmemcachedinternal)
 143 set_target_properties(libmemcachedinternal PROPERTIES CXX_STANDARD ${CXX_STANDARD} LIBRARY_OUTPUT_NAME memcachedinternal)
 144 target_compile_definitions(libmemcachedinternal PRIVATE -DBUILDING_LIBMEMCACHEDINTERNAL)
 145 target_link_libraries(libmemcachedinternal PUBLIC libhashkit Threads::Threads ${CMAKE_DL_LIBS})
 146 target_link_libraries(libmemcachedinternal PRIVATE p9y)
 147 if(MSVC)
 148     target_link_libraries(libmemcached PUBLIC wsock32 ws2_32)
 149 endif()
 150 if(HAVE_LIBSASL)
 151     target_link_libraries(libmemcachedinternal PUBLIC ${LIBSASL})
 152 endif()
 153 if(HAVE_BACKTRACE)
 154     target_link_libraries(libmemcachedinternal PUBLIC ${BACKTRACE})
 155 endif()
 156 target_include_directories(libmemcachedinternal PRIVATE
 157         ${CMAKE_SOURCE_DIR}/src
 158         ${CMAKE_BINARY_DIR}/src
 159         ${CMAKE_BINARY_DIR})
 160 target_include_directories(libmemcachedinternal PUBLIC
 161         $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/include>
 162         $<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/include>
 163         $<INSTALL_INTERFACE:include>)
 164
 165 enable_dtrace_for(libmemcachedinternal libmemcached_probes.d dtrace_probes.h)
 166
 167 # let libmemcached depend on libmemcachedinternal to ensure that they do not
 168 # compete for the same generated dependencies
 169 add_dependencies(libmemcached libmemcachedinternal)