git.m6w6.name Git - m6w6/libmemcached/blob - src/libmemcached/CMakeLists.txt

   1
   2 find_package(FLEX)
   3 find_package(BISON 2.3)
   4
   5 if("${BISON_VERSION}" VERSION_GREATER_EQUAL 3.0)
   6         set(BISON_WARNINGS -Wno-deprecated)
   7 endif()
   8
   9 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/csl)
  10 bison_target(CSL_PARSER csl/parser.yy ${CMAKE_CURRENT_BINARY_DIR}/csl/parser.cc
  11         DEFINES_FILE ${CMAKE_CURRENT_BINARY_DIR}/csl/parser.h
  12         COMPILE_FLAGS ${BISON_WARNINGS}
  13         )
  14 set_source_files_properties(${BISON_CSL_PARSER_OUTPUTS} PROPERTIES SKIP_UNITY_BUILD_INCLUSION ON)
  15 if(NOT HAVE_UNISTD_H)
  16         set(FLEX_FLAGS --nounistd)
  17 endif()
  18 flex_target(CSL_SCANNER csl/scanner.l ${CMAKE_CURRENT_BINARY_DIR}/csl/scanner.cc
  19         DEFINES_FILE ${CMAKE_CURRENT_BINARY_DIR}/csl/scanner.h
  20         COMPILE_FLAGS "${FLEX_FLAGS}"
  21         )
  22 set_source_files_properties(${FLEX_CSL_SCANNER_OUTPUTS} PROPERTIES SKIP_UNITY_BUILD_INCLUSION ON)
  23 add_flex_bison_dependency(CSL_SCANNER CSL_PARSER)
  24
  25 set(LIBMEMCACHED_SOURCES
  26         csl/context.cc
  27         ${BISON_CSL_PARSER_OUTPUTS}
  28         ${FLEX_CSL_SCANNER_OUTPUTS}
  29         allocators.cc
  30         analyze.cc
  31         array.c
  32         auto.cc
  33         backtrace.cc
  34         behavior.cc
  35         byteorder.cc
  36         callback.cc
  37         common.h
  38         connect.cc
  39         delete.cc
  40         do.cc
  41         dump.cc
  42         encoding_key.cc
  43         error.cc
  44         exist.cc
  45         fetch.cc
  46         flag.cc
  47         flush.cc
  48         flush_buffers.cc
  49         get.cc
  50         hash.cc
  51         hosts.cc
  52         initialize_query.cc
  53         instance.cc
  54         io.cc
  55         key.cc
  56         memcached.cc
  57         namespace.cc
  58         options.cc
  59         parse.cc
  60         poll.cc
  61         purge.cc
  62         quit.cc
  63         response.cc
  64         result.cc
  65         sasl.cc
  66         server.cc
  67         server_list.cc
  68         stats.cc
  69         storage.cc
  70         strerror.cc
  71         string.cc
  72         touch.cc
  73         udp.cc
  74         verbosity.cc
  75         version.cc
  76         virtual_bucket.c)
  77
  78 check_cxx_compiler_flag(-Wno-deprecated-register W_NO_DEPRECATED_REGISTER)
  79
  80 if(W_NO_DEPRECATED_REGISTER)
  81         set_source_files_properties(
  82                 ${FLEX_CSL_SCANNER_OUTPUTS}
  83                 ${BISON_CSL_PARSER_OUTPUTS}
  84                 PROPERTIES COMPILE_OPTIONS -Wno-deprecated-register
  85         )
  86 endif()
  87
  88 add_library(libmemcached SHARED
  89         ${LIBMEMCACHED_SOURCES})
  90 add_library(memcached ALIAS libmemcached)
  91 set_target_properties(libmemcached PROPERTIES
  92         CXX_STANDARD ${CXX_STANDARD}
  93         LIBRARY_OUTPUT_NAME memcached
  94         LIBRARY_OUTPUT_NAME_DEBUG memcached-dbg
  95         SOVERSION ${LIBMEMCACHED_SO_VERSION})
  96 target_compile_definitions(libmemcached PRIVATE -DBUILDING_LIBMEMCACHED)
  97 target_link_libraries(libmemcached PUBLIC libhashkit Threads::Threads ${CMAKE_DL_LIBS})
  98 if(MSVC)
  99     target_link_libraries(libmemcached PUBLIC wsock32 ws2_32)
 100 endif()
 101 if(HAVE_BACKTRACE)
 102     target_link_libraries(libmemcached PUBLIC ${BACKTRACE})
 103 endif()
 104 if(HAVE_LIBSASL)
 105     target_link_libraries(libmemcached PUBLIC ${LIBSASL})
 106 endif()
 107 if(CMAKE_CXX_COMPILER_ID STREQUAL "SunPro")
 108     # see https://docs.oracle.com/cd/E77782_01/html/E77789/bkamq.html#OSSCPgrxeu
 109     target_link_libraries(libmemcached INTERFACE stdc++ gcc_s CrunG3 c)
 110 endif()
 111 target_include_directories(libmemcached PRIVATE
 112         ${CMAKE_SOURCE_DIR}/src
 113         ${CMAKE_BINARY_DIR}/src
 114         ${CMAKE_BINARY_DIR})
 115 target_include_directories(libmemcached PUBLIC
 116         $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/include>
 117         $<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/include>
 118         $<INSTALL_INTERFACE:include>)
 119
 120 enable_dtrace_for(libmemcached libmemcached_probes.d dtrace_probes.h)
 121
 122 install(TARGETS libmemcached EXPORT libmemcached-targets
 123         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
 124 export(EXPORT libmemcached-targets NAMESPACE libmemcached::)
 125 install(EXPORT libmemcached-targets NAMESPACE libmemcached:: DESTINATION ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/cmake)
 126
 127 install_public_headers(
 128         libmemcached
 129
 130         memcached.h
 131         memcached.hpp
 132         util.h
 133         )
 134
 135 add_library(libmemcachedinternal STATIC
 136         ${LIBMEMCACHED_SOURCES})
 137 add_library(memcachedinternal ALIAS libmemcachedinternal)
 138 set_target_properties(libmemcachedinternal PROPERTIES CXX_STANDARD ${CXX_STANDARD} LIBRARY_OUTPUT_NAME memcachedinternal)
 139 target_compile_definitions(libmemcachedinternal PRIVATE -DBUILDING_LIBMEMCACHEDINTERNAL)
 140 target_link_libraries(libmemcachedinternal PUBLIC libhashkit Threads::Threads ${CMAKE_DL_LIBS})
 141 if(MSVC)
 142     target_link_libraries(libmemcached PUBLIC wsock32 ws2_32)
 143 endif()
 144 if(HAVE_LIBSASL)
 145     target_link_libraries(libmemcachedinternal PUBLIC ${LIBSASL})
 146 endif()
 147 if(HAVE_BACKTRACE)
 148     target_link_libraries(libmemcachedinternal PUBLIC ${BACKTRACE})
 149 endif()
 150 target_include_directories(libmemcachedinternal PRIVATE
 151         ${CMAKE_SOURCE_DIR}/src
 152         ${CMAKE_BINARY_DIR}/src
 153         ${CMAKE_BINARY_DIR})
 154 target_include_directories(libmemcachedinternal PUBLIC
 155         $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/include>
 156         $<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/include>
 157         $<INSTALL_INTERFACE:include>)
 158
 159 enable_dtrace_for(libmemcachedinternal libmemcached_probes.d dtrace_probes.h)
 160
 161 # let libmemcached depend on libmemcachedinternal to ensure that they do not
 162 # compete for the same generated dependencies
 163 add_dependencies(libmemcached libmemcachedinternal)