git.m6w6.name Git - m6w6/libmemcached/blob - docs/CMakeLists.txt

   1 find_package(Sphinx)
   2
   3 if(NOT SPHINX_EXECUTABLE)
   4
   5     message(WARNING "The sphinx-build command is required to build manpages.")
   6
   7 else()
   8
   9     if(NOT DEFINED SPHINX_OPTIONS)
  10         set(SPHINX_OPTIONS)
  11     endif()
  12
  13     if(NOT DEFINED SPHINX_THEME)
  14         set(SPHINX_THEME sphinx_rtd_theme)
  15         set(SPHINX_THEME_OPTIONS "'collapse_navigation':False, 'navigation_depth':2, 'titles_only':False, 'includehidden':False")
  16     endif()
  17
  18     set(SPHINX_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/source")
  19
  20     # configured documentation tools and intermediate build results
  21     set(SPHINX_BUILD_DIR "${CMAKE_CURRENT_BINARY_DIR}")
  22
  23     # Sphinx cache with pickled ReST documents
  24     set(SPHINX_CACHE_DIR "${SPHINX_BUILD_DIR}/_doctrees")
  25
  26     # HTML output directory
  27     set(SPHINX_HTML_DIR "${SPHINX_BUILD_DIR}/html")
  28
  29     # MAN output directory
  30     set(SPHINX_MAN_DIR "${SPHINX_BUILD_DIR}/man")
  31
  32     configure_file(
  33             "${SPHINX_SOURCE_DIR}/conf.py.in"
  34             "${SPHINX_BUILD_DIR}/conf.py"
  35             @ONLY)
  36
  37     add_custom_target(html
  38             ${SPHINX_EXECUTABLE}
  39             -q -b html
  40             -c "${SPHINX_BUILD_DIR}"
  41             -d "${SPHINX_CACHE_DIR}"
  42             ${SPHINX_OPTIONS}
  43             "${SPHINX_SOURCE_DIR}"
  44             "${SPHINX_HTML_DIR}"
  45             BYPRODUCTS ${SPHINX_HTML_DIR}
  46             )
  47     add_custom_target(man ALL
  48             ${SPHINX_EXECUTABLE}
  49             -q -b man
  50             -c "${SPHINX_BUILD_DIR}"
  51             -d "${SPHINX_CACHE_DIR}"
  52             ${SPHINX_OPTIONS}
  53             "${SPHINX_SOURCE_DIR}"
  54             "${SPHINX_MAN_DIR}"
  55             BYPRODUCTS ${SPHINX_MAN_DIR}
  56             )
  57
  58     set(MAN_EXT "")
  59     if(GZIP_MAN)
  60         find_program(PIGZ pigz)
  61         if(PIGZ)
  62             set(GZIP ${PIGZ})
  63         else()
  64             find_package(UnixCommands)
  65         endif()
  66         if(GZIP)
  67             set(MAN_EXT ".gz")
  68             add_custom_target(man_gz ALL
  69                     ${GZIP} -kf ${SPHINX_MAN_DIR}/*.{1,3}
  70                     DEPENDS man
  71                     )
  72         endif()
  73     endif()
  74
  75     install(DIRECTORY ${SPHINX_MAN_DIR}/
  76             DESTINATION ${CMAKE_INSTALL_MANDIR}/man1
  77             FILES_MATCHING PATTERN *.1${MAN_EXT}
  78             )
  79     install(DIRECTORY ${SPHINX_MAN_DIR}/
  80             DESTINATION ${CMAKE_INSTALL_MANDIR}/man3
  81             FILES_MATCHING PATTERN *.3${MAN_EXT}
  82             )
  83 endif()