git.m6w6.name Git - m6w6/libmemcached/blob - CMake/_Include.cmake

   1
   2 # globals
   3 if(CMAKE_PROJECT_NAME STREQUAL PROJECT_NAME)
   4     include(CTest)
   5 endif()
   6 include(GNUInstallDirs)
   7 include(CMakePackageConfigHelpers)
   8
   9 if(CMAKE_HOST_SYSTEM_NAME MATCHES "BSD")
  10     find_program(PKGCONF pkgconf)
  11     if(PKGCONF)
  12         set(PKG_CONFIG_EXECUTABLE ${PKGCONF})
  13     endif()
  14 endif()
  15 find_package(PkgConfig)
  16 set(THREADS_PREFER_PTHREAD_FLAG ON)
  17 find_package(Threads REQUIRED)
  18
  19 # locals
  20 include(InstallPublicHeaders)
  21 include(SafeString)
  22 include(CheckDebug)
  23 include(CheckDecl)
  24 include(CheckDependency)
  25 include(CheckHeader)
  26 include(CheckCompiles)
  27 include(CheckType)
  28 include(TestBigEndian)
  29 include(CheckByteswap)
  30
  31 # configuration
  32
  33 ## debug
  34 check_debug()
  35
  36 ## dtrace
  37 include(EnableDtrace)
  38 if(ENABLE_DTRACE)
  39     find_package(DTrace)
  40     if(DTRACE_EXECUTABLE)
  41         set(HAVE_DTRACE 1)
  42     else()
  43         message(WARNING "The dtrace command is required to enable dtrace/systemtap support.")
  44     endif()
  45 endif()
  46
  47 ## sasl
  48 if(ENABLE_SASL)
  49     check_dependency(LIBSASL sasl2 sasl/sasl.h)
  50     if(HAVE_LIBSASL)
  51         set(LIBMEMCACHED_WITH_SASL_SUPPORT 1)
  52     endif()
  53 endif()
  54
  55 ## hashes
  56 if(ENABLE_HASH_FNV64)
  57     set(HAVE_FNV64_HASH 1)
  58 endif()
  59 if(ENABLE_HASH_MURMUR)
  60     set(HAVE_MURMUR_HASH 1)
  61 endif()
  62 if(ENABLE_HASH_HSIEH)
  63     set(HAVE_HSIEH_HASH 1)
  64 endif()
  65
  66 # system checks
  67
  68 test_big_endian(WORDS_BIGENDIAN)
  69 check_byteswap()
  70
  71 # most of the following checks are due to mingw or msvc; see gnulib
  72 check_header(arpa/inet.h)
  73 check_header(dlfcn.h)
  74 check_header(netdb.h)
  75 check_header(poll.h)
  76 check_header(strings.h)
  77 check_header(sys/socket.h)
  78 check_header(sys/time.h)
  79 check_header(sys/un.h)
  80 check_header(time.h)
  81 check_header(unistd.h)
  82
  83 if(WIN32)
  84     check_header(io.h)
  85     check_header(winsock2.h)
  86     check_header(ws2tcpip.h)
  87 endif()
  88
  89 check_decl(abi::__cxa_demangle cxxabi.h)
  90 check_decl(fcntl fcntl.h)
  91 check_decl(htonll arpa/inet.h)
  92 check_decl(MSG_DONTWAIT sys/socket.h)
  93 check_decl(MSG_MORE sys/socket.h)
  94 check_decl(MSG_NOSIGNAL sys/socket.h)
  95 check_decl(SO_RCVTIMEO sys/socket.h)
  96 check_decl(SO_SNDTIMEO sys/socket.h)
  97 check_decl(setenv stdlib.h)
  98 check_decl(strerror string.h)
  99 check_decl(strerror_r string.h)
 100
 101 check_type(in_port_t netinet/in.h)
 102
 103 check_compiles(HAVE_STRERROR_R_CHAR_P "
 104         char x, y = *strerror_r(0,&x,1);"
 105         string.h)
 106
 107
 108 find_package(Backtrace)
 109 if(Backtrace_FOUND)
 110     set(HAVE_BACKTRACE 1)
 111     set(BACKTRACE BACKTRACE)
 112     add_library(BACKTRACE INTERFACE IMPORTED)
 113     set_target_properties(BACKTRACE PROPERTIES
 114             INTERFACE_LINK_LIBRARIES "${Backtrace_LIBRARIES}"
 115             INTERFACE_INCLUDE_DIRECTORIES "${Backtrace_INCLUDE_DIR}")
 116 endif()
 117