git.m6w6.name Git - m6w6/libmemcached/blob - CMake/_Include.cmake

   1
   2 # globals
   3 if(CMAKE_PROJECT_NAME STREQUAL PROJECT_NAME)
   4     include(CTest)
   5 endif()
   6 include(GNUInstallDirs)
   7 include(CMakePackageConfigHelpers)
   8
   9 if(CMAKE_HOST_SYSTEM_NAME MATCHES "BSD")
  10     find_program(PKGCONF pkgconf)
  11     if(PKGCONF)
  12         set(PKG_CONFIG_EXECUTABLE ${PKGCONF})
  13     endif()
  14 endif()
  15 find_package(PkgConfig)
  16 set(THREADS_PREFER_PTHREAD_FLAG ON)
  17 find_package(Threads REQUIRED)
  18
  19 # locals
  20 include(InstallPublicHeaders)
  21 include(SafeString)
  22 include(CheckDebug)
  23 include(CheckDecl)
  24 include(CheckDependency)
  25 include(CheckHeader)
  26 include(CheckCompiles)
  27 include(CheckType)
  28 include(TestBigEndian)
  29 include(CheckByteswap)
  30
  31 # configuration
  32
  33 ## debug
  34 check_debug()
  35
  36 ## dtrace
  37 include(EnableDtrace)
  38 if(ENABLE_DTRACE)
  39     find_package(DTrace)
  40     if(DTRACE_EXECUTABLE)
  41         set(HAVE_DTRACE 1)
  42     else()
  43         message(WARNING "The dtrace command is required to enable dtrace/systemtap support.")
  44     endif()
  45 endif()
  46
  47 ## uuid
  48 if(BUILD_TESTING)
  49     if(NOT MEMCACHED_BINARY)
  50         find_package(Memcached)
  51         set(MEMCACHED_BINARY ${MEMCACHED_EXECUTABLE})
  52     endif()
  53 endif()
  54
  55 ## sasl
  56 if(ENABLE_SASL)
  57     check_dependency(LIBSASL sasl2 sasl/sasl.h)
  58     if(HAVE_LIBSASL)
  59         set(LIBMEMCACHED_WITH_SASL_SUPPORT 1)
  60     endif()
  61 endif()
  62
  63 ## hashes
  64 if(ENABLE_HASH_FNV64)
  65     set(HAVE_FNV64_HASH 1)
  66 endif()
  67 if(ENABLE_HASH_MURMUR)
  68     set(HAVE_MURMUR_HASH 1)
  69 endif()
  70 if(ENABLE_HASH_HSIEH)
  71     set(HAVE_HSIEH_HASH 1)
  72 endif()
  73
  74 # system checks
  75
  76 test_big_endian(WORDS_BIGENDIAN)
  77 check_byteswap()
  78
  79 check_header(alloca.h)
  80 check_header(arpa/inet.h)
  81 check_header(dlfcn.h)
  82 check_header(errno.h)
  83 check_header(fcntl.h)
  84 check_header(io.h)
  85 check_header(limits.h)
  86 check_header(netdb.h)
  87 check_header(poll.h)
  88 check_header(stddef.h)
  89 check_header(stdlib.h)
  90 check_header(strings.h)
  91 check_header(sys/socket.h)
  92 check_header(sys/time.h)
  93 check_header(sys/types.h)
  94 check_header(sys/un.h)
  95 check_header(sys/wait.h)
  96 check_header(time.h)
  97 check_header(umem.h)
  98 check_header(unistd.h)
  99 check_header(winsock2.h)
 100 check_header(ws2tcpip.h)
 101
 102 check_decl(fcntl fcntl.h)
 103 check_decl(htonll arpa/inet.h)
 104 check_decl(MSG_DONTWAIT sys/socket.h)
 105 check_decl(MSG_MORE sys/socket.h)
 106 check_decl(MSG_NOSIGNAL sys/socket.h)
 107 check_decl(SO_RCVTIMEO sys/socket.h)
 108 check_decl(SO_SNDTIMEO sys/socket.h)
 109 check_decl(setenv stdlib.h)
 110 check_decl(strerror string.h)
 111 check_decl(strerror_r string.h)
 112
 113 check_compiles(HAVE_STRERROR_R_CHAR_P "char x, y = *strerror_r(0,&x,1);" string.h)
 114
 115 check_decl(abi::__cxa_demangle cxxabi.h)
 116
 117 find_package(Backtrace)
 118 if(Backtrace_FOUND)
 119     set(HAVE_BACKTRACE 1)
 120     set(BACKTRACE BACKTRACE)
 121     add_library(BACKTRACE INTERFACE IMPORTED)
 122     set_target_properties(BACKTRACE PROPERTIES
 123             INTERFACE_LINK_LIBRARIES "${Backtrace_LIBRARIES}"
 124             INTERFACE_INCLUDE_DIRECTORIES "${Backtrace_INCLUDE_DIR}")
 125 endif()
 126
 127 check_type(in_port_t netinet/in.h)
 128
 129 check_header(cstdint)
 130 check_header(cinttypes)
 131 check_header(inttypes.h)