git.m6w6.name Git - m6w6/libmemcached/blob - configure.ac

   1 #!/usr/bin/env bash
   2 # libmemcached
   3 # Copyright (C) 2006-2010 Brian Aker, Monty Taylor, Trond Norbye
   4 # All rights reserved.
   5 #
   6 # Use and distribution licensed under the BSD license.  See
   7 # the COPYING file in this directory for full text.
   8
   9 AC_PREREQ(2.59)
  10 AC_INIT([libmemcached],[0.47],[http://libmemcached.org/])
  11 AC_CONFIG_SRCDIR([libmemcached/memcached.c])
  12 AC_CONFIG_AUX_DIR(config)
  13
  14 PANDORA_CANONICAL_TARGET(no-vc-changelog)
  15
  16 #shared library versioning
  17 MEMCACHED_UTIL_LIBRARY_VERSION=1:0:0
  18 MEMCACHED_PROTOCAL_LIBRARY_VERSION=0:0:0
  19 MEMCACHED_LIBRARY_VERSION=6:0:0
  20 #                         | | |
  21 #                  +------+ | +---+
  22 #                  |        |     |
  23 #                 current:revision:age
  24 #                  |        |     |
  25 #                  |        |     +- increment if interfaces have been added
  26 #                  |        |        set to zero if interfaces have been removed or changed
  27 #                  |        +- increment if source code has changed
  28 #                  |           set to zero if current is incremented
  29 #                  +- increment if interfaces have been added, removed or changed
  30 AC_SUBST(MEMCACHED_UTIL_LIBRARY_VERSION)
  31 AC_SUBST(MEMCACHED_PROTOCAL_LIBRARY_VERSION)
  32 AC_SUBST(MEMCACHED_LIBRARY_VERSION)
  33
  34
  35 HASHKIT_LIBRARY_VERSION=0:0:0
  36 AC_SUBST(HASHKIT_LIBRARY_VERSION)
  37
  38 AH_TOP([
  39 #ifndef CONFIG_H
  40 #define CONFIG_H
  41
  42 #ifdef _SYS_FEATURE_TESTS_H
  43 #error "You should include config.h as your first include file"
  44 #endif
  45
  46 #ifdef WIN32
  47 #define _WIN32_WINNT 0x0501
  48 #endif
  49 ])
  50
  51 AH_BOTTOM([
  52 #ifdef HAVE_SYS_WAIT_H
  53 #include <sys/wait.h>
  54 #endif
  55
  56 #ifdef HAVE_FNMATCH_H
  57 #include <fnmatch.h>
  58 #endif
  59
  60 #ifdef HAVE_POLL_H
  61 #include <poll.h>
  62 #else
  63 #include "poll/poll.h"
  64 #endif
  65
  66 /* To hide the platform differences between MS Windows and Unix, I am
  67  * going to use the Microsoft way and #define the Microsoft-specific
  68  * functions to the unix way. Microsoft use a separate subsystem for sockets,
  69  * but Unix normally just use a filedescriptor on the same functions. It is
  70  * a lot easier to map back to the unix way with macros than going the other
  71  * way without side effect ;-)
  72  */
  73 #ifdef WIN32
  74 #include "win32/wrappers.h"
  75 #define get_socket_errno() WSAGetLastError()
  76 #else
  77 #define INVALID_SOCKET -1
  78 #define SOCKET_ERROR -1
  79 #define closesocket(a) close(a)
  80 #define get_socket_errno() errno
  81 #endif
  82
  83 #ifndef HAVE_MSG_NOSIGNAL
  84 #define MSG_NOSIGNAL 0
  85 #endif
  86
  87 #ifndef HAVE_MSG_DONTWAIT
  88 #define MSG_DONTWAIT 0
  89 #endif
  90
  91 #endif
  92 ])
  93
  94 AC_SEARCH_LIBS(getopt_long, gnugetopt)
  95 AC_SEARCH_LIBS(gethostbyname, nsl)
  96
  97 AC_CHECK_FUNCS([getline])
  98
  99 PANDORA_HAVE_LIBGTEST
 100 PANDORA_HAVE_LIBEVENT
 101 my_saved_libs="$LIBS"
 102 LIBS=
 103 PANDORA_REQUIRE_PTHREAD
 104 LIBS="$my_saved_libs"
 105 PANDORA_CXX_DEMANGLE
 106
 107 dnl Specialty checks
 108 DETECT_BYTEORDER
 109 ENABLE_UTILLIB
 110 SETSOCKOPT_SANITY
 111 ENABLE_HSIEH_HASH
 112 ENABLE_MURMUR_HASH
 113 PROTOCOL_BINARY_TEST
 114 WITH_MEMCACHED
 115 ENABLE_DEPRECATED
 116 PANDORA_HAVE_LIBINNODB
 117 PANDORA_PRINT_CALLSTACK
 118 PANDORA_HAVE_SASL
 119
 120 dnl The sasl functions should only be visible if we build with sasl support
 121 AS_IF([test "x$ac_cv_sasl" = "xyes"],
 122       [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 1"])
 123 AC_SUBST(LIBMEMCACHED_WITH_SASL_SUPPORT)
 124
 125 AC_CHECK_HEADERS([atomic.h])
 126 AS_IF([test "x$ac_cv_header_atomic_h" = "xyes"],[
 127       AC_CHECK_FUNCS(atomic_add_64)
 128       AC_CHECK_FUNCS(atomic_add_32)
 129       AS_IF([test "x$ac_cv_func_atomic_add_64" = "xyes" -a "x$ac_cv_func_atomic_add_32" = "xyes"],[
 130             AC_DEFINE([USE_ATOMIC_H],
 131                       [1],
 132                       [Define to true if you want to use functions from atomic.h])])])
 133
 134 AC_ARG_WITH([docs],
 135   [AS_HELP_STRING([--with-docs],
 136     [Generate documentation (yes|no) @<:@default=yes@:>@])],
 137   [with_docs=$withval],
 138   [with_docs=yes])
 139
 140 AS_IF([test "$with_docs" = "yes"],
 141   [
 142     REQUIRE_POD2MAN
 143     REQUIRE_PODCHECKER
 144   ])
 145 AM_CONDITIONAL(BUILD_DOCS, test "$with_docs" = "yes")
 146
 147 AC_CHECK_HEADERS_ONCE(winsock2.h poll.h sys/wait.h fnmatch.h)
 148 AM_CONDITIONAL(BUILD_POLL, test "x$ac_cv_header_poll_h" = "xno")
 149 AM_CONDITIONAL(BUILD_WIN32_WRAPPERS, test "x$ac_cv_header_winsock2_h" = "xyes")
 150 AS_IF(test "x$ac_cv_header_winsock2_h" = "xyes",
 151       [AM_LDFLAGS="$AM_LDFLAGS -lws2_32"
 152        AM_CFLAGS="$AM_CFLAGS $NO_WERROR"
 153        AM_CXXFLAGS="$AM_CXXFLAGS $NO_WERROR"
 154       ])
 155 DETECT_EAGAIN
 156 SOCKET_SEND_FLAGS
 157
 158 AC_CONFIG_FILES([
 159   Makefile
 160   docs/Makefile
 161   libhashkit/configure.h
 162   libmemcached/configure.h
 163   support/libmemcached.pc
 164   support/libmemcached.spec
 165   support/libmemcached-fc.spec
 166   ])
 167 AC_OUTPUT
 168
 169 echo "---"
 170 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 171 echo ""
 172 echo "   * Installation prefix:       $prefix"
 173 echo "   * System type:               $host_vendor-$host_os"
 174 echo "   * Host CPU:                  $host_cpu"
 175 echo "   * C Compiler:                $CC_VERSION"
 176 echo "   * Assertions enabled:        $ac_cv_assert"
 177 echo "   * Debug enabled:             $with_debug"
 178 echo "   * Warnings as failure:       $ac_cv_warnings_as_errors"
 179 echo ""
 180 echo "---"
 181
 182 case "$host_os" in
 183   *freebsd*)
 184     echo "*****"
 185     echo "*"
 186     echo "*  NOTE: You are on FreeBSD. BSD make will not work."
 187     echo "*"
 188     echo "*   use 'gmake' To build libmemcached"
 189     echo "*"
 190     echo "*****"
 191   ;;
 192 esac
 193
 194 AS_IF(test "$with_docs" = "no",
 195   [
 196     echo "*****"
 197     echo "*"
 198     echo "*  WARNING: You are not generating any documentation."
 199     echo "*           Please don't ship libmemcached to an end user"
 200     echo "*           without documentation..."
 201     echo "*"
 202     echo "*****"
 203   ])