git.m6w6.name Git - m6w6/libmemcached/blob - docs/CMakeLists.txt

   1 find_package(Sphinx)
   2
   3 if(NOT SPHINX_EXECUTABLE)
   4
   5     message(WARNING "The sphinx-build command is required to build documentation.")
   6
   7 else()
   8
   9     if(NOT DEFINED SPHINX_OPTIONS)
  10         set(SPHINX_OPTIONS)
  11     endif()
  12
  13     if(NOT DEFINED SPHINX_THEME)
  14         set(SPHINX_THEME sphinx_rtd_theme)
  15         set(SPHINX_THEME_OPTIONS "'collapse_navigation':False, 'navigation_depth':2, 'titles_only':False, 'includehidden':False")
  16     endif()
  17
  18     set(SPHINX_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/source")
  19
  20     # configured documentation tools and intermediate build results
  21     set(SPHINX_BUILD_DIR "${CMAKE_CURRENT_BINARY_DIR}")
  22
  23     # Sphinx cache with pickled ReST documents
  24     set(SPHINX_CACHE_DIR "${SPHINX_BUILD_DIR}/_doctrees")
  25
  26     # HTML output directory
  27     set(SPHINX_HTML_DIR "${SPHINX_BUILD_DIR}/html")
  28
  29     # MAN output directory
  30     set(SPHINX_MAN_DIR "${SPHINX_BUILD_DIR}/man")
  31
  32     configure_file("conf.py.in" "conf.py" @ONLY)
  33     add_subdirectory(source)
  34
  35     if(BUILD_DOCS_HTML)
  36         add_custom_target(html
  37                 COMMAND
  38                 ${SPHINX_EXECUTABLE}
  39                 -q -b html
  40                 -c "${SPHINX_BUILD_DIR}"
  41                 -d "${SPHINX_CACHE_DIR}"
  42                 ${SPHINX_OPTIONS}
  43                 "${SPHINX_SOURCE_DIR}"
  44                 "${SPHINX_HTML_DIR}"
  45                 BYPRODUCTS ${SPHINX_HTML_DIR}
  46                 )
  47     endif()
  48
  49     if(BUILD_DOCS_MAN)
  50         add_custom_target(man ALL
  51                 ${SPHINX_EXECUTABLE}
  52                 -q -b man
  53                 -c "${SPHINX_BUILD_DIR}"
  54                 -d "${SPHINX_CACHE_DIR}"
  55                 ${SPHINX_OPTIONS}
  56                 "${SPHINX_SOURCE_DIR}"
  57                 "${SPHINX_MAN_DIR}"
  58                 BYPRODUCTS ${SPHINX_MAN_DIR}
  59                 )
  60
  61         set(MAN_EXT "")
  62         if(BUILD_DOCS_MANGZ)
  63             find_program(PIGZ pigz)
  64             if(PIGZ)
  65                 set(GZIP ${PIGZ})
  66             else()
  67                 find_package(UnixCommands)
  68             endif()
  69             if(GZIP)
  70                 set(MAN_EXT ".gz")
  71                 add_custom_target(man_gz ALL
  72                         ${GZIP} -kf ${SPHINX_MAN_DIR}/*.{1,3}
  73                         DEPENDS man
  74                         )
  75             endif()
  76         endif()
  77
  78         install(DIRECTORY ${SPHINX_MAN_DIR}/
  79                 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1
  80                 FILES_MATCHING PATTERN *.1${MAN_EXT}
  81                 )
  82         install(DIRECTORY ${SPHINX_MAN_DIR}/
  83                 DESTINATION ${CMAKE_INSTALL_MANDIR}/man3
  84                 FILES_MATCHING PATTERN *.3${MAN_EXT}
  85                 )
  86     endif()
  87
  88 endif()