git.m6w6.name Git - m6w6/libmemcached/blob - src/libmemcached/CMakeLists.txt

   1
   2 find_package(FLEX)
   3 find_package(BISON 2.3)
   4
   5 if("${BISON_VERSION}" VERSION_GREATER_EQUAL 3.0)
   6         set(BISON_WARNINGS -Wno-deprecated)
   7 endif()
   8
   9 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/csl)
  10 bison_target(CSL_PARSER csl/parser.yy ${CMAKE_CURRENT_BINARY_DIR}/csl/parser.cc
  11         DEFINES_FILE ${CMAKE_CURRENT_BINARY_DIR}/csl/parser.h
  12         COMPILE_FLAGS ${BISON_WARNINGS}
  13         )
  14 set_source_files_properties(${BISON_CSL_PARSER_OUTPUTS} PROPERTIES SKIP_UNITY_BUILD_INCLUSION ON)
  15 flex_target(CSL_SCANNER csl/scanner.l ${CMAKE_CURRENT_BINARY_DIR}/csl/scanner.cc
  16         DEFINES_FILE ${CMAKE_CURRENT_BINARY_DIR}/csl/scanner.h
  17         )
  18 set_source_files_properties(${FLEX_CSL_SCANNER_OUTPUTS} PROPERTIES SKIP_UNITY_BUILD_INCLUSION ON)
  19 add_flex_bison_dependency(CSL_SCANNER CSL_PARSER)
  20
  21 set(LIBMEMCACHED_SOURCES
  22         csl/context.cc
  23         ${BISON_CSL_PARSER_OUTPUTS}
  24         ${FLEX_CSL_SCANNER_OUTPUTS}
  25         allocators.cc
  26         analyze.cc
  27         array.c
  28         auto.cc
  29         backtrace.cc
  30         behavior.cc
  31         byteorder.cc
  32         callback.cc
  33         common.h
  34         connect.cc
  35         delete.cc
  36         do.cc
  37         dump.cc
  38         encoding_key.cc
  39         error.cc
  40         exist.cc
  41         fetch.cc
  42         flag.cc
  43         flush.cc
  44         flush_buffers.cc
  45         get.cc
  46         hash.cc
  47         hosts.cc
  48         initialize_query.cc
  49         instance.cc
  50         io.cc
  51         key.cc
  52         memcached.cc
  53         namespace.cc
  54         options.cc
  55         parse.cc
  56         poll.cc
  57         purge.cc
  58         quit.cc
  59         response.cc
  60         result.cc
  61         sasl.cc
  62         server.cc
  63         server_list.cc
  64         stats.cc
  65         storage.cc
  66         strerror.cc
  67         string.cc
  68         touch.cc
  69         udp.cc
  70         verbosity.cc
  71         version.cc
  72         virtual_bucket.c)
  73
  74 check_cxx_compiler_flag(-Wno-deprecated-register W_NO_DEPRECATED_REGISTER)
  75
  76 if(W_NO_DEPRECATED_REGISTER)
  77         set_source_files_properties(
  78                 ${FLEX_CSL_SCANNER_OUTPUTS}
  79                 ${BISON_CSL_PARSER_OUTPUTS}
  80                 PROPERTIES COMPILE_OPTIONS -Wno-deprecated-register
  81         )
  82 endif()
  83
  84 add_library(libmemcached SHARED
  85         ${LIBMEMCACHED_SOURCES})
  86 add_library(memcached ALIAS libmemcached)
  87 set_target_properties(libmemcached PROPERTIES
  88         CXX_STANDARD ${CXX_STANDARD}
  89         LIBRARY_OUTPUT_NAME memcached
  90         LIBRARY_OUTPUT_NAME_DEBUG memcached-dbg
  91         SOVERSION ${LIBMEMCACHED_SO_VERSION})
  92 target_compile_definitions(libmemcached PRIVATE -DBUILDING_LIBMEMCACHED)
  93 target_link_libraries(libmemcached PUBLIC libhashkit Threads::Threads ${CMAKE_DL_LIBS})
  94 if(HAVE_BACKTRACE)
  95     target_link_libraries(libmemcached PUBLIC ${BACKTRACE})
  96 endif()
  97 if(HAVE_LIBSASL)
  98     target_link_libraries(libmemcached PUBLIC ${LIBSASL})
  99 endif()
 100 if(CMAKE_CXX_COMPILER_ID STREQUAL "SunPro")
 101     # see https://docs.oracle.com/cd/E77782_01/html/E77789/bkamq.html#OSSCPgrxeu
 102     target_link_libraries(libmemcached INTERFACE stdc++ gcc_s CrunG3 c)
 103 endif()
 104 target_include_directories(libmemcached PRIVATE
 105         ${CMAKE_SOURCE_DIR}/src
 106         ${CMAKE_BINARY_DIR}/src
 107         ${CMAKE_BINARY_DIR})
 108 target_include_directories(libmemcached PUBLIC
 109         $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/include>
 110         $<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/include>
 111         $<INSTALL_INTERFACE:include>)
 112
 113 enable_dtrace_for(libmemcached libmemcached_probes.d dtrace_probes.h)
 114
 115 install(TARGETS libmemcached EXPORT libmemcached-targets
 116         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
 117 export(EXPORT libmemcached-targets NAMESPACE libmemcached::)
 118 install(EXPORT libmemcached-targets NAMESPACE libmemcached:: DESTINATION ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/cmake)
 119
 120 install_public_headers(
 121         libmemcached
 122
 123         memcached.h
 124         memcached.hpp
 125         util.h
 126         )
 127
 128 add_library(libmemcachedinternal STATIC
 129         ${LIBMEMCACHED_SOURCES})
 130 add_library(memcachedinternal ALIAS libmemcachedinternal)
 131 set_target_properties(libmemcachedinternal PROPERTIES CXX_STANDARD ${CXX_STANDARD} LIBRARY_OUTPUT_NAME memcachedinternal)
 132 target_compile_definitions(libmemcachedinternal PRIVATE -DBUILDING_LIBMEMCACHEDINTERNAL)
 133 target_link_libraries(libmemcachedinternal PUBLIC libhashkit Threads::Threads ${CMAKE_DL_LIBS})
 134 if(HAVE_LIBSASL)
 135     target_link_libraries(libmemcachedinternal PUBLIC ${LIBSASL})
 136 endif()
 137 if(HAVE_BACKTRACE)
 138     target_link_libraries(libmemcachedinternal PUBLIC ${BACKTRACE})
 139 endif()
 140 target_include_directories(libmemcachedinternal PRIVATE
 141         ${CMAKE_SOURCE_DIR}/src
 142         ${CMAKE_BINARY_DIR}/src
 143         ${CMAKE_BINARY_DIR})
 144 target_include_directories(libmemcachedinternal PUBLIC
 145         $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/include>
 146         $<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/include>
 147         $<INSTALL_INTERFACE:include>)
 148
 149 enable_dtrace_for(libmemcachedinternal libmemcached_probes.d dtrace_probes.h)
 150
 151 # let libmemcached depend on libmemcachedinternal to ensure that they do not
 152 # compete for the same generated dependencies
 153 add_dependencies(libmemcached libmemcachedinternal)