git.m6w6.name Git - m6w6/libmemcached/blob - CPack.txt

   1 # default options
   2
   3 set(CPACK_ARCHIVE_COMPONENT_INSTALL ${CPACK_COMPONENT_INSTALL})
   4 set(CPACK_SOURCE_IGNORE_FILES "/[.]git/;/[.](idea|settings|c?project);~$;[.]log$;[.]bak$")
   5
   6 macro(cpack_include_if GENERATOR)
   7     message(STATUS "Checking ${GENERATOR} package configuration ...")
   8     if(EXISTS ${CMAKE_SOURCE_DIR}/CPack/${GENERATOR}.txt)
   9         include(${CMAKE_SOURCE_DIR}/CPack/${GENERATOR}.txt)
  10     endif()
  11 endmacro()
  12
  13 # shell installer
  14 set(CPACK_BINARY_STGZ ${UNIX})
  15
  16 # binary archive
  17 set(CPACK_BINARY_TBZ2 0)
  18 set(CPACK_BINARY_TGZ ${UNIX})
  19 set(CPACK_BINARY_TXZ 0)
  20 set(CPACK_BINARY_TZ 0)
  21 set(CPACK_BINARY_ZIP ${WIN32})
  22 set(CPACK_BINARY_NSIS ${WIN32})
  23 set(CPACK_BINARY_NUGET 0)
  24
  25 # source archive
  26 set(CPACK_SOURCE_TBZ2 0)
  27 set(CPACK_SOURCE_TGZ ${UNIX})
  28 set(CPACK_SOURCE_TXZ 0)
  29 set(CPACK_SOURCE_TZ 0)
  30 set(CPACK_SOURCE_ZIP ${WIN32})
  31
  32 # project internals
  33 set(CPACK_PACKAGE_LICENSE "BSD-3-Clause")
  34 set(CPACK_PACKAGE_CONTACT "${PROJECT_CONTACT}")
  35 set(CPACK_PACKAGE_VENDOR "${PROJECT_CONTACT}")
  36 set(CPACK_PACKAGE_DESCRIPTION
  37         "libmemcached is an open source C/C++ client library and tools for the
  38 memcached server (http://memcached.org/). It has been designed to be
  39 light on memory usage, thread safe, and provide full access to server
  40 side methods.")
  41 if(CMAKE_VERSION VERSION_LESS 3.12)
  42     string(REPLACE ";" "-" CPACK_PACKAGE_DIRECTORY "${PROJECT_CONFIG}")
  43 else()
  44     list(JOIN PROJECT_CONFIG "-" CPACK_PACKAGE_DIRECTORY)
  45 endif()
  46 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPack/ProjectConfig.txt")
  47 set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_SOURCE_DIR}/README.md")
  48 set(CPACK_PACKAGE_INSTALL_DIRECTORY "${PROJECT_NAME}/${PROJECT_VERSION}")
  49 set(CPACK_PACKAGE_CHECKSUM SHA1)
  50 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/LICENSE")
  51 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/README.md")
  52 set(CPACK_CHANGELOG_FILE "${CMAKE_SOURCE_DIR}/ChangeLog-1.1.md")
  53
  54 execute_process(
  55         COMMAND git describe --tags --match [0-9]*.*
  56         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
  57         OUTPUT_VARIABLE PROJECT_TAG
  58         ERROR_VARIABLE GIT_ERROR_OUTPUT
  59 )
  60 if(GIT_ERROR_OUTPUT)
  61     message(NOTICE "git describe: ${GIT_ERROR_OUTPUT}")
  62 endif()
  63 string(STRIP "${PROJECT_TAG}" PROJECT_TAG)
  64 if(PROJECT_TAG)
  65     set(CPACK_PACKAGE_FILE_NAME ${PROJECT_NAME}-${PROJECT_TAG})
  66 else()
  67     set(CPACK_PACKAGE_FILE_NAME ${PROJECT_NAME}-${PROJECT_VERSION})
  68 endif()
  69
  70 # dependencies
  71 if(HAVE_LIBSASL)
  72     string(APPEND CPACK_PACKAGE_DEPENDS " libsasl2")
  73 endif()
  74 if(HAVE_TBB)
  75     string(APPEND CPACK_PACKAGE_DEPENDS " tbb")
  76 endif()
  77 if(HAVE_LIBEVENT)
  78     string(APPEND CPACK_PACKAGE_DEPENDS " libevent")
  79 endif()
  80
  81 # DEBs
  82 find_program(DPKG dpkg)
  83 if(DPKG)
  84     cpack_include_if(DEB)
  85 endif()
  86
  87 # WIN
  88 if(WIN32)
  89     cpack_include_if(NSIS)
  90 endif()
  91
  92 # RPMs
  93 find_program(RPMBUILD rpmbuild)
  94 if(RPMBUILD)
  95     cpack_include_if(RPM)
  96 endif()
  97
  98 # keep last
  99 include(CPack)
 100
 101 set(PUSH_ARTIFACTS_SH "${CMAKE_SOURCE_DIR}/scripts/push-artifacts.sh")
 102 if(WIN32)
 103     set(PUSH_ARTIFACTS_CMD msys2 -c '${PUSH_ARTIFACTS_SH} ${CPACK_PACKAGE_DIRECTORY}/')
 104 else()
 105     set(PUSH_ARTIFACTS_CMD ${PUSH_ARTIFACTS_SH} ${CPACK_PACKAGE_DIRECTORY}/)
 106 endif()
 107
 108 add_custom_target(push-artifacts
 109         COMMAND ${PUSH_ARTIFACTS_CMD}
 110         WORKING_DIRECTORY ${CPACK_BINARY_DIR}
 111         )
 112