git.m6w6.name Git - m6w6/libmemcached/blob - docs/CMakeLists.txt

   1 find_package(Sphinx)
   2
   3 if(NOT SPHINX_EXECUTABLE)
   4
   5     message(WARNING "The sphinx-build command is required to build documentation.")
   6
   7 else()
   8
   9     if(NOT DEFINED SPHINX_OPTIONS)
  10         set(SPHINX_OPTIONS)
  11     endif()
  12
  13     if(NOT DEFINED SPHINX_THEME)
  14         set(SPHINX_THEME sphinx_rtd_theme)
  15         set(SPHINX_THEME_OPTIONS "'collapse_navigation':False, 'navigation_depth':2, 'titles_only':False, 'includehidden':False")
  16     endif()
  17
  18     set(SPHINX_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/source")
  19
  20     # configured documentation tools and intermediate build results
  21     set(SPHINX_BUILD_DIR "${CMAKE_CURRENT_BINARY_DIR}")
  22
  23     # Sphinx cache with pickled ReST documents
  24     set(SPHINX_CACHE_DIR "${SPHINX_BUILD_DIR}/_doctrees")
  25
  26     # HTML output directory
  27     set(SPHINX_HTML_DIR "${SPHINX_BUILD_DIR}/html")
  28
  29     # MAN output directory
  30     set(SPHINX_MAN_DIR "${SPHINX_BUILD_DIR}/man")
  31
  32     configure_file("conf.py.in" "conf.py" @ONLY)
  33     add_subdirectory(source)
  34
  35     file(GLOB_RECURSE DOCS_SOURCE
  36             CONFIGURE_DEPENDS
  37             "*.rst")
  38
  39     if(BUILD_DOCS_HTML)
  40         add_custom_command(
  41                 OUTPUT "${SPHINX_HTML_DIR}"
  42                 COMMAND
  43                 ${SPHINX_EXECUTABLE}
  44                 -q -b html
  45                 -c "${SPHINX_BUILD_DIR}"
  46                 -d "${SPHINX_CACHE_DIR}"
  47                 ${SPHINX_OPTIONS}
  48                 "${SPHINX_SOURCE_DIR}"
  49                 "${SPHINX_HTML_DIR}"
  50                 COMMAND ${CMAKE_COMMAND} -E touch html
  51                 BYPRODUCTS ${SPHINX_HTML_DIR}
  52                 DEPENDS "${DOCS_SOURCE}"
  53                 )
  54         add_custom_target(html ALL DEPENDS "${SPHINX_HTML_DIR}")
  55
  56         install(DIRECTORY ${SPHINX_HTML_DIR}/
  57                 COMPONENT doc
  58                 DESTINATION ${CMAKE_INSTALL_DOCDIR}/html)
  59     endif()
  60
  61     if(BUILD_DOCS_MAN)
  62         add_custom_command(
  63                 OUTPUT ${SPHINX_MAN_DIR}
  64                 COMMAND
  65                 ${SPHINX_EXECUTABLE}
  66                 -q -b man
  67                 -c "${SPHINX_BUILD_DIR}"
  68                 -d "${SPHINX_CACHE_DIR}"
  69                 ${SPHINX_OPTIONS}
  70                 "${SPHINX_SOURCE_DIR}"
  71                 "${SPHINX_MAN_DIR}"
  72                 COMMAND ${CMAKE_COMMAND} -E touch man
  73                 BYPRODUCTS ${SPHINX_MAN_DIR}
  74                 DEPENDS "${DOCS_SOURCE}"
  75                 )
  76         add_custom_target(man ALL DEPENDS "${SPHINX_MAN_DIR}")
  77
  78         set(MAN_EXT "")
  79         if(BUILD_DOCS_MANGZ)
  80             find_program(PIGZ pigz)
  81             if(PIGZ)
  82                 set(GZIP ${PIGZ})
  83             else()
  84                 find_package(UnixCommands)
  85             endif()
  86             if(GZIP)
  87                 set(MAN_EXT ".gz")
  88                 add_custom_target(man_gz ALL
  89                         ${GZIP} -kf ${SPHINX_MAN_DIR}/*.{1,3}
  90                         DEPENDS man
  91                         )
  92             endif()
  93         endif()
  94
  95         install(DIRECTORY ${SPHINX_MAN_DIR}/
  96                 COMPONENT doc
  97                 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1
  98                 FILES_MATCHING PATTERN *.1${MAN_EXT}
  99                 )
 100         install(DIRECTORY ${SPHINX_MAN_DIR}/
 101                 COMPONENT doc
 102                 DESTINATION ${CMAKE_INSTALL_MANDIR}/man3
 103                 FILES_MATCHING PATTERN *.3${MAN_EXT}
 104                 )
 105     endif()
 106
 107 endif()