git.m6w6.name Git - m6w6/libmemcached/blob - configure.ac

   1 # LibmemcacheD
   2 # Copyright (C) 2011-2012 Data Differential, http://datadifferential.com/
   3 # Copyright (C) 2006-2010 Brian Aker, Monty Taylor, Trond Norbye
   4 # All rights reserved.
   5 #
   6 # Use and distribution licensed under the BSD license.  See
   7 # the COPYING file in this directory for full text.
   8
   9 AC_INIT([libmemcached],[1.0.15],[http://libmemcached.org/])
  10 AC_CONFIG_AUX_DIR([build-aux])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_CANONICAL_TARGET
  14 AC_ARG_PROGRAM
  15 AC_USE_SYSTEM_EXTENSIONS
  16
  17 AM_INIT_AUTOMAKE([1.11 color-tests -Wno-portability subdir-objects foreign tar-ustar])
  18
  19 AC_PREREQ([2.61])
  20
  21 AC_CONFIG_HEADERS([mem_config.h:mem_config.in])dnl Keep filename to 8.3 for MS-DOS.
  22 AC_CONFIG_SRCDIR([libmemcached/memcached.cc])
  23
  24 #shared library versioning
  25 MEMCACHED_UTIL_LIBRARY_VERSION=2:0:0
  26 MEMCACHED_PROTOCAL_LIBRARY_VERSION=0:0:0
  27 MEMCACHED_LIBRARY_VERSION=11:0:0
  28 #                         | | |
  29 #                  +------+ | +---+
  30 #                  |        |     |
  31 #                 current:revision:age
  32 #                  |        |     |
  33 #                  |        |     +- increment if interfaces have been added
  34 #                  |        |        set to zero if interfaces have been removed or changed
  35 #                  |        +- increment if source code has changed
  36 #                  |           set to zero if current is incremented
  37 #                  +- increment if interfaces have been added, removed or changed
  38 AC_SUBST([MEMCACHED_UTIL_LIBRARY_VERSION])
  39 AC_SUBST([MEMCACHED_PROTOCAL_LIBRARY_VERSION])
  40 AC_SUBST([MEMCACHED_LIBRARY_VERSION])
  41
  42 AX_HEX_VERSION([LIBMEMCACHED],[$VERSION])
  43 AX_HEX_VERSION([LIBHASHKIT],[1.0.0])
  44
  45 m4_include([libhashkit/include.m4])
  46
  47 LT_PREREQ([2.2])
  48 LT_INIT
  49 LT_LANG([C++])
  50 LT_LIB_M
  51
  52 AX_ASSERT
  53
  54 AX_PLATFORM
  55
  56 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  57
  58 AX_CXX_HEADER_STDCXX_98
  59 AS_IF([test "x$ax_cv_cxx_stdcxx_98" = "xno"],
  60       [AC_MSG_ERROR([Your system lacks a new enough C++ compiler])])
  61
  62 AC_DEFUN([LIBMEMCACHED_PROTOCOL],
  63          [AC_ARG_ENABLE([libmemcachedprotocol],
  64                         [AS_HELP_STRING([--enable-libmemcachedprotocol],
  65                                         [Enable libmemcachedprotocol])],
  66                                         [ax_enable_libmemcachedprotocol=yes],
  67                                         [ax_enable_libmemcachedprotocol=no])
  68
  69          AM_CONDITIONAL([BUILD_LIBMEMCACHED_PROTOCOL],[test "$ax_enable_libmemcachedprotocol" = "yes"])
  70
  71          AC_MSG_CHECKING([for libmemcachedprotocol])
  72          AC_MSG_RESULT([$ax_enable_libmemcachedprotocol])
  73          ])
  74 LIBMEMCACHED_PROTOCOL
  75
  76 # Adding support for libtest
  77 m4_include([libtest/yatl.m4])
  78
  79 CHECK_FOR_GEARMAND
  80 CHECK_FOR_LIBGEARMAND
  81
  82 AM_CONDITIONAL([BUILDING_LIBMEMCACHED],[true])
  83 AM_CONDITIONAL([HAVE_LIBMEMCACHED],[false])
  84 AM_CONDITIONAL([HAVE_LIBDRIZZLE],[false])
  85 AC_DEFINE([HAVE_LIBMEMCACHED],[1],[Enables libmemcached Support])
  86
  87 AM_CONDITIONAL([BUILDING_GEARMAN],[false])
  88
  89 # Specialty checks
  90 AX_CXX_CINTTYPES
  91 CONFIG_EXTRA
  92 DETECT_BYTEORDER
  93 SETSOCKOPT_SANITY
  94 ENABLE_HSIEH_HASH
  95 ENABLE_MURMUR_HASH
  96 ENABLE_FNV64_HASH
  97 ENABLE_MEMASLAP
  98 PROTOCOL_BINARY_TEST
  99 ENABLE_DEPRECATED
 100
 101 # Checks for programs.
 102 AC_CHECK_PROGS([LEX],['flex'],[:])
 103 AC_CHECK_PROGS([YACC],['bison'],[:])
 104 AX_PROG_SPHINX_BUILD
 105
 106 # Checks for libraries.
 107 AC_SEARCH_LIBS([getopt_long],[gnugetopt])
 108 AC_SEARCH_LIBS([gethostbyname],[nsl])
 109
 110 # Checks for header files.
 111 AC_CHECK_HEADERS_ONCE([arpa/inet.h])
 112 AC_CHECK_HEADERS_ONCE([dlfcn.h])
 113 AC_CHECK_HEADERS_ONCE([errno.h])
 114 AC_CHECK_HEADERS_ONCE([execinfo.h])
 115 AC_CHECK_HEADERS_ONCE([fcntl.h])
 116 AC_CHECK_HEADERS_ONCE([fnmatch.h])
 117 AC_CHECK_HEADERS_ONCE([inttypes.h])
 118 AC_CHECK_HEADERS_ONCE([libintl.h])
 119 AC_CHECK_HEADERS_ONCE([limits.h])
 120 AC_CHECK_HEADERS_ONCE([mach/mach.h])
 121 AC_CHECK_HEADERS_ONCE([malloc.h])
 122 AC_CHECK_HEADERS_ONCE([math.h])
 123 AC_CHECK_HEADERS_ONCE([netdb.h])
 124 AC_CHECK_HEADERS_ONCE([netinet/in.h])
 125 AC_CHECK_HEADERS_ONCE([netinet/tcp.h])
 126 AC_CHECK_HEADERS_ONCE([poll.h])
 127 AC_CHECK_HEADERS_ONCE([pthread.h])
 128 AC_CHECK_HEADERS_ONCE([spawn.h])
 129 AC_CHECK_HEADERS_ONCE([stdarg.h])
 130 AC_CHECK_HEADERS_ONCE([stddef.h])
 131 AC_CHECK_HEADERS_ONCE([stdio.h])
 132 AC_CHECK_HEADERS_ONCE([stdlib.h])
 133 AC_CHECK_HEADERS_ONCE([sys/socket.h])
 134 AC_CHECK_HEADERS_ONCE([sys/sysctl.h])
 135 AC_CHECK_HEADERS_ONCE([sys/time.h])
 136 AC_CHECK_HEADERS_ONCE([sys/un.h])
 137 AC_CHECK_HEADERS_ONCE([sys/wait.h])
 138 AC_CHECK_HEADERS_ONCE([syslog.h])
 139 AC_CHECK_HEADERS_ONCE([time.h])
 140 AC_CHECK_HEADERS_ONCE([unistd.h])
 141
 142 # Windows only
 143 AC_CHECK_HEADERS_ONCE([winsock2.h])
 144 AC_CHECK_HEADERS_ONCE([ws2tcpip.h])
 145
 146 # Checks for typedefs, structures, and compiler characteristics.
 147
 148 # Checks for library functions.
 149
 150 AC_CHECK_FUNCS([alarm])
 151 AC_CHECK_FUNCS([atexit])
 152 AC_CHECK_FUNCS([clock_gettime])
 153 AC_CHECK_FUNCS([dup2])
 154 AC_CHECK_FUNCS([fcntl])
 155 AC_CHECK_FUNCS([floor])
 156 AC_CHECK_FUNCS([getcwd])
 157 AC_CHECK_FUNCS([getline])
 158 AC_CHECK_FUNCS([gettimeofday])
 159 AC_CHECK_FUNCS([inet_ntoa])
 160 AC_CHECK_FUNCS([memchr])
 161 AC_CHECK_FUNCS([memmove])
 162 AC_CHECK_FUNCS([memset])
 163 AC_CHECK_FUNCS([pipe2])
 164 AC_CHECK_FUNCS([putenv])
 165 AC_CHECK_FUNCS([select])
 166 AC_CHECK_FUNCS([setenv])
 167 AC_CHECK_FUNCS([sigignore])
 168 AC_CHECK_FUNCS([socket])
 169 AC_CHECK_FUNCS([sqrt])
 170 AC_CHECK_FUNCS([strcasecmp])
 171 AC_CHECK_FUNCS([strchr])
 172 AC_CHECK_FUNCS([strdup])
 173 AC_CHECK_FUNCS([strerror])
 174 AC_CHECK_FUNCS([strstr])
 175 AC_CHECK_FUNCS([strtol])
 176 AC_CHECK_FUNCS([strtoul])
 177 AC_CHECK_FUNCS([strtoull])
 178 AC_FUNC_ALLOCA
 179 AC_FUNC_ERROR_AT_LINE
 180 AC_FUNC_FORK
 181 AC_FUNC_STRERROR_R
 182
 183 AC_CHECK_HEADER([umem.h],
 184                 [AC_DEFINE([HAVE_UMEM_H],[1],[Define this if you have umem.h])
 185                 build_cache=no],
 186                 [build_cache=yes])
 187
 188 AM_CONDITIONAL([BUILD_CACHE],[test "x$build_cache" = "xyes"])
 189
 190 AX_COMPILER_VENDOR
 191
 192 AC_CHECK_TYPES([ptrdiff_t])
 193 AC_HEADER_STDBOOL
 194 AC_TYPE_INT16_T
 195 AC_TYPE_INT32_T
 196 AC_TYPE_INT64_T
 197 AC_TYPE_INT8_T
 198 AC_TYPE_OFF_T
 199 AC_TYPE_PID_T
 200 AC_TYPE_SSIZE_T
 201 AC_TYPE_UINT16_T
 202 AC_TYPE_UINT32_T
 203 AC_TYPE_UINT64_T
 204 AC_TYPE_UINT8_T
 205
 206 AC_C_BIGENDIAN
 207 AC_C_CONST
 208 AC_C_INLINE
 209 AC_C_VOLATILE
 210 AC_C_RESTRICT
 211
 212 AX_CXX_GCC_ABI_DEMANGLE
 213
 214 AX_LIBEVENT
 215
 216 AC_CHECK_LIB([rt],[clock_gettime],
 217              [AC_SUBST([RT_LIB],[-lrt])
 218              AC_DEFINE([HAVE_CLOCK_GETTIME],[1],[Have clock_gettime])],
 219              [AC_DEFINE([HAVE_CLOCK_GETTIME],[0],[Have clock_gettime])])
 220
 221 # Check for the ability to call dlopen (used in libhostile)
 222 AS_IF([test "x$enable_shared" = xyes],
 223       [AX_CHECK_LIBRARY([DL],[dlfcn.h],[dl],
 224                         [AC_DEFINE([HAVE_LIBDL],[1],[Have dlopen])
 225                         AC_CHECK_LIB([dl],[dlopen],[AC_DEFINE([HAVE_DLOPEN],[1],[Have dlopen])])
 226                         AC_CHECK_LIB([dl],[dladdr],[AC_DEFINE([HAVE_DLADDR],[1],[Have dladdr])])])
 227       ])
 228
 229 AC_CHECK_HEADERS([atomic.h])
 230 AS_IF([test "x$ac_cv_header_atomic_h" = "xyes"],
 231       [AC_CHECK_FUNCS([atomic_add_64])
 232       AC_CHECK_FUNCS([atomic_add_32])
 233       AS_IF([test "x$ac_cv_func_atomic_add_64" = "xyes" -a "x$ac_cv_func_atomic_add_32" = "xyes"],
 234             [AC_DEFINE([USE_ATOMIC_H],[1],[Define to true if you want to use functions from atomic.h])])])
 235
 236 AC_DEFINE([HAVE_LIBDRIZZLE],[0],[Support for libdrizzle])
 237 AC_DEFINE([HAVE_DRIZZLED_BINARY],[0],[Support for DrizzleD])
 238 AC_DEFINE([DRIZZLED_BINARY],[0],[Support for DrizzleD])
 239 AC_DEFINE([GEARMAND_BLOBSLAP_WORKER],[0],[Support for Gearman Blobslap worker])
 240 AC_DEFINE([HAVE_LIBPQ],[0],[Support for Postgres])
 241 AC_DEFINE([HAVE_LIBCURL],[0],[Support for libcurl])
 242
 243 # Check for the requirements for running memcached with less privileges
 244 # than the default privilege set. On Solaris we need setppriv and priv.h
 245 # If you want to add support for other platforms you should check for
 246 # your requirements, define HAVE_DROP_PRIVILEGES, and make sure you add
 247 # the source file containing the implementation into memcached_SOURCE
 248 # in Makefile.am
 249 AC_CHECK_FUNCS([setppriv],
 250                [AC_CHECK_HEADER([priv.h],
 251                                 [AC_DEFINE([HAVE_DROP_PRIVILEGES],
 252                                            [1],
 253                                            [Define this if you have an implementation of drop_privileges()])
 254                                 build_solaris_privs=yes])
 255                ])
 256
 257 AM_CONDITIONAL([BUILD_POLL],[test "x$ac_cv_header_poll_h" = "xno"])
 258 AM_CONDITIONAL([BUILD_WIN32_WRAPPERS],[test "x$ac_cv_header_winsock2_h" = "xyes"])
 259 AS_IF([test "x$ac_cv_header_winsock2_h" = "xyes"],
 260       [AM_LDFLAGS="$AM_LDFLAGS -lws2_32"
 261        AM_CFLAGS="$AM_CFLAGS $NO_WERROR"
 262        AM_CXXFLAGS="$AM_CXXFLAGS $NO_WERROR"
 263        ])
 264 SOCKET_SEND_FLAGS
 265
 266 AX_UUID_GENERATE_TIME_SAFE
 267
 268 AC_DEFUN([CHECK_FOR_PTHREAD_AND_SASL],
 269          [AX_PTHREAD(, [AC_MSG_ERROR([could not find libpthread])])
 270          AX_PTHREAD_TIMEDJOIN_NP
 271
 272          # The sasl functions should only be visible if we build with sasl support
 273          #
 274          AX_SASL_OPTION
 275          AS_IF([test "x$ac_enable_sasl" = xyes],
 276                [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 1"],
 277                [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 0"])
 278          AC_SUBST([LIBMEMCACHED_WITH_SASL_SUPPORT])
 279          ])
 280 CHECK_FOR_PTHREAD_AND_SASL
 281
 282
 283 # backtrace(), others require shared builds
 284 AS_IF([test "x$enable_shared" = "xyes"],
 285       [AC_DEFINE([HAVE_SHARED_ENABLED],[1],[Enable code which requires shared library support. Like backtrace().])])
 286 AM_CONDITIONAL([SHARED_ENABLED],[test "x$enable_shared" = "xyes"])
 287
 288 PANDORA_ENABLE_DTRACE
 289 HAVE_GCC_ATOMICS
 290 AX_ENDIAN
 291 AX_ASSERT
 292 AX_HARDEN_COMPILER_FLAGS
 293
 294 AX_AM_JOBSERVER([yes])
 295
 296 AC_CONFIG_FILES([Makefile
 297                  docs/conf.py
 298                  libmemcached-1.0/configure.h
 299                  support/libmemcached.pc
 300                  support/libmemcached.spec
 301                  ])
 302 AC_OUTPUT
 303
 304 echo "---"
 305 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 306 echo ""
 307 echo "   * Installation prefix:       $prefix"
 308 echo "   * System type:               $host_vendor-$host_os"
 309 echo "   * Host CPU:                  $host_cpu"
 310 echo "   * C Compiler:                $CC_VERSION"
 311 echo "   * C Flags:                   $CFLAGS"
 312 echo "   * C++ Compiler:              $CXX_VERSION"
 313 echo "   * C++ Flags:                 $CXXFLAGS"
 314 echo "   * CPP Flags:                 $CPPFLAGS"
 315 echo "   * LIB Flags:                 $LIB"
 316 echo "   * Assertions enabled:        $ax_enable_assert"
 317 echo "   * Debug enabled:             $ax_enable_debug"
 318 echo "   * Shared:                    $enable_shared"
 319 echo "   * Warnings as failure:       $ac_cv_warnings_as_errors"
 320 echo "   * SASL support:              $ax_sasl_option"
 321 echo "   * make -j:                   $enable_jobserver"
 322 echo "   * VCS checkout:              $ac_cv_vcs_checkout"
 323 echo ""
 324 echo "---"
 325
 326 case "$host_os" in
 327   *freebsd*)
 328     echo "*****"
 329     echo "*"
 330     echo "*  NOTE: You are on FreeBSD. BSD make will not work."
 331     echo "*"
 332     echo "*   use 'gmake' To build libmemcached"
 333     echo "*"
 334     echo "*****"
 335   ;;
 336 esac
 337