git.m6w6.name Git - m6w6/libmemcached/blob - m4/ax_pthread.m4

   1 # ===========================================================================
   2 #        http://www.gnu.org/software/autoconf-archive/ax_pthread.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
   8 #
   9 # DESCRIPTION
  10 #
  11 #   This macro figures out how to build C programs using POSIX threads. It
  12 #   sets the PTHREAD_LIBS output variable to the threads library and linker
  13 #   flags, and the PTHREAD_CFLAGS output variable to any special C compiler
  14 #   flags that are needed. (The user can also force certain compiler
  15 #   flags/libs to be tested by setting these environment variables.)
  16 #
  17 #   Also sets PTHREAD_CC to any special C compiler that is needed for
  18 #   multi-threaded programs (defaults to the value of CC otherwise). (This
  19 #   is necessary on AIX to use the special cc_r compiler alias.)
  20 #
  21 #   NOTE: You are assumed to not only compile your program with these flags,
  22 #   but also link it with them as well. e.g. you should link with
  23 #   $PTHREAD_CC $CFLAGS $PTHREAD_CFLAGS $LDFLAGS ... $PTHREAD_LIBS $LIBS
  24 #
  25 #   If you are only building threads programs, you may wish to use these
  26 #   variables in your default LIBS, CFLAGS, and CC:
  27 #
  28 #     LIBS="$PTHREAD_LIBS $LIBS"
  29 #     CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  30 #     CC="$PTHREAD_CC"
  31 #
  32 #   In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute constant
  33 #   has a nonstandard name, defines PTHREAD_CREATE_JOINABLE to that name
  34 #   (e.g. PTHREAD_CREATE_UNDETACHED on AIX).
  35 #
  36 #   Also HAVE_PTHREAD_PRIO_INHERIT is defined if pthread is found and the
  37 #   PTHREAD_PRIO_INHERIT symbol is defined when compiling with
  38 #   PTHREAD_CFLAGS.
  39 #
  40 #   ACTION-IF-FOUND is a list of shell commands to run if a threads library
  41 #   is found, and ACTION-IF-NOT-FOUND is a list of commands to run it if it
  42 #   is not found. If ACTION-IF-FOUND is not specified, the default action
  43 #   will define HAVE_PTHREAD.
  44 #
  45 #   Please let the authors know if this macro fails on any platform, or if
  46 #   you have any other suggestions or comments. This macro was based on work
  47 #   by SGJ on autoconf scripts for FFTW (http://www.fftw.org/) (with help
  48 #   from M. Frigo), as well as ac_pthread and hb_pthread macros posted by
  49 #   Alejandro Forero Cuervo to the autoconf macro repository. We are also
  50 #   grateful for the helpful feedback of numerous users.
  51 #
  52 #   Updated for Autoconf 2.68 by Daniel Richard G.
  53 #
  54 # LICENSE
  55 #
  56 #   Copyright (c) 2008 Steven G. Johnson <stevenj@alum.mit.edu>
  57 #   Copyright (c) 2011 Daniel Richard G. <skunk@iSKUNK.ORG>
  58 #
  59 #   This program is free software: you can redistribute it and/or modify it
  60 #   under the terms of the GNU General Public License as published by the
  61 #   Free Software Foundation, either version 3 of the License, or (at your
  62 #   option) any later version.
  63 #
  64 #   This program is distributed in the hope that it will be useful, but
  65 #   WITHOUT ANY WARRANTY; without even the implied warranty of
  66 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
  67 #   Public License for more details.
  68 #
  69 #   You should have received a copy of the GNU General Public License along
  70 #   with this program. If not, see <http://www.gnu.org/licenses/>.
  71 #
  72 #   As a special exception, the respective Autoconf Macro's copyright owner
  73 #   gives unlimited permission to copy, distribute and modify the configure
  74 #   scripts that are the output of Autoconf when processing the Macro. You
  75 #   need not follow the terms of the GNU General Public License when using
  76 #   or distributing such scripts, even though portions of the text of the
  77 #   Macro appear in them. The GNU General Public License (GPL) does govern
  78 #   all other use of the material that constitutes the Autoconf Macro.
  79 #
  80 #   This special exception to the GPL applies to versions of the Autoconf
  81 #   Macro released by the Autoconf Archive. When you make and distribute a
  82 #   modified version of the Autoconf Macro, you may extend this special
  83 #   exception to the GPL to apply to your modified version as well.
  84
  85 #serial 22
  86
  87 AU_ALIAS([ACX_PTHREAD], [AX_PTHREAD])
  88 AC_DEFUN([AX_PTHREAD], [
  89 AC_REQUIRE([AC_CANONICAL_HOST])
  90 ax_pthread_ok=no
  91
  92 # We used to check for pthread.h first, but this fails if pthread.h
  93 # requires special compiler flags (e.g. on True64 or Sequent).
  94 # It gets checked for in the link test anyway.
  95
  96 # First of all, check if the user has set any of the PTHREAD_LIBS,
  97 # etcetera environment variables, and if threads linking works using
  98 # them:
  99 if test x"$PTHREAD_LIBS$PTHREAD_CFLAGS" != x; then
 100         save_CFLAGS="$CFLAGS"
 101         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 102         save_LIBS="$LIBS"
 103         LIBS="$PTHREAD_LIBS $LIBS"
 104         AC_MSG_CHECKING([for pthread_join in LIBS=$PTHREAD_LIBS with CFLAGS=$PTHREAD_CFLAGS])
 105         AC_TRY_LINK_FUNC([pthread_join], [ax_pthread_ok=yes])
 106         AC_MSG_RESULT([$ax_pthread_ok])
 107         if test x"$ax_pthread_ok" = xno; then
 108                 PTHREAD_LIBS=""
 109                 PTHREAD_CFLAGS=""
 110         fi
 111         LIBS="$save_LIBS"
 112         CFLAGS="$save_CFLAGS"
 113 fi
 114
 115 # We must check for the threads library under a number of different
 116 # names; the ordering is very important because some systems
 117 # (e.g. DEC) have both -lpthread and -lpthreads, where one of the
 118 # libraries is broken (non-POSIX).
 119
 120 # Create a list of thread flags to try.  Items starting with a "-" are
 121 # C compiler flags, and other items are library names, except for "none"
 122 # which indicates that we try without any flags at all, and "pthread-config"
 123 # which is a program returning the flags for the Pth emulation library.
 124
 125 ax_pthread_flags="pthreads none -Kthread -kthread lthread -pthread -pthreads -mthreads pthread --thread-safe -mt pthread-config"
 126
 127 # The ordering *is* (sometimes) important.  Some notes on the
 128 # individual items follow:
 129
 130 # pthreads: AIX (must check this before -lpthread)
 131 # none: in case threads are in libc; should be tried before -Kthread and
 132 #       other compiler flags to prevent continual compiler warnings
 133 # -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
 134 # -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
 135 # lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
 136 # -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads)
 137 # -pthreads: Solaris/gcc
 138 # -mthreads: Mingw32/gcc, Lynx/gcc
 139 # -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
 140 #      doesn't hurt to check since this sometimes defines pthreads too;
 141 #      also defines -D_REENTRANT)
 142 #      ... -mt is also the pthreads flag for HP/aCC
 143 # pthread: Linux, etcetera
 144 # --thread-safe: KAI C++
 145 # pthread-config: use pthread-config program (for GNU Pth library)
 146
 147 case ${host_os} in
 148         solaris*)
 149
 150         # On Solaris (at least, for some versions), libc contains stubbed
 151         # (non-functional) versions of the pthreads routines, so link-based
 152         # tests will erroneously succeed.  (We need to link with -pthreads/-mt/
 153         # -lpthread.)  (The stubs are missing pthread_cleanup_push, or rather
 154         # a function called by this macro, so we could check for that, but
 155         # who knows whether they'll stub that too in a future libc.)  So,
 156         # we'll just look for -pthreads and -lpthread first:
 157
 158         ax_pthread_flags="-pthreads pthread -mt -pthread $ax_pthread_flags"
 159         ;;
 160
 161         darwin*)
 162         ax_pthread_flags="none -pthread $ax_pthread_flags"
 163         ;;
 164 esac
 165
 166 # Clang doesn't consider unrecognized options an error unless we specify
 167 # -Werror. We throw in some extra Clang-specific options to ensure that
 168 # this doesn't happen for GCC, which also accepts -Werror.
 169
 170 AC_MSG_CHECKING([if compiler needs -Werror to reject unknown flags])
 171 save_CFLAGS="$CFLAGS"
 172 ax_pthread_extra_flags="-Werror"
 173 CFLAGS="$CFLAGS $ax_pthread_extra_flags -Wunknown-warning-option -Wsizeof-array-argument"
 174 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int foo(void);],[foo()])],
 175                   [AC_MSG_RESULT([yes])],
 176                   [ax_pthread_extra_flags=
 177                    AC_MSG_RESULT([no])])
 178 CFLAGS="$save_CFLAGS"
 179
 180 if test x"$ax_pthread_ok" = xno; then
 181 for flag in $ax_pthread_flags; do
 182
 183         case $flag in
 184                 none)
 185                 AC_MSG_CHECKING([whether pthreads work without any flags])
 186                 ;;
 187
 188                 -*)
 189                 AC_MSG_CHECKING([whether pthreads work with $flag])
 190                 PTHREAD_CFLAGS="$flag"
 191                 ;;
 192
 193                 pthread-config)
 194                 AC_CHECK_PROG([ax_pthread_config], [pthread-config], [yes], [no])
 195                 if test x"$ax_pthread_config" = xno; then continue; fi
 196                 PTHREAD_CFLAGS="`pthread-config --cflags`"
 197                 PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`"
 198                 ;;
 199
 200                 *)
 201                 AC_MSG_CHECKING([for the pthreads library -l$flag])
 202                 PTHREAD_LIBS="-l$flag"
 203                 ;;
 204         esac
 205
 206         save_LIBS="$LIBS"
 207         save_CFLAGS="$CFLAGS"
 208         LIBS="$PTHREAD_LIBS $LIBS"
 209         CFLAGS="$CFLAGS $PTHREAD_CFLAGS $ax_pthread_extra_flags"
 210
 211         # Check for various functions.  We must include pthread.h,
 212         # since some functions may be macros.  (On the Sequent, we
 213         # need a special flag -Kthread to make this header compile.)
 214         # We check for pthread_join because it is in -lpthread on IRIX
 215         # while pthread_create is in libc.  We check for pthread_attr_init
 216         # due to DEC craziness with -lpthreads.  We check for
 217         # pthread_cleanup_push because it is one of the few pthread
 218         # functions on Solaris that doesn't have a non-functional libc stub.
 219         # We try pthread_create on general principles.
 220         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <pthread.h>
 221                         static void routine(void *a) { a = 0; }
 222                         static void *start_routine(void *a) { return a; }],
 223                        [pthread_t th; pthread_attr_t attr;
 224                         pthread_create(&th, 0, start_routine, 0);
 225                         pthread_join(th, 0);
 226                         pthread_attr_init(&attr);
 227                         pthread_cleanup_push(routine, 0);
 228                         pthread_cleanup_pop(0) /* ; */])],
 229                 [ax_pthread_ok=yes],
 230                 [])
 231
 232         LIBS="$save_LIBS"
 233         CFLAGS="$save_CFLAGS"
 234
 235         AC_MSG_RESULT([$ax_pthread_ok])
 236         if test "x$ax_pthread_ok" = xyes; then
 237                 break;
 238         fi
 239
 240         PTHREAD_LIBS=""
 241         PTHREAD_CFLAGS=""
 242 done
 243 fi
 244
 245 # Various other checks:
 246 if test "x$ax_pthread_ok" = xyes; then
 247         save_LIBS="$LIBS"
 248         LIBS="$PTHREAD_LIBS $LIBS"
 249         save_CFLAGS="$CFLAGS"
 250         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 251
 252         # Detect AIX lossage: JOINABLE attribute is called UNDETACHED.
 253         AC_MSG_CHECKING([for joinable pthread attribute])
 254         attr_name=unknown
 255         for attr in PTHREAD_CREATE_JOINABLE PTHREAD_CREATE_UNDETACHED; do
 256             AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <pthread.h>],
 257                            [int attr = $attr; return attr /* ; */])],
 258                 [attr_name=$attr; break],
 259                 [])
 260         done
 261         AC_MSG_RESULT([$attr_name])
 262         if test "$attr_name" != PTHREAD_CREATE_JOINABLE; then
 263             AC_DEFINE_UNQUOTED([PTHREAD_CREATE_JOINABLE], [$attr_name],
 264                                [Define to necessary symbol if this constant
 265                                 uses a non-standard name on your system.])
 266         fi
 267
 268         AC_MSG_CHECKING([if more special flags are required for pthreads])
 269         flag=no
 270         case ${host_os} in
 271             aix* | freebsd* | darwin*) flag="-D_THREAD_SAFE";;
 272             osf* | hpux*) flag="-D_REENTRANT";;
 273             solaris*)
 274             if test "$GCC" = "yes"; then
 275                 flag="-D_REENTRANT"
 276             else
 277                 # TODO: What about Clang on Solaris?
 278                 flag="-mt -D_REENTRANT"
 279             fi
 280             ;;
 281         esac
 282         AC_MSG_RESULT([$flag])
 283         if test "x$flag" != xno; then
 284             PTHREAD_CFLAGS="$flag $PTHREAD_CFLAGS"
 285         fi
 286
 287         AC_CACHE_CHECK([for PTHREAD_PRIO_INHERIT],
 288             [ax_cv_PTHREAD_PRIO_INHERIT], [
 289                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]],
 290                                                 [[int i = PTHREAD_PRIO_INHERIT;]])],
 291                     [ax_cv_PTHREAD_PRIO_INHERIT=yes],
 292                     [ax_cv_PTHREAD_PRIO_INHERIT=no])
 293             ])
 294         AS_IF([test "x$ax_cv_PTHREAD_PRIO_INHERIT" = "xyes"],
 295             [AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], [1], [Have PTHREAD_PRIO_INHERIT.])])
 296
 297         LIBS="$save_LIBS"
 298         CFLAGS="$save_CFLAGS"
 299
 300         # More AIX lossage: compile with *_r variant
 301         if test "x$GCC" != xyes; then
 302             case $host_os in
 303                 aix*)
 304                 AS_CASE(["x/$CC"],
 305                   [x*/c89|x*/c89_128|x*/c99|x*/c99_128|x*/cc|x*/cc128|x*/xlc|x*/xlc_v6|x*/xlc128|x*/xlc128_v6],
 306                   [#handle absolute path differently from PATH based program lookup
 307                    AS_CASE(["x$CC"],
 308                      [x/*],
 309                      [AS_IF([AS_EXECUTABLE_P([${CC}_r])],[PTHREAD_CC="${CC}_r"])],
 310                      [AC_CHECK_PROGS([PTHREAD_CC],[${CC}_r],[$CC])])])
 311                 ;;
 312             esac
 313         fi
 314 fi
 315
 316 test -n "$PTHREAD_CC" || PTHREAD_CC="$CC"
 317
 318 AC_SUBST([PTHREAD_LIBS])
 319 AC_SUBST([PTHREAD_CFLAGS])
 320 AC_SUBST([PTHREAD_CC])
 321
 322 # Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
 323 if test x"$ax_pthread_ok" = xyes; then
 324         ifelse([$1],,[AC_DEFINE([HAVE_PTHREAD],[1],[Define if you have POSIX threads libraries and header files.])],[$1])
 325         :
 326 else
 327         ax_pthread_ok=no
 328         $2
 329 fi
 330 ])dnl AX_PTHREAD