git.m6w6.name Git - m6w6/libmemcached/blob - libmemcached/csl/scanner.l

   1 /*  vim:expandtab:shiftwidth=2:tabstop=2:smarttab:
   2  *
   3  *  Libmemcached library
   4  *
   5  *  Copyright (C) 2012 Data Differential, http://datadifferential.com/
   6  *
   7  *  Redistribution and use in source and binary forms, with or without
   8  *  modification, are permitted provided that the following conditions are
   9  *  met:
  10  *
  11  *      * Redistributions of source code must retain the above copyright
  12  *  notice, this list of conditions and the following disclaimer.
  13  *
  14  *      * Redistributions in binary form must reproduce the above
  15  *  copyright notice, this list of conditions and the following disclaimer
  16  *  in the documentation and/or other materials provided with the
  17  *  distribution.
  18  *
  19  *      * The names of its contributors may not be used to endorse or
  20  *  promote products derived from this software without specific prior
  21  *  written permission.
  22  *
  23  *  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  24  *  "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  25  *  LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  26  *  A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  27  *  OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  28  *  SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  29  *  LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  30  *  DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  31  *  THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  32  *  (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  33  *  OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  34  *
  35  */
  36
  37
  38 %top{
  39
  40 #include <libmemcached/csl/common.h>
  41 #include <libmemcached/csl/context.h>
  42 #include <libmemcached/csl/parser.h>
  43 #include <libmemcached/csl/symbol.h>
  44
  45 #ifndef __INTEL_COMPILER
  46 #pragma GCC diagnostic ignored "-Wold-style-cast"
  47 #pragma GCC diagnostic ignored "-Wsign-compare"
  48 #pragma GCC diagnostic ignored "-Wunused-parameter"
  49 #pragma GCC diagnostic ignored "-Wmissing-declarations"
  50 #endif
  51
  52 #define YY_NO_INPUT
  53
  54 #define YY_EXTRA_TYPE Context*
  55
  56 }
  57
  58
  59 %{
  60 #include <cstdlib>
  61 #include <cstring>
  62
  63 #define PARAM yyget_extra(yyscanner)
  64
  65 #define get_lex_chars(buffer, result, max_size, context) \
  66 { \
  67   if (context->pos >= context->length) \
  68   { \
  69     result= YY_NULL; \
  70   } \
  71   else \
  72   { \
  73     result= (int)(context->length - context->pos); \
  74     (size_t)result > (size_t)max_size ? result= max_size : 0; \
  75     memcpy(buffer, context->buf + context->pos, result); \
  76     context->pos += result; \
  77   } \
  78 }
  79
  80
  81 #define YY_INPUT(buffer, result, max_size) get_lex_chars(buffer, result, max_size, PARAM)
  82
  83 %}
  84
  85 %option 8bit
  86 %option bison-bridge
  87 %option case-insensitive
  88 %option debug
  89 %option nounput
  90 %option noyywrap
  91 %option outfile="libmemcached/csl/scanner.cc" header-file="libmemcached/csl/scanner.h"
  92 %option perf-report
  93 %option prefix="config_"
  94 %option reentrant
  95
  96 %%
  97
  98
  99 =|,|[ ]       { return yytext[0];}
 100
 101 [[:digit:]]+ { yylval->number= atoi(yytext); return (NUMBER); }
 102
 103 :[[:digit:]]{1,5} { yylval->number= atoi(yytext +1); return PORT; }
 104
 105 "/?"[[:digit:]]{1,5} { yylval->number= atoi(yytext +2); return WEIGHT_START; }
 106
 107 [\t\r\n] ; /* skip whitespace */
 108
 109
 110 ^#.*$ {
 111       return COMMENT;
 112     }
 113
 114 "--SERVER="                          { yyextra->begin= yytext; yyextra->set_server(); return yyextra->previous_token= SERVER; }
 115
 116 "--SOCKET="                          { yyextra->begin= yytext; return yyextra->previous_token= SOCKET; }
 117
 118 "--BINARY-PROTOCOL"                     { yyextra->begin= yytext; return yyextra->previous_token= BINARY_PROTOCOL; }
 119 "--BUFFER-REQUESTS"                     { yyextra->begin= yytext; return yyextra->previous_token= BUFFER_REQUESTS; }
 120 "--CONFIGURE-FILE="                     { yyextra->begin= yytext; return yyextra->previous_token= CONFIGURE_FILE; }
 121 "--CONNECT-TIMEOUT="                    { yyextra->begin= yytext; return yyextra->previous_token= CONNECT_TIMEOUT; }
 122 "--DISTRIBUTION="                       { yyextra->begin= yytext; return yyextra->previous_token= DISTRIBUTION; }
 123 "--HASH-WITH-NAMESPACE"         { yyextra->begin= yytext; return yyextra->previous_token= HASH_WITH_NAMESPACE; }
 124 "--HASH="                               { yyextra->begin= yytext; return yyextra->previous_token= HASH; }
 125 "--IO-BYTES-WATERMARK="         { yyextra->begin= yytext; return yyextra->previous_token= IO_BYTES_WATERMARK; }
 126 "--IO-KEY-PREFETCH="                    { yyextra->begin= yytext; return yyextra->previous_token= IO_KEY_PREFETCH; }
 127 "--IO-MSG-WATERMARK="           { yyextra->begin= yytext; return yyextra->previous_token= IO_MSG_WATERMARK; }
 128 "--NOREPLY"                         { yyextra->begin= yytext; return yyextra->previous_token= NOREPLY; }
 129 "--NUMBER-OF-REPLICAS="         { yyextra->begin= yytext; return yyextra->previous_token= NUMBER_OF_REPLICAS; }
 130 "--POLL-TIMEOUT="                       { yyextra->begin= yytext; return yyextra->previous_token= POLL_TIMEOUT; }
 131 "--RANDOMIZE-REPLICA-READ"              { yyextra->begin= yytext; return yyextra->previous_token= RANDOMIZE_REPLICA_READ; }
 132 "--RCV-TIMEOUT="                        { yyextra->begin= yytext; return yyextra->previous_token= RCV_TIMEOUT; }
 133 "--REMOVE-FAILED-SERVERS="                      { yyextra->begin= yytext; return yyextra->previous_token= REMOVE_FAILED_SERVERS; }
 134 "--RETRY-TIMEOUT="                      { yyextra->begin= yytext; return yyextra->previous_token= RETRY_TIMEOUT; }
 135 "--SND-TIMEOUT="                        { yyextra->begin= yytext; return yyextra->previous_token= SND_TIMEOUT; }
 136 "--SOCKET-RECV-SIZE="           { yyextra->begin= yytext; return yyextra->previous_token= SOCKET_RECV_SIZE; }
 137 "--SOCKET-SEND-SIZE="           { yyextra->begin= yytext; return yyextra->previous_token= SOCKET_SEND_SIZE; }
 138 "--SORT-HOSTS"                  { yyextra->begin= yytext; return yyextra->previous_token= SORT_HOSTS; }
 139 "--SUPPORT-CAS"                 { yyextra->begin= yytext; return yyextra->previous_token= SUPPORT_CAS; }
 140 "--TCP-KEEPALIVE"                       { yyextra->begin= yytext; return yyextra->previous_token= _TCP_KEEPALIVE; }
 141 "--TCP-KEEPIDLE"                        { yyextra->begin= yytext; return yyextra->previous_token= _TCP_KEEPIDLE; }
 142 "--TCP-NODELAY"                 { yyextra->begin= yytext; return yyextra->previous_token= _TCP_NODELAY; }
 143 "--USE-UDP"                             { yyextra->begin= yytext; return yyextra->previous_token= USE_UDP; }
 144 "--USER-DATA"                   { yyextra->begin= yytext; return yyextra->previous_token= USER_DATA; }
 145 "--VERIFY-KEY"                      { yyextra->begin= yytext; return yyextra->previous_token= VERIFY_KEY; }
 146
 147 "--POOL-MIN="                           { yyextra->begin= yytext; return yyextra->previous_token= POOL_MIN; }
 148 "--POOL-MAX="                           { yyextra->begin= yytext; return yyextra->previous_token= POOL_MAX; }
 149
 150 "--NAMESPACE="                          { yyextra->begin= yytext; return yyextra->previous_token= NAMESPACE; }
 151
 152 "--FETCH-VERSION"                               { yyextra->begin= yytext; return yyextra->previous_token= FETCH_VERSION; }
 153
 154 INCLUDE           { yyextra->begin= yytext; return yyextra->previous_token= INCLUDE; }
 155 RESET           { yyextra->begin= yytext; return yyextra->previous_token= RESET; }
 156 DEBUG           { yyextra->begin= yytext; return yyextra->previous_token= PARSER_DEBUG; }
 157 SERVERS           { yyextra->begin= yytext; return yyextra->previous_token= SERVERS; }
 158 END           { yyextra->begin= yytext; return yyextra->previous_token= END; }
 159 ERROR           { yyextra->begin= yytext; return yyextra->previous_token= ERROR; }
 160
 161 TRUE           { return yyextra->previous_token= TRUE; }
 162 FALSE           { return yyextra->previous_token= FALSE; }
 163
 164
 165 "--"[[:alnum:]]*   {
 166       yyextra->begin= yytext;
 167       return UNKNOWN_OPTION;
 168     }
 169
 170 CONSISTENT      { return CONSISTENT; }
 171 MODULA          { return MODULA; }
 172 RANDOM          { return RANDOM; }
 173
 174 MD5                     { return MD5; }
 175 CRC                     { return CRC; }
 176 FNV1_64                 { return FNV1_64; }
 177 FNV1A_64                        { return FNV1A_64; }
 178 FNV1_32                 { return FNV1_32; }
 179 FNV1A_32                        { return FNV1A_32; }
 180 HSIEH                   { return HSIEH; }
 181 MURMUR                  { return MURMUR; }
 182 JENKINS                 { return JENKINS; }
 183
 184 (([[:digit:]]{1,3}"."){3}([[:digit:]]{1,3})) {
 185       yylval->server.port= MEMCACHED_DEFAULT_PORT;
 186       yylval->server.weight= 1;
 187       yylval->server.c_str= yyextra->set_hostname(yytext, yyleng);
 188       if (yylval->server.c_str)
 189         yylval->server.size= yyleng;
 190       return IPADDRESS;
 191     }
 192
 193 [[:alnum:]]["."[:alnum:]_-]+[[:alnum:]] {
 194       if (yyextra->is_server())
 195       {
 196         yylval->server.port= MEMCACHED_DEFAULT_PORT;
 197         yylval->server.weight= 1;
 198         yylval->server.c_str= yyextra->set_hostname(yytext, yyleng);
 199         if (yylval->server.c_str)
 200           yylval->server.size= yyleng;
 201
 202         return HOSTNAME;
 203       }
 204
 205       yylval->string.c_str = yytext;
 206       yylval->string.size = yyleng;
 207
 208       return STRING;
 209     }
 210
 211 L?\"(\\.|[^\\"])*\" {
 212       yyget_text(yyscanner)[yyleng -1]= 0;
 213       yylval->string.c_str= yytext +1;
 214       yylval->string.size= yyleng -2;
 215       return QUOTED_STRING;
 216     }
 217
 218 .   {
 219       yyextra->begin= yytext;
 220       return UNKNOWN;
 221     }
 222
 223 %%
 224
 225 void Context::init_scanner()
 226 {
 227   yylex_init(&scanner);
 228   yyset_extra(this, scanner);
 229 }
 230
 231 void Context::destroy_scanner()
 232 {
 233   yylex_destroy(scanner);
 234 }
 235