git.m6w6.name Git - m6w6/ext-psi/blob - src/parser_proc_grammar.y

   1 %code top {
   2 #include "php_psi_stdinc.h"
   3 }
   4
   5 %code {
   6 #include <assert.h>
   7 #include <stdarg.h>
   8 #include <fnmatch.h>
   9
  10 #include "php_psi.h"
  11
  12 #include "plist.h"
  13 #include "parser.h"
  14
  15 #define YYDEBUG 1
  16 #define PSI_PARSER_PROC_DEBUG 1
  17
  18 static int psi_parser_proc_lex(YYSTYPE *u, struct psi_parser *P, struct psi_plist *tokens, size_t *index);
  19 static void psi_parser_proc_error(struct psi_parser *P, struct psi_plist *tokens, size_t *index, const char *msg);
  20
  21 static inline void psi_parser_proc_add_struct(struct psi_parser *P, struct psi_decl_struct *strct)
  22 {
  23         assert(strct);
  24         if (!P->structs) {
  25                 P->structs = psi_plist_init((psi_plist_dtor) psi_decl_struct_free);
  26         }
  27         P->structs = psi_plist_add(P->structs, &strct);
  28 }
  29 static inline void psi_parser_proc_add_union(struct psi_parser *P, struct psi_decl_union *u)
  30 {
  31         assert(u);
  32         if (!P->unions) {
  33                 P->unions = psi_plist_init((psi_plist_dtor) psi_decl_union_free);
  34         }
  35         P->unions = psi_plist_add(P->unions, &u);
  36 }
  37 static inline void psi_parser_proc_add_enum(struct psi_parser *P, struct psi_decl_enum *e)
  38 {
  39         assert(e);
  40         if (!P->enums) {
  41                 P->enums = psi_plist_init((psi_plist_dtor) psi_decl_enum_free);
  42         }
  43         P->enums = psi_plist_add(P->enums, &e);
  44 }
  45 static inline void psi_parser_proc_add_typedef(struct psi_parser *P, struct psi_decl_arg *def)
  46 {
  47         assert(def);
  48         if (!P->types) {
  49                 P->types = psi_plist_init((psi_plist_dtor) psi_decl_arg_free);
  50         }
  51         P->types = psi_plist_add(P->types, &def);
  52 }
  53 static inline void psi_parser_proc_add_const(struct psi_parser *P, struct psi_const *cnst) {
  54         assert(cnst);
  55         if (!P->consts) {
  56                 P->consts = psi_plist_init((psi_plist_dtor) psi_const_free);
  57         }
  58         P->consts = psi_plist_add(P->consts, &cnst);
  59
  60 }
  61 static inline void psi_parser_proc_add_decl(struct psi_parser *P, struct psi_decl *decl) {
  62         char *blacklisted;
  63         size_t i = 0;
  64
  65         assert(decl);
  66
  67         while (psi_plist_get(PSI_G(blacklist).decls, i++, &blacklisted)) {
  68                 if (!fnmatch(blacklisted, decl->func->var->name, 0)) {
  69                         psi_decl_free(&decl);
  70                         return;
  71                 }
  72         }
  73
  74         if (!P->decls) {
  75                 P->decls = psi_plist_init((psi_plist_dtor) psi_decl_free);
  76         }
  77         P->decls = psi_plist_add(P->decls, &decl);
  78 }
  79 static inline void psi_parser_proc_add_impl(struct psi_parser *P, struct psi_impl *impl) {
  80         assert(impl);
  81         if (!P->impls) {
  82                 P->impls = psi_plist_init((psi_plist_dtor) psi_impl_free);
  83         }
  84         P->impls = psi_plist_add(P->impls, &impl);
  85 }
  86
  87 /* end code */
  88 }
  89
  90 %code requires {
  91 #include "plist.h"
  92 #include "types/layout.h"
  93
  94 struct psi_parser;
  95
  96 }
  97
  98 %require "3.0"
  99 %language "c"
 100 %name-prefix "psi_parser_proc_"
 101 %token-table
 102 %verbose
 103 %glr-parser
 104
 105 %param {struct psi_parser *P} {struct psi_plist *tokens} {size_t *index}
 106
 107 %define api.pure true
 108 %define api.token.prefix {PSI_T_}
 109 %define api.value.type union
 110
 111 %define parse.error verbose
 112 %define parse.trace true
 113
 114 %initial-action {
 115 }
 116
 117 %start file
 118
 119 %token <struct psi_token *> BOOL
 120 %token <struct psi_token *> CHAR
 121 %token <struct psi_token *> SHORT
 122 %token <struct psi_token *> INT
 123 %token <struct psi_token *> SIGNED
 124 %token <struct psi_token *> UNSIGNED
 125 %token <struct psi_token *> LONG
 126 %token <struct psi_token *> FLOAT
 127 %token <struct psi_token *> DOUBLE
 128 %token <struct psi_token *> STRING
 129 %token <struct psi_token *> MIXED
 130 %token <struct psi_token *> ARRAY
 131 %token <struct psi_token *> OBJECT
 132 %token <struct psi_token *> CALLABLE
 133 %token <struct psi_token *> VOID
 134 %token <struct psi_token *> ZVAL
 135 %token <struct psi_token *> INT8
 136 %token <struct psi_token *> UINT8
 137 %token <struct psi_token *> INT16
 138 %token <struct psi_token *> UINT16
 139 %token <struct psi_token *> INT32
 140 %token <struct psi_token *> UINT32
 141 %token <struct psi_token *> INT64
 142 %token <struct psi_token *> UINT64
 143 %token <struct psi_token *> NULL
 144 %token <struct psi_token *> TRUE
 145 %token <struct psi_token *> FALSE
 146 %token <struct psi_token *> NAME
 147 %token <struct psi_token *> NSNAME
 148 %token <struct psi_token *> DOLLAR_NAME
 149 %token <struct psi_token *> NUMBER
 150 %token <struct psi_token *> QUOTED_STRING
 151 %token <struct psi_token *> QUOTED_CHAR
 152 %token <struct psi_token *> SIZEOF
 153 %token <struct psi_token *> VOLATILE
 154
 155 %token <struct psi_token *> EOF 0               "end of file"
 156 %token <struct psi_token *> EOL                 "end of line"
 157 %token <struct psi_token *> EOS                 ";"
 158 %token <struct psi_token *> LPAREN              "("
 159 %token <struct psi_token *> RPAREN              ")"
 160 %token <struct psi_token *> COMMA               ","
 161 %token <struct psi_token *> COLON               ":"
 162 %token <struct psi_token *> LBRACE              "{"
 163 %token <struct psi_token *> RBRACE              "}"
 164 %token <struct psi_token *> LBRACKET    "["
 165 %token <struct psi_token *> RBRACKET    "]"
 166 %token <struct psi_token *> EQUALS              "="
 167 %token <struct psi_token *> HASH                "#"
 168 %token <struct psi_token *> PIPE                "|"
 169 %token <struct psi_token *> CARET               "^"
 170 %token <struct psi_token *> AMPERSAND   "&"
 171 %token <struct psi_token *> LSHIFT              "<<"
 172 %token <struct psi_token *> RSHIFT              ">>"
 173 %token <struct psi_token *> PLUS                "+"
 174 %token <struct psi_token *> MINUS               "-"
 175 %token <struct psi_token *> ASTERISK    "*"
 176 %token <struct psi_token *> SLASH               "/"
 177 %token <struct psi_token *> MODULO              "%"
 178 %token <struct psi_token *> LCHEVR              "<"
 179 %token <struct psi_token *> RCHEVR              ">"
 180 %token <struct psi_token *> CMP_GE              ">="
 181 %token <struct psi_token *> CMP_LE              "<="
 182 %token <struct psi_token *> OR                  "||"
 183 %token <struct psi_token *> AND                 "&&"
 184 %token <struct psi_token *> CMP_EQ              "=="
 185 %token <struct psi_token *> CMP_NE              "!="
 186 %token <struct psi_token *> TILDE               "~"
 187 %token <struct psi_token *> NOT                 "!"
 188 %token <struct psi_token *> PERIOD              "."
 189 %token <struct psi_token *> BACKSLASH   "\\"
 190 %token <struct psi_token *> ELLIPSIS    "..."
 191 %token <struct psi_token *> IIF                 "?"
 192
 193 %token <struct psi_token *> PRAGMA
 194 %token <struct psi_token *> PRAGMA_ONCE
 195 %token <struct psi_token *> LINE
 196 %token <struct psi_token *> ERROR
 197 %token <struct psi_token *> WARNING
 198 %token <struct psi_token *> IF
 199 %token <struct psi_token *> IFDEF
 200 %token <struct psi_token *> IFNDEF
 201 %token <struct psi_token *> ELSE
 202 %token <struct psi_token *> ELIF
 203 %token <struct psi_token *> ENDIF
 204 %token <struct psi_token *> DEFINE
 205 %token <struct psi_token *> DEFINED
 206 %token <struct psi_token *> UNDEF
 207 %token <struct psi_token *> IMPORT
 208 %token <struct psi_token *> INCLUDE
 209 %token <struct psi_token *> INCLUDE_NEXT
 210
 211 %token <struct psi_token *> TYPEDEF
 212 %token <struct psi_token *> STRUCT
 213 %token <struct psi_token *> UNION
 214 %token <struct psi_token *> ENUM
 215 %token <struct psi_token *> CONST
 216 %token <struct psi_token *> LIB
 217 %token <struct psi_token *> STATIC
 218 %token <struct psi_token *> CALLBACK
 219 %token <struct psi_token *> FUNCTION
 220 %token <struct psi_token *> LET
 221 %token <struct psi_token *> SET
 222 %token <struct psi_token *> TEMP
 223 %token <struct psi_token *> FREE
 224 %token <struct psi_token *> RETURN
 225 %token <struct psi_token *> PRE_ASSERT
 226 %token <struct psi_token *> POST_ASSERT
 227 %token <struct psi_token *> BOOLVAL
 228 %token <struct psi_token *> INTVAL
 229 %token <struct psi_token *> STRVAL
 230 %token <struct psi_token *> PATHVAL
 231 %token <struct psi_token *> STRLEN
 232 %token <struct psi_token *> FLOATVAL
 233 %token <struct psi_token *> ARRVAL
 234 %token <struct psi_token *> OBJVAL
 235 %token <struct psi_token *> COUNT
 236 %token <struct psi_token *> CALLOC
 237 %token <struct psi_token *> TO_BOOL
 238 %token <struct psi_token *> TO_INT
 239 %token <struct psi_token *> TO_STRING
 240 %token <struct psi_token *> TO_FLOAT
 241 %token <struct psi_token *> TO_ARRAY
 242 %token <struct psi_token *> TO_OBJECT
 243
 244 %token <struct psi_token *> COMMENT
 245 %token <struct psi_token *> WHITESPACE
 246 %token <struct psi_token *> NO_WHITESPACE
 247 %token <struct psi_token *> CPP_HEADER
 248 %token <struct psi_token *> CPP_ATTRIBUTE
 249 %token <struct psi_token *> CPP_EXTENSION
 250 %token <struct psi_token *> CPP_PASTE
 251 %token <struct psi_token *> CPP_INLINE
 252 %token <struct psi_token *> CPP_RESTRICT
 253 %token <struct psi_token *> CPP_ASM
 254
 255 %precedence IIF COLON
 256 %precedence OR
 257 %precedence AND
 258 %precedence PIPE
 259 %precedence CARET
 260 %precedence AMPERSAND
 261 %precedence CMP_EQ CMP_NE
 262 %precedence LCHEVR CMP_LE RCHEVR CMP_GE
 263 %precedence LSHIFT RSHIFT
 264 %precedence PLUS MINUS
 265 %precedence ASTERISK SLASH MODULO
 266 //%precedence NOT TILDE
 267 %precedence BINARY
 268 %precedence UNARY
 269
 270 %type           <struct psi_token *>                            lib optional_name enum_name struct_name union_name
 271 %destructor     {psi_token_free(&$$);}                          lib optional_name enum_name struct_name union_name
 272
 273 %type           <struct psi_token *>                            cpp_message_token cpp_include_token cpp_header_token cpp_no_arg_token cpp_name_arg_token cpp_exp_arg_token cpp_special_name_token
 274 %destructor     {}                                                                      cpp_message_token cpp_include_token cpp_header_token cpp_no_arg_token cpp_name_arg_token cpp_exp_arg_token cpp_special_name_token
 275
 276 %type           <struct psi_token *>                            name_token any_noeol_token binary_op_token unary_op_token
 277 %destructor     {}                                                                      name_token any_noeol_token binary_op_token unary_op_token
 278
 279 %type           <struct psi_token *>                            int_width int_width_types int_signed_types
 280 %destructor     {psi_token_free(&$$);}                          int_width int_width_types int_signed_types
 281
 282 %type           <struct psi_token *>                            signed_long_types signed_short_types int_signed
 283 %destructor     {}                                                                      signed_long_types signed_short_types int_signed
 284
 285 %type           <struct psi_cpp_exp *>                          cpp cpp_exp
 286 %destructor     {psi_cpp_exp_free(&$$);}                        cpp cpp_exp
 287 %type           <struct psi_cpp_macro_decl *>           cpp_macro_decl
 288 %destructor     {psi_cpp_macro_decl_free(&$$);}         cpp_macro_decl
 289 %type           <struct psi_plist *>                            cpp_macro_sig cpp_macro_sig_args cpp_macro_decl_tokens cpp_macro_decl_token_list cpp_macro_call_args cpp_macro_call_arg_list
 290 %destructor {psi_plist_free($$);}                               cpp_macro_sig cpp_macro_sig_args cpp_macro_decl_tokens cpp_macro_decl_token_list cpp_macro_call_args cpp_macro_call_arg_list
 291 %type           <struct psi_num_exp *>                          cpp_macro_exp
 292 %destructor     {psi_num_exp_free(&$$);}                        cpp_macro_exp
 293
 294 %type           <struct psi_token *>                            constant_type_token impl_def_val_token
 295 %destructor     {}                                                                      constant_type_token impl_def_val_token
 296
 297 %type           <struct psi_const *>                            constant
 298 %destructor     {psi_const_free(&$$);}                          constant
 299 %type           <struct psi_const_type *>                       constant_type
 300 %destructor     {psi_const_type_free(&$$);}                     constant_type
 301 %type           <struct psi_impl_def_val *>                     impl_def_val
 302 %destructor     {psi_impl_def_val_free(&$$);}           impl_def_val
 303
 304 %type           <struct psi_token *>                            decl_real_type decl_int_type decl_type_simple
 305 %destructor     {psi_token_free(&$$);}                          decl_real_type decl_int_type decl_type_simple
 306
 307 %type           <struct psi_token *>                            decl_stdint_type
 308 %destructor     {}                                                                      decl_stdint_type
 309
 310 %type           <struct psi_decl_type *>                        decl_type qualified_decl_type decl_type_complex
 311 %destructor     {psi_decl_type_free(&$$);}                      decl_type qualified_decl_type decl_type_complex
 312 %type           <struct psi_decl *>                                     decl_stmt decl decl_body decl_func_body decl_functor_body
 313 %destructor     {psi_decl_free(&$$);}                           decl_stmt decl decl_body decl_func_body decl_functor_body
 314 %type           <struct psi_decl_arg *>                         decl_typedef decl_func decl_functor decl_arg decl_anon_arg typedef typedef_decl typedef_anon typedef_anon_decl
 315 %destructor     {psi_decl_arg_free(&$$);}                       decl_typedef decl_func decl_functor decl_arg decl_anon_arg typedef typedef_decl typedef_anon typedef_anon_decl
 316 %type           <struct psi_decl_var *>                         decl_var
 317 %destructor     {psi_decl_var_free(&$$);}                       decl_var
 318 %type           <struct psi_decl_struct *>                      decl_struct
 319 %destructor     {psi_decl_struct_free(&$$);}            decl_struct
 320 %type           <struct psi_decl_union *>                       decl_union
 321 %destructor     {psi_decl_union_free(&$$);}                     decl_union
 322 %type           <struct psi_decl_enum *>                        decl_enum
 323 %destructor     {psi_decl_enum_free(&$$);}                      decl_enum
 324 %type           <struct psi_decl_enum_item *>           decl_enum_item
 325 %destructor     {psi_decl_enum_item_free(&$$);}         decl_enum_item
 326 %type           <struct psi_plist *>                            decl_args decl_struct_args struct_args_block struct_args struct_arg_var_list decl_enum_items decl_vars decl_vars_with_layout
 327 %destructor     {psi_plist_free($$);}                           decl_args decl_struct_args struct_args_block struct_args struct_arg_var_list decl_enum_items decl_vars decl_vars_with_layout
 328
 329 %type           <struct psi_layout>                                     align_and_size
 330 %destructor     {}                                                                      align_and_size
 331 %type           <struct psi_layout *>                           decl_layout
 332 %destructor     {psi_layout_free(&$$);}                         decl_layout
 333
 334 %type           <struct psi_number *>                           sizeof sizeof_body sizeof_body_notypes
 335 %destructor     {psi_number_free(&$$);}                         sizeof sizeof_body sizeof_body_notypes
 336
 337 %type           <struct psi_impl *>                                     impl
 338 %destructor     {psi_impl_free(&$$);}                           impl
 339 %type           <struct psi_impl_func *>                        impl_func
 340 %destructor     {psi_impl_func_free(&$$);}                      impl_func
 341 %type           <struct psi_impl_arg *>                         impl_arg
 342 %destructor     {psi_impl_arg_free(&$$);}                       impl_arg
 343 %type           <struct psi_impl_type *>                        impl_type
 344 %destructor     {psi_impl_type_free(&$$);}                      impl_type
 345 %type           <struct psi_impl_var *>                         impl_var
 346 %destructor     {psi_impl_var_free(&$$);}                       impl_var
 347
 348 %type           <struct psi_let_stmt *>                         let_stmt
 349 %destructor     {psi_let_stmt_free(&$$);}                       let_stmt
 350 %type           <struct psi_let_exp *>                          let_exp let_exp_byref let_exp_assign
 351 %destructor     {psi_let_exp_free(&$$);}                        let_exp let_exp_byref let_exp_assign
 352 %type           <struct psi_let_calloc *>                       let_calloc
 353 %destructor     {psi_let_calloc_free(&$$);}                     let_calloc
 354 %type           <struct psi_let_callback *>                     let_callback
 355 %destructor     {psi_let_callback_free(&$$);}           let_callback
 356 %type           <struct psi_let_func *>                         let_func
 357 %destructor     {psi_let_func_free(&$$);}                       let_func
 358 %type           <struct psi_set_stmt *>                         set_stmt
 359 %destructor     {psi_set_stmt_free(&$$);}                       set_stmt
 360 %type           <struct psi_set_exp *>                          set_exp
 361 %destructor     {psi_set_exp_free(&$$);}                        set_exp
 362 %type           <struct psi_set_func *>                         set_func
 363 %destructor     {psi_set_func_free(&$$);}                       set_func
 364 %type           <struct psi_assert_stmt *>                      assert_stmt
 365 %destructor     {psi_assert_stmt_free(&$$);}            assert_stmt
 366 %type           <struct psi_return_stmt *>                      return_stmt
 367 %destructor     {psi_return_stmt_free(&$$);}            return_stmt
 368 %type           <struct psi_free_stmt *>                        free_stmt
 369 %destructor     {psi_free_stmt_free(&$$);}                      free_stmt
 370 %type           <struct psi_free_exp *>                         free_exp
 371 %destructor     {psi_free_exp_free(&$$);}                       free_exp
 372
 373 %type           <struct psi_token **>                           impl_stmt
 374 %destructor     {psi_impl_stmt_free(&$$);}                      impl_stmt
 375 %type           <struct psi_token *>                            impl_type_token callback_rval let_func_token set_func_token assert_stmt_token
 376 %destructor     {psi_token_free(&$$);}                          impl_type_token callback_rval let_func_token set_func_token assert_stmt_token
 377 %type           <struct psi_plist *>                            impl_args impl_stmts let_exps let_func_exps callback_arg_list callback_args set_exps set_func_exps free_exps
 378 %destructor     {psi_plist_free($$);}                           impl_args impl_stmts let_exps let_func_exps callback_arg_list callback_args set_exps set_func_exps free_exps
 379
 380 %type           <struct psi_num_exp *>                          num_exp
 381 %destructor     {psi_num_exp_free(&$$);}                        num_exp
 382 %type           <struct psi_number *>                           number
 383 %destructor     {psi_number_free(&$$);}                         number
 384
 385 %type           <size_t>                                                        indirection pointers asterisks array_size
 386 %destructor     {}                                                                      indirection pointers asterisks array_size
 387 %type           <bool>                                                          reference
 388 %destructor     {}                                                                      reference
 389
 390 %%
 391
 392 /* rules */
 393
 394
 395 binary_op_token: PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | RCHEVR | LCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE ;
 396 unary_op_token: TILDE | NOT | PLUS | MINUS ;
 397 name_token: NAME | FUNCTION | TEMP | FREE | SET | LET | CALLOC | CALLBACK | LIB | BOOL | STRING | ERROR | WARNING | LINE | PRAGMA_ONCE | PRAGMA | let_func_token | set_func_token;
 398 any_noeol_token: BOOL | CHAR | SHORT | INT | SIGNED | UNSIGNED | LONG | FLOAT | DOUBLE | STRING | MIXED | ARRAY | OBJECT | CALLABLE | VOID | ZVAL | INT8 | UINT8 | INT16 | UINT16 | INT32 | UINT32 | INT64 | UINT64 | NULL | TRUE | FALSE | NAME | NSNAME | DOLLAR_NAME | NUMBER | QUOTED_STRING | QUOTED_CHAR | EOF | EOS | LPAREN | RPAREN | COMMA | COLON | LBRACE | RBRACE | LBRACKET | RBRACKET | EQUALS | HASH | PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | LCHEVR | RCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE | TILDE | NOT | PERIOD | BACKSLASH | ELLIPSIS | ERROR | WARNING | LINE | PRAGMA | PRAGMA_ONCE | IIF | IF | IFDEF | IFNDEF | ELSE | ELIF | ENDIF | DEFINE | DEFINED | UNDEF | INCLUDE | TYPEDEF | STRUCT | UNION | ENUM | CONST | LIB | STATIC | CALLBACK | FUNCTION | LET | SET | TEMP | FREE | RETURN | PRE_ASSERT | POST_ASSERT | BOOLVAL | INTVAL | STRVAL | PATHVAL | STRLEN | FLOATVAL | ARRVAL | OBJVAL | COUNT | CALLOC | TO_BOOL | TO_INT | TO_STRING | TO_FLOAT | TO_ARRAY | TO_OBJECT | COMMENT | CPP_HEADER | CPP_PASTE | CPP_INLINE | CPP_RESTRICT | CPP_EXTENSION | CPP_ASM | SIZEOF | VOLATILE;
 399 any_nobrace_token: BOOL | CHAR | SHORT | INT | SIGNED | UNSIGNED | LONG | FLOAT | DOUBLE | STRING | MIXED | ARRAY | OBJECT | CALLABLE | VOID | ZVAL | INT8 | UINT8 | INT16 | UINT16 | INT32 | UINT32 | INT64 | UINT64 | NULL | TRUE | FALSE | NAME | NSNAME | DOLLAR_NAME | NUMBER | QUOTED_STRING | QUOTED_CHAR | EOF | EOS | LPAREN | RPAREN | COMMA | COLON | LBRACKET | RBRACKET | EQUALS | HASH | PIPE | CARET | AMPERSAND | LSHIFT | RSHIFT | PLUS | MINUS | ASTERISK | SLASH | MODULO | LCHEVR | RCHEVR | CMP_GE | CMP_LE | OR | AND | CMP_EQ | CMP_NE | TILDE | NOT | PERIOD | BACKSLASH | ELLIPSIS | ERROR | WARNING | LINE | PRAGMA | PRAGMA_ONCE | IIF | IF | IFDEF | IFNDEF | ELSE | ELIF | ENDIF | DEFINE | DEFINED | UNDEF | INCLUDE | TYPEDEF | STRUCT | UNION | ENUM | CONST | LIB | STATIC | CALLBACK | FUNCTION | LET | SET | TEMP | FREE | RETURN | PRE_ASSERT | POST_ASSERT | BOOLVAL | INTVAL | STRVAL | PATHVAL | STRLEN | FLOATVAL | ARRVAL | OBJVAL | COUNT | CALLOC | TO_BOOL | TO_INT | TO_STRING | TO_FLOAT | TO_ARRAY | TO_OBJECT | COMMENT | CPP_HEADER | CPP_PASTE | CPP_INLINE | CPP_RESTRICT | CPP_EXTENSION | CPP_ASM | SIZEOF | VOLATILE;
 400
 401
 402 file:
 403         %empty
 404 |       blocks
 405 ;
 406 blocks:
 407         block
 408 |       blocks block
 409 ;
 410 block:
 411         EOS
 412 |       EOL
 413 |       COMMENT
 414 |       cpp {
 415         if ($cpp) {
 416                 psi_cpp_exp_exec($cpp, P->preproc, PSI_DATA(P));
 417                 psi_cpp_exp_free(&$cpp);
 418         }
 419 }
 420 |       lib {
 421         if (P->file.ln) {
 422                 P->error(PSI_DATA(P), $lib, PSI_WARNING,
 423                                 "Extra 'lib \"%s\"' statement has no effect", $lib->text);
 424         } else {
 425                 P->file.ln = strndup($lib->text, $lib->size);
 426         }
 427 }
 428 |       constant {
 429         psi_parser_proc_add_const(P, $constant);
 430 }
 431 |       decl_stmt {
 432         psi_parser_proc_add_decl(P, $decl_stmt);
 433 }
 434 |       ignored_decl
 435 |       decl_ext_var_stmt
 436 |       decl_typedef[def] {
 437         psi_parser_proc_add_typedef(P, $def);
 438 }
 439 |       decl_struct[struct] {
 440         psi_parser_proc_add_struct(P, $struct);
 441 }
 442 |       decl_union[union] {
 443         psi_parser_proc_add_union(P, $union);
 444 }
 445 |       decl_enum[enum] {
 446         psi_parser_proc_add_enum(P, $enum);
 447 }
 448 |       impl {
 449         psi_parser_proc_add_impl(P, $impl);
 450 }
 451 ;
 452
 453 lib:
 454         LIB QUOTED_STRING EOS {
 455         $lib = $QUOTED_STRING;
 456 }
 457 ;
 458
 459 cpp:
 460         HASH EOL {
 461         $cpp = NULL;
 462 }
 463 |       HASH cpp_exp[exp] EOL {
 464         $cpp = $exp;
 465 }
 466 ;
 467
 468 cpp_exp[exp]:
 469         cpp_message_token cpp_macro_decl_tokens[tokens] {
 470         if ($tokens) {
 471                 struct psi_token *msg = NULL;
 472
 473                 if (psi_plist_get($tokens, 0, &msg)) {
 474                         size_t index = 1;
 475                         struct psi_token *next;
 476
 477                         msg = psi_token_copy(msg);
 478                         while (psi_plist_get($tokens, index++, &next)) {
 479                                 struct psi_token *old = msg;
 480                                 msg = psi_token_cat(" ", 2, msg, next);
 481                                 free(old);
 482                         }
 483                 }
 484                 psi_plist_free($tokens);
 485
 486                 $exp = psi_cpp_exp_init($cpp_message_token->type, msg);
 487         } else {
 488                 $exp = psi_cpp_exp_init($cpp_message_token->type, NULL);
 489         }
 490         $exp->token = psi_token_copy($cpp_message_token);
 491 }
 492 |       cpp_include_token[INCLUDE] cpp_header_token {
 493         $exp = psi_cpp_exp_init($INCLUDE->type, psi_token_copy($cpp_header_token));
 494         $exp->token = psi_token_copy($INCLUDE);
 495 }
 496 |       cpp_no_arg_token {
 497         $exp = psi_cpp_exp_init($cpp_no_arg_token->type, NULL);
 498         $exp->token = psi_token_copy($cpp_no_arg_token);
 499 }
 500 |       cpp_name_arg_token cpp_special_name_token[name_token] {
 501         $name_token->type = PSI_T_NAME;
 502         $exp = psi_cpp_exp_init($cpp_name_arg_token->type, psi_token_copy($name_token));
 503         $exp->token = psi_token_copy($cpp_name_arg_token);
 504 }
 505 |       DEFINE cpp_macro_decl {
 506         $exp = psi_cpp_exp_init($DEFINE->type, $cpp_macro_decl);
 507         $exp->token = psi_token_copy($DEFINE);
 508 }
 509 |       cpp_exp_arg_token cpp_macro_exp {
 510         $exp = psi_cpp_exp_init($cpp_exp_arg_token->type, $cpp_macro_exp);
 511         $exp->token = psi_token_copy($cpp_exp_arg_token);
 512 }
 513 |       PRAGMA_ONCE {
 514         $exp = psi_cpp_exp_init($PRAGMA_ONCE->type, NULL);
 515         $exp->token = psi_token_copy($PRAGMA_ONCE);
 516 }
 517 |       cpp_ignored_token cpp_macro_decl_tokens[tokens] {
 518         psi_plist_free($tokens);
 519         $exp = NULL;
 520 }
 521 ;
 522
 523 cpp_ignored_token:
 524         LINE
 525 |       PRAGMA
 526 ;
 527
 528 cpp_message_token:
 529         ERROR
 530 |       WARNING
 531 ;
 532
 533 cpp_include_token:
 534         IMPORT
 535 |       INCLUDE
 536 |       INCLUDE_NEXT
 537 ;
 538
 539 cpp_header_token:
 540         QUOTED_STRING
 541 |       CPP_HEADER
 542 ;
 543
 544 cpp_no_arg_token:
 545         ELSE
 546 |       ENDIF
 547 ;
 548
 549 cpp_name_arg_token:
 550         IFDEF
 551 |       IFNDEF
 552 |       UNDEF
 553 ;
 554
 555 cpp_exp_arg_token:
 556         IF
 557 |       ELIF
 558 ;
 559
 560 cpp_special_name_token:
 561         name_token
 562 |       NULL
 563 |       TRUE
 564 |       FALSE
 565 |       CPP_RESTRICT
 566 |       CPP_EXTENSION
 567 |       CPP_INLINE
 568 ;
 569
 570 cpp_macro_decl[macro]:
 571         name_token NO_WHITESPACE LPAREN cpp_macro_sig RPAREN cpp_macro_decl_tokens {
 572         $name_token->type = PSI_T_NAME;
 573         $macro = psi_cpp_macro_decl_init($cpp_macro_sig, $cpp_macro_decl_tokens, NULL);
 574         $macro->token = psi_token_copy($name_token);
 575 }
 576 |       cpp_special_name_token[name_token] cpp_macro_decl_tokens {
 577         $name_token->type = PSI_T_NAME;
 578         $macro = psi_cpp_macro_decl_init(NULL, $cpp_macro_decl_tokens, NULL);
 579         $macro->token = psi_token_copy($name_token);
 580 }
 581 ;
 582
 583 cpp_macro_sig[sig]:
 584         %empty {
 585         $sig = psi_plist_init(NULL);
 586 }
 587 |       ELLIPSIS {
 588         $sig = psi_plist_init(NULL); /* FIXME */
 589 }
 590 |       cpp_macro_sig_args
 591 |       cpp_macro_sig_args[args] COMMA ELLIPSIS {
 592         $sig = $args;
 593 }
 594 ;
 595
 596 cpp_macro_sig_args[args]:
 597         name_token {
 598         $name_token = psi_token_copy($name_token);
 599         $name_token->type = PSI_T_NAME;
 600         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_token_free), &$name_token);
 601 }
 602 |       cpp_macro_sig_args[args_] COMMA name_token {
 603         $name_token = psi_token_copy($name_token);
 604         $name_token->type = PSI_T_NAME;
 605         $args = psi_plist_add($args_, &$name_token);
 606 }
 607 ;
 608
 609 cpp_macro_decl_tokens[tokens]:
 610         %empty {
 611         $tokens = NULL;
 612 }
 613 | cpp_macro_decl_token_list
 614 ;
 615
 616 cpp_macro_decl_token_list[tokens]:
 617         any_noeol_token[token] {
 618         $token = psi_token_copy($token);
 619         $tokens = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_token_free), &$token);
 620 }
 621 |       cpp_macro_decl_token_list[tokens_] any_noeol_token[token] {
 622         $token = psi_token_copy($token);
 623         $tokens = psi_plist_add($tokens_, &$token);
 624 }
 625 ;
 626
 627 cpp_macro_exp[exp]:
 628         LPAREN cpp_macro_exp[exp_] RPAREN {
 629         $exp = psi_num_exp_init_unary($LPAREN->type, $exp_);
 630         $exp->token = psi_token_copy($LPAREN);
 631 }
 632 |       unary_op_token cpp_macro_exp[exp_] %prec UNARY {
 633         $exp = psi_num_exp_init_unary($unary_op_token->type, $exp_);
 634         $exp->token = psi_token_copy($unary_op_token);
 635 }
 636 |       cpp_macro_exp[lhs] binary_op_token cpp_macro_exp[rhs] %prec BINARY {
 637         $exp = psi_num_exp_init_binary($binary_op_token->type, $lhs, $rhs);
 638         $exp->token = psi_token_copy($binary_op_token);
 639 }
 640 |       cpp_macro_exp[cond] IIF cpp_macro_exp[truthy] COLON cpp_macro_exp[falsy] {
 641         $exp = psi_num_exp_init_ternary($IIF->type, $cond, $truthy, $falsy);
 642         $exp->token = psi_token_copy($IIF);
 643 }
 644
 645 |       DEFINED name_token {
 646         {
 647                 uint8_t exists;
 648
 649                 $name_token->type = PSI_T_NAME;
 650                 exists = psi_cpp_defined(P->preproc, $name_token);
 651                 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_UINT8, &exists, 0));
 652                 $exp->token = psi_token_copy($name_token);
 653         }
 654 }
 655 |       DEFINED LPAREN name_token RPAREN {
 656         {
 657                 uint8_t exists;
 658
 659                 $name_token->type = PSI_T_NAME;
 660                 exists = psi_cpp_defined(P->preproc, $name_token);
 661                 $exp = psi_num_exp_init_num(psi_number_init(PSI_T_UINT8, &exists, 0));
 662                 $exp->token = psi_token_copy($name_token);
 663         }
 664 }
 665 |       NUMBER {
 666         $exp = psi_num_exp_init_num(psi_number_init($NUMBER->type, $NUMBER->text, $NUMBER->flags));
 667         $exp->token = psi_token_copy($NUMBER);
 668         $exp->data.n->token = psi_token_copy($NUMBER);
 669 }
 670 |       QUOTED_CHAR {
 671         $exp = psi_num_exp_init_num(psi_number_init($QUOTED_CHAR->type, $QUOTED_CHAR->text, 0));
 672         $exp->token = psi_token_copy($QUOTED_CHAR);
 673         $exp->data.n->token = psi_token_copy($QUOTED_CHAR);
 674 }
 675 |       sizeof {
 676         $exp = psi_num_exp_init_num($sizeof);
 677         $exp->token = psi_token_copy($sizeof->token);
 678 }
 679 |       name_token {
 680         $name_token->type = PSI_T_NAME;
 681         $exp = psi_num_exp_init_num(psi_number_init(PSI_T_DEFINE, $name_token->text, 0));
 682         $exp->token = psi_token_copy($name_token);
 683         $exp->data.n->token = psi_token_copy($name_token);
 684 }
 685 |       name_token LPAREN cpp_macro_call_args RPAREN {
 686         $name_token->type = PSI_T_NAME;
 687         $exp = psi_num_exp_init_num(psi_number_init(PSI_T_FUNCTION,
 688                 psi_cpp_macro_call_init($name_token->text, $cpp_macro_call_args), 0));
 689         $exp->token = psi_token_copy($name_token);
 690 }
 691 ;
 692
 693 cpp_macro_call_args[args]:
 694         %empty {
 695         $args = NULL;
 696 }
 697 |       cpp_macro_call_arg_list
 698 ;
 699
 700 cpp_macro_call_arg_list[args]:
 701         cpp_macro_exp {
 702         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_num_exp_free),
 703                 &$cpp_macro_exp);
 704 }
 705 |       cpp_macro_call_arg_list[args_] COMMA cpp_macro_exp {
 706         $args = psi_plist_add($args_, &$cpp_macro_exp);
 707 }
 708 ;
 709
 710 constant[const]:
 711         CONST constant_type NSNAME EQUALS impl_def_val EOS {
 712         $const = psi_const_init($constant_type, $NSNAME->text, $impl_def_val);
 713         $const->token = psi_token_copy($NSNAME);
 714 }
 715 ;
 716
 717 constant_type[type]:
 718         constant_type_token[token] {
 719         $type = psi_const_type_init($token->type, $token->text);
 720 }
 721 ;
 722
 723 constant_type_token:
 724         BOOL
 725 |       INT
 726 |       FLOAT
 727 |       STRING
 728 ;
 729
 730 impl_def_val[val]:
 731         %empty {
 732         $val = NULL;
 733 }
 734 |       num_exp[num] {
 735         if (psi_num_exp_validate(PSI_DATA(P), $num, NULL, NULL, NULL, NULL, NULL)) {
 736                 impl_val res = {0};
 737                 token_t type = psi_num_exp_exec($num, &res, NULL, &P->preproc->defs);
 738
 739                 if (type == PSI_T_FLOAT || type == PSI_T_DOUBLE) {
 740                         $val = psi_impl_def_val_init(type, NULL);
 741                 } else {
 742                         $val = psi_impl_def_val_init(PSI_T_INT, NULL);
 743                 }
 744
 745                 switch (type) {
 746                 case PSI_T_UINT8:       $val->ival.zend.lval = res.u8;  break;
 747                 case PSI_T_UINT16:      $val->ival.zend.lval = res.u16; break;
 748                 case PSI_T_UINT32:      $val->ival.zend.lval = res.u32; break;
 749                 case PSI_T_UINT64:      $val->ival.zend.lval = res.u64; break; /* FIXME */
 750                 case PSI_T_INT8:        $val->ival.zend.lval = res.i8;  break;
 751                 case PSI_T_INT16:       $val->ival.zend.lval = res.i16; break;
 752                 case PSI_T_INT32:       $val->ival.zend.lval = res.i32; break;
 753                 case PSI_T_INT64:       $val->ival.zend.lval = res.i64; break;
 754                 case PSI_T_FLOAT:       $val->ival.dval = res.fval;             break;
 755                 case PSI_T_DOUBLE:      $val->ival.dval = res.dval;             break;
 756                 default:
 757                         assert(0);
 758
 759                 }
 760         } else {
 761                 $val = NULL;
 762         }
 763         psi_num_exp_free(&$num);
 764 }
 765 |       impl_def_val_token[token] {
 766         $val = psi_impl_def_val_init($token->type, $token->text);
 767         $val->token = psi_token_copy($token);
 768 }
 769 ;
 770
 771 impl_def_val_token:
 772         NULL
 773 |       TRUE
 774 |       FALSE
 775 |       QUOTED_STRING
 776 ;
 777
 778 decl_typedef[def]:
 779         TYPEDEF typedef[def_] EOS {
 780         $def = $def_;
 781 }
 782 |       TYPEDEF VOID name_token EOS {
 783         $def = psi_decl_arg_init(
 784                 psi_decl_type_init(PSI_T_VOID, $VOID->text),
 785                 psi_decl_var_init($name_token->text, 0, 0)
 786         );
 787         $def->token = psi_token_copy($VOID);
 788         $def->type->token = psi_token_copy($VOID);
 789         $def->var->token = psi_token_copy($name_token);
 790 }
 791 |       CPP_EXTENSION TYPEDEF typedef[def_] EOS {
 792         $def = $def_;
 793 }
 794 ;
 795
 796 typedef[def]:
 797         typedef_decl {
 798         $def = $typedef_decl;
 799 }
 800 |       CPP_EXTENSION typedef_decl {
 801         $def = $typedef_decl;
 802 }
 803 ;
 804
 805 typedef_anon[def]:
 806         typedef_anon_decl {
 807         $def = $typedef_anon_decl;
 808 }
 809 |       CPP_EXTENSION typedef_anon_decl {
 810         $def = $typedef_anon_decl;
 811 }
 812 ;
 813
 814 typedef_decl[def]:
 815         decl_arg
 816 |       decl_func_body[decl] {
 817         $def = psi_decl_arg_init(
 818                 psi_decl_type_init(PSI_T_FUNCTION, $decl->func->var->name),
 819                 psi_decl_var_copy($decl->func->var)
 820         );
 821         $def->type->token = psi_token_copy($decl->func->token);
 822         $def->type->real.func = $decl;
 823 }
 824 |       decl_enum[enum] name_token {
 825         $name_token->type = PSI_T_NAME;
 826         $def = psi_decl_arg_init(
 827                 psi_decl_type_init(PSI_T_ENUM, $enum->name),
 828                 psi_decl_var_init($name_token->text, 0, 0)
 829         );
 830         $def->var->token = psi_token_copy($name_token);
 831         $def->type->token = psi_token_copy($enum->token);
 832         $def->type->real.enm = $enum;
 833         psi_parser_proc_add_enum(P, $enum);
 834 }
 835 |       struct_name[struct] align_and_size[as] struct_args_block[args] decl_var[var] {
 836         $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_STRUCT, $struct->text), $var);
 837         $def->type->token = $struct;
 838         $def->type->real.strct = psi_decl_struct_init($struct->text, $args);
 839         $def->type->real.strct->token = psi_token_copy($struct);
 840         $def->type->real.strct->align = $as.pos;
 841         $def->type->real.strct->size = $as.len;
 842         psi_parser_proc_add_struct(P, $def->type->real.strct);
 843 }
 844 |       union_name[union] align_and_size[as] struct_args_block[args] decl_var[var] {
 845         $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_UNION, $union->text), $var);
 846         $def->type->token = $union;
 847         $def->type->real.unn = psi_decl_union_init($union->text, $args);
 848         $def->type->real.unn->token = psi_token_copy($union);
 849         $def->type->real.unn->align = $as.pos;
 850         $def->type->real.unn->size = $as.len;
 851         psi_parser_proc_add_union(P, $def->type->real.unn);
 852 }
 853 |       qualified_decl_type[type] decl_stdint_type[stdint] {
 854         $stdint->type = PSI_T_NAME;
 855         $def = psi_decl_arg_init($type, psi_decl_var_init($stdint->text, 0, 0));
 856         $def->var->token = psi_token_copy($stdint);
 857 }
 858 ;
 859
 860 typedef_anon_decl[def]:
 861         typedef_decl
 862 |       qualified_decl_type[type] {
 863         $def = psi_decl_arg_init($type, psi_decl_var_init(NULL, 0, 0));
 864         $def->var->token = psi_token_copy($type->token);
 865 }
 866 |       decl_enum[enum] {
 867         $def = psi_decl_arg_init(
 868                 psi_decl_type_init(PSI_T_ENUM, $enum->name),
 869                 psi_decl_var_init(NULL, 0, 0)
 870         );
 871         $def->var->token = psi_token_copy($enum->token);
 872         $def->type->token = psi_token_copy($enum->token);
 873         $def->type->real.enm = $enum;
 874         psi_parser_proc_add_enum(P, $enum);
 875 }
 876 |       struct_name[struct] align_and_size[as] struct_args_block[args] {
 877         $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_STRUCT, $struct->text), psi_decl_var_init(NULL, 0, 0));
 878         $def->type->token = $struct;
 879         $def->type->real.strct = psi_decl_struct_init($struct->text, $args);
 880         $def->type->real.strct->token = psi_token_copy($struct);
 881         $def->type->real.strct->align = $as.pos;
 882         $def->type->real.strct->size = $as.len;
 883         psi_parser_proc_add_struct(P, $def->type->real.strct);
 884 }
 885 |       union_name[union] align_and_size[as] struct_args_block[args] {
 886         $def = psi_decl_arg_init(psi_decl_type_init(PSI_T_UNION, $union->text), psi_decl_var_init(NULL, 0, 0));
 887         $def->type->token = $union;
 888         $def->type->real.unn = psi_decl_union_init($union->text, $args);
 889         $def->type->real.unn->token = psi_token_copy($union);
 890         $def->type->real.unn->align = $as.pos;
 891         $def->type->real.unn->size = $as.len;
 892         psi_parser_proc_add_union(P, $def->type->real.unn);
 893 }
 894 ;
 895
 896 qualified_decl_type[type]:
 897         CONST decl_type[type_] {
 898         $type = $type_;
 899 }
 900 |       VOLATILE decl_type[type_] {
 901         $type = $type_;
 902 }
 903 |       decl_type
 904 ;
 905
 906 decl_type[type]:
 907         decl_type_simple[token] {
 908         $type = psi_decl_type_init($token->type, $token->text);
 909         $type->token = $token;
 910 }
 911 |       decl_type_complex
 912 ;
 913
 914 decl_type_complex[type]:
 915         STRUCT[token] name_token {
 916         $name_token->type = PSI_T_NAME;
 917         $type = psi_decl_type_init($token->type, $name_token->text);
 918         $type->token = psi_token_copy($name_token);
 919 }
 920 |       UNION[token] name_token {
 921         $name_token->type = PSI_T_NAME;
 922         $type = psi_decl_type_init($token->type, $name_token->text);
 923         $type->token = psi_token_copy($name_token);
 924 }
 925 |       ENUM[token] name_token {
 926         $name_token->type = PSI_T_NAME;
 927         $type = psi_decl_type_init($token->type, $name_token->text);
 928         $type->token = psi_token_copy($name_token);
 929 }
 930 ;
 931
 932 decl_type_simple[type]:
 933         decl_int_type
 934 |       decl_real_type
 935 |       decl_stdint_type[type_] {
 936         $type = psi_token_copy($type_);
 937 }
 938 |       NAME[type_] {
 939         $type = psi_token_copy($type_);
 940 }
 941 ;
 942
 943 decl_real_type[type]:
 944         FLOAT[type_] {
 945         $type = psi_token_copy($type_);
 946 }
 947 |       DOUBLE[type_] {
 948         $type = psi_token_copy($type_);
 949 }
 950 |       LONG DOUBLE {
 951         $type = psi_token_cat(" ", 2, $LONG, $DOUBLE);
 952 }
 953 ;
 954
 955 decl_stdint_type[type]:
 956         INT8
 957 |       UINT8
 958 |       INT16
 959 |       UINT16
 960 |       INT32
 961 |       UINT32
 962 |       INT64
 963 |       UINT64
 964 ;
 965
 966 int_signed[i]:
 967         SIGNED
 968 |       UNSIGNED
 969 ;
 970
 971 int_width[i]:
 972         SHORT {
 973         $i = psi_token_copy($SHORT);
 974 }
 975 |       LONG {
 976         $i = psi_token_copy($LONG);
 977 }
 978 |       LONG[l1] LONG[l2] {
 979         $i = psi_token_cat(" ", 2, $l1, $l2);
 980 }
 981 ;
 982
 983 decl_int_type[type]:
 984         CHAR {
 985         $type = psi_token_copy($CHAR);
 986 }
 987 |       INT {
 988         $type = psi_token_copy($INT);
 989 }
 990 |       int_signed int_signed_types {
 991         if ($2) {
 992                 $type = psi_token_cat(" ", 2, $1, $2);
 993                 free($2);
 994         } else {
 995                 $type = psi_token_copy($1);
 996         }
 997 }
 998 |       int_width int_width_types {
 999         if ($2) {
1000                 $type = psi_token_cat(" ", 2, $1, $2);
1001                 free($1);
1002                 free($2);
1003         } else {
1004                 $type = $1;
1005         }
1006 }
1007 ;
1008
1009 int_signed_types[type]:
1010         %empty {
1011         $type = NULL;
1012 }
1013 |       CHAR {
1014         $type = psi_token_copy($CHAR);
1015 }
1016 |       SHORT signed_short_types {
1017         if ($2) {
1018                 $type = psi_token_cat(" ", 2, $1, $2);
1019         } else {
1020                 $type = psi_token_copy($1);
1021         }
1022 }
1023 |       INT {
1024         $type = psi_token_copy($INT);
1025 }
1026 |       LONG signed_long_types {
1027         if ($2) {
1028                 $type = psi_token_cat(" ", 2, $1, $2);
1029         } else {
1030                 $type = psi_token_copy($1);
1031         }
1032 }
1033 ;
1034
1035 signed_short_types[type]:
1036         %empty {
1037         $type = NULL;
1038 }
1039 |       INT
1040 ;
1041 signed_long_types[type]:
1042         %empty {
1043         $type = NULL;
1044 }
1045 |       INT
1046 |       LONG
1047 |       LONG INT
1048 ;
1049
1050 int_width_types[type]:
1051         %empty {
1052         $type = NULL;
1053 }
1054 |       INT {
1055         $type = psi_token_copy($INT);
1056 }
1057 |       int_signed int_signed_types {
1058         if ($2) {
1059                 $type = psi_token_cat(" ", 2, $1, $2);
1060                 free($2);
1061         } else {
1062                 $type = psi_token_copy($1);
1063         }
1064 }
1065 ;
1066
1067 decl_stmt:
1068         decl decl_asm EOS {
1069         $decl_stmt = $decl;
1070 }
1071 |       CPP_EXTENSION decl decl_asm EOS {
1072         $decl_stmt = $decl;
1073 }
1074 ;
1075
1076 decl_asm:
1077         %empty
1078 |       CPP_ASM LPAREN ignored_quoted_strings RPAREN
1079 ;
1080
1081 ignored_quoted_strings:
1082         QUOTED_STRING
1083 |       ignored_quoted_strings QUOTED_STRING
1084 ;
1085
1086 decl_ext_var_stmt:
1087         decl_ext_var EOS
1088 ;
1089
1090 decl_ext_var:
1091         NAME decl_arg decl_ext_var_list {
1092         psi_decl_arg_free(&$decl_arg);
1093 }
1094 ;
1095
1096 decl_ext_var_list:
1097         %empty
1098 |       COMMA decl_vars {
1099         psi_plist_free($decl_vars);
1100 }
1101 ;
1102
1103 decl_vars[vars]:
1104         decl_var[var] {
1105         $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_var_free), &$var);
1106 }
1107 |       decl_vars[vars_] COMMA decl_var[var] {
1108         $vars = psi_plist_add($vars_, &$var);
1109 }
1110 ;
1111
1112 ignored_decl:
1113         STATIC decl_body ignored_decl_body {
1114         psi_decl_free(&$decl_body);
1115 }
1116 |       CPP_INLINE decl_body ignored_decl_body {
1117         psi_decl_free(&$decl_body);
1118 }
1119 |       STATIC CPP_INLINE decl_body ignored_decl_body {
1120         psi_decl_free(&$decl_body);
1121 }
1122 ;
1123
1124 ignored_decl_body:
1125         LBRACE ignored_decl_body_stmts RBRACE
1126 ;
1127
1128 ignored_decl_body_stmts:
1129         ignored_decl_body_stmt
1130 |       ignored_decl_body_stmts ignored_decl_body_stmt
1131 ;
1132
1133 ignored_decl_body_stmt:
1134         any_nobrace_token
1135 |       ignored_decl_body
1136 ;
1137
1138 decl:
1139         decl_body
1140 |       NAME[abi] decl_body {
1141         $decl = $decl_body;
1142         $decl->abi = psi_decl_abi_init($abi->text);
1143 }
1144 ;
1145
1146 decl_body:
1147         decl_func_body
1148 |       decl_functor_body
1149 ;
1150
1151 decl_func_body[decl]:
1152         decl_func[func] LPAREN decl_args[args] RPAREN array_size[as] {
1153         $decl = psi_decl_init($func, $args);
1154         if ($as) {
1155                 $decl->func->var->pointer_level += 1;
1156                 $decl->func->var->array_size = $as;
1157         }
1158 }
1159 |       decl_func[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1160         $decl = psi_decl_init($func, $args);
1161         $decl->varargs = 1;
1162         if ($as) {
1163                 $decl->func->var->pointer_level += 1;
1164                 $decl->func->var->array_size = $as;
1165         }
1166 }
1167 ;
1168
1169 decl_functor_body[decl]:
1170         decl_functor[func] LPAREN decl_args[args] RPAREN array_size[as] {
1171         $decl = psi_decl_init($func, $args);
1172         if ($as) {
1173                 $decl->func->var->pointer_level += 1;
1174                 $decl->func->var->array_size = $as;
1175         }
1176 }
1177 |       decl_functor[func] LPAREN decl_args[args] COMMA ELLIPSIS RPAREN array_size[as] {
1178         $decl = psi_decl_init($func, $args);
1179         $decl->varargs = 1;
1180         if ($as) {
1181                 $decl->func->var->pointer_level += 1;
1182                 $decl->func->var->array_size = $as;
1183         }
1184 }
1185 ;
1186
1187 decl_functor[arg]:
1188         qualified_decl_type[type] indirection[i] LPAREN indirection[unused1] name_token[NAME] RPAREN {
1189         (void) $unused1;
1190         $NAME->type = PSI_T_NAME;
1191         $arg = psi_decl_arg_init($type, psi_decl_var_init($NAME->text, $i, 0));
1192         $arg->var->token = psi_token_copy($NAME);
1193         $arg->token = psi_token_copy($NAME);
1194 }
1195 |       CONST VOID pointers LPAREN indirection[unused1] name_token[NAME] RPAREN {
1196         (void) $unused1;
1197         $NAME->type = PSI_T_NAME;
1198         $arg = psi_decl_arg_init(
1199                 psi_decl_type_init($VOID->type, $VOID->text),
1200                 psi_decl_var_init($NAME->text, $pointers, 0)
1201         );
1202         $arg->type->token = psi_token_copy($VOID);
1203         $arg->var->token = psi_token_copy($NAME);
1204         $arg->token = psi_token_copy($NAME);
1205 }
1206 |       VOID pointers LPAREN indirection[unused1] name_token[NAME] RPAREN {
1207         (void) $unused1;
1208         $NAME->type = PSI_T_NAME;
1209         $arg = psi_decl_arg_init(
1210                 psi_decl_type_init($VOID->type, $VOID->text),
1211                 psi_decl_var_init($NAME->text, $pointers, 0)
1212         );
1213         $arg->type->token = psi_token_copy($VOID);
1214         $arg->var->token = psi_token_copy($NAME);
1215         $arg->token = psi_token_copy($NAME);
1216 }
1217 |       VOID LPAREN indirection[unused1] name_token[NAME] RPAREN {
1218         (void) $unused1;
1219         $NAME->type = PSI_T_NAME;
1220         $arg = psi_decl_arg_init(
1221                 psi_decl_type_init($VOID->type, $VOID->text),
1222                 psi_decl_var_init($NAME->text, 0, 0)
1223         );
1224         $arg->type->token = psi_token_copy($VOID);
1225         $arg->var->token = psi_token_copy($NAME);
1226         $arg->token = psi_token_copy($NAME);
1227 }
1228 ;
1229
1230 decl_func[func]:
1231         decl_arg
1232 |       VOID name_token[NAME] {
1233         $func = psi_decl_arg_init(
1234                 psi_decl_type_init($VOID->type, $VOID->text),
1235                 psi_decl_var_init($NAME->text, 0, 0)
1236         );
1237         $func->type->token = psi_token_copy($VOID);
1238         $func->var->token = psi_token_copy($NAME);
1239         $func->token = psi_token_copy($NAME);
1240 }
1241 ;
1242
1243 decl_args[args]:
1244         %empty {
1245         $args = NULL;
1246 }
1247 |       VOID {
1248         $args = NULL;
1249 }
1250 |       decl_anon_arg[arg] {
1251         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &$arg);
1252 }
1253 |       decl_args[args_] COMMA decl_anon_arg[arg] {
1254         $args = psi_plist_add($args_, &$arg);
1255 }
1256 ;
1257
1258 decl_anon_arg[arg]:
1259 /* FIXME decl_functor_body_anon */
1260         decl_arg {
1261         $arg = $decl_arg;
1262 }
1263 |       qualified_decl_type[type] indirection {
1264         $arg = psi_decl_arg_init(
1265                 $type,
1266                 psi_decl_var_init(NULL, $indirection, 0)
1267         );
1268 }
1269 |       CONST VOID pointers {
1270         $arg = psi_decl_arg_init(
1271                 psi_decl_type_init($VOID->type, $VOID->text),
1272                 psi_decl_var_init(NULL, $pointers, 0)
1273         );
1274         $arg->type->token = psi_token_copy($VOID);
1275         $arg->var->token = psi_token_copy($VOID);
1276         $arg->token = psi_token_copy($VOID);
1277 }
1278 |       VOID pointers {
1279         $arg = psi_decl_arg_init(
1280                 psi_decl_type_init($VOID->type, $VOID->text),
1281                 psi_decl_var_init(NULL, $pointers, 0)
1282         );
1283         $arg->type->token = psi_token_copy($VOID);
1284         $arg->var->token = psi_token_copy($VOID);
1285         $arg->token = psi_token_copy($VOID);
1286 }
1287 ;
1288
1289 decl_arg[arg]:
1290         decl_functor_body[decl] {
1291         $arg = psi_decl_arg_init(
1292                 psi_decl_type_init(PSI_T_FUNCTION, $decl->func->var->name),
1293                 psi_decl_var_copy($decl->func->var)
1294         );
1295         $arg->type->token = psi_token_copy($decl->func->token);
1296         $arg->type->real.func = $decl;
1297 }
1298 |       qualified_decl_type[type] decl_var[var] {
1299         $arg = psi_decl_arg_init($type, $var);
1300 }
1301 |       CONST VOID pointers name_token[NAME] {
1302         $NAME->type = PSI_T_NAME;
1303         $arg = psi_decl_arg_init(
1304                 psi_decl_type_init($VOID->type, $VOID->text),
1305                 psi_decl_var_init($NAME->text, $pointers, 0)
1306         );
1307         $arg->type->token = psi_token_copy($VOID);
1308         $arg->var->token = psi_token_copy($NAME);
1309         $arg->token = psi_token_copy($NAME);
1310 }
1311 |       VOID pointers name_token[NAME] {
1312         $NAME->type = PSI_T_NAME;
1313         $arg = psi_decl_arg_init(
1314                 psi_decl_type_init($VOID->type, $VOID->text),
1315                 psi_decl_var_init($NAME->text, $pointers, 0)
1316         );
1317         $arg->type->token = psi_token_copy($VOID);
1318         $arg->var->token = psi_token_copy($NAME);
1319         $arg->token = psi_token_copy($NAME);
1320 }
1321 ;
1322
1323 decl_var[var]:
1324         pointers name_token array_size {
1325         $name_token->type = PSI_T_NAME;
1326         $var = psi_decl_var_init($name_token->text, $pointers + !! $array_size, $array_size);
1327         $var->token = psi_token_copy($name_token);
1328 }
1329 |       name_token array_size {
1330         $name_token->type = PSI_T_NAME;
1331         $var = psi_decl_var_init($name_token->text, !! $array_size, $array_size);
1332         $var->token = psi_token_copy($name_token);
1333 }
1334 ;
1335
1336 decl_union[union]:
1337         UNION name_token align_and_size[as] decl_struct_args[args] {
1338         $name_token->type = PSI_T_NAME;
1339         $union = psi_decl_union_init($name_token->text, $args);
1340         $union->align = $as.pos;
1341         $union->size = $as.len;
1342         $union->token = psi_token_copy($name_token);
1343 }
1344 ;
1345
1346 decl_struct[struct]:
1347         STRUCT name_token align_and_size[as] decl_struct_args[args] {
1348         $name_token->type = PSI_T_NAME;
1349         $struct = psi_decl_struct_init($name_token->text, $args);
1350         $struct->align = $as.pos;
1351         $struct->size = $as.len;
1352         $struct->token = psi_token_copy($name_token);
1353 }
1354 ;
1355
1356 decl_struct_args[args]:
1357         EOS {
1358         $args = NULL;
1359 }
1360 |       struct_args_block
1361 ;
1362
1363 struct_args_block[args]:
1364         LBRACE struct_args RBRACE {
1365         $args = $struct_args;
1366 }
1367 ;
1368
1369 struct_args[args]:
1370         typedef_anon[arg] decl_layout[layout] struct_arg_var_list[vars] EOS {
1371         $arg->layout = $layout;
1372         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &$arg);
1373         if ($vars) {
1374                 size_t i = 0;
1375                 struct psi_decl_arg *arg;
1376
1377                 while (psi_plist_get($vars, i++, &arg)) {
1378                         arg->type = psi_decl_type_copy($arg->type);
1379                         $args = psi_plist_add($args, &arg);
1380                 }
1381                 free($vars);
1382         }
1383 }
1384 |       struct_args[args_] typedef_anon[arg] decl_layout[layout] struct_arg_var_list[vars] EOS {
1385         $arg->layout = $layout;
1386         $args = psi_plist_add($args_, &$arg);
1387         if ($vars) {
1388                 size_t i = 0;
1389                 struct psi_decl_arg *arg;
1390
1391                 while (psi_plist_get($vars, i++, &arg)) {
1392                         arg->type = psi_decl_type_copy($arg->type);
1393                         $args = psi_plist_add($args, &arg);
1394                 }
1395                 free($vars);
1396         }
1397 }
1398 ;
1399
1400 struct_arg_var_list[vars]:
1401         %empty {
1402         $vars = NULL;
1403 }
1404 |       COMMA decl_vars_with_layout[vars_] {
1405         $vars = $vars_;
1406 }
1407 ;
1408
1409 decl_vars_with_layout[vars]:
1410         decl_var[var] decl_layout[layout] {
1411         {
1412                 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, $var);
1413                 arg->layout = $layout;
1414                 $vars = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_arg_free), &arg);
1415         }
1416 }
1417 |       decl_vars_with_layout[vars_] COMMA decl_var[var] decl_layout[layout] {
1418         {
1419                 struct psi_decl_arg *arg = psi_decl_arg_init(NULL, $var);
1420                 arg->layout = $layout;
1421                 $vars = psi_plist_add($vars_, &arg);
1422         }
1423 }
1424 ;
1425
1426 decl_enum[enum]:
1427         enum_name LBRACE decl_enum_items[list] RBRACE {
1428         $enum = psi_decl_enum_init($enum_name->text, $list);
1429         $enum->token = $enum_name;
1430 }
1431 ;
1432
1433 decl_enum_items[list]:
1434         decl_enum_item[i] {
1435         $list = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_decl_enum_item_free), &$i);
1436 }
1437 |       decl_enum_items[list_] COMMA decl_enum_item[i] {
1438         $list = psi_plist_add($list_, &$i);
1439 }
1440 ;
1441
1442 decl_enum_item[i]:
1443         name_token {
1444         $name_token->type = PSI_T_NAME;
1445         $i = psi_decl_enum_item_init($name_token->text, NULL);
1446         $i->token = psi_token_copy($name_token);
1447 }
1448 |       name_token EQUALS num_exp {
1449         $name_token->type = PSI_T_NAME;
1450         $i = psi_decl_enum_item_init($name_token->text, $num_exp);
1451         $i->token = psi_token_copy($name_token);
1452 }
1453 ;
1454
1455 num_exp[exp]:
1456         number {
1457         $exp = psi_num_exp_init_num($number);
1458         $exp->token = psi_token_copy($number->token);
1459 }
1460 |       LPAREN qualified_decl_type[type] RPAREN num_exp[exp_] %prec UNARY {
1461         $exp = psi_num_exp_init_cast($type, $exp_);
1462         $exp->token = psi_token_copy($type->token);
1463 }
1464 |       LPAREN num_exp[exp_] RPAREN {
1465         $exp = psi_num_exp_init_unary(PSI_T_LPAREN, $exp_);
1466         $exp->token = psi_token_copy($LPAREN);
1467 }
1468 |       num_exp[lhs] binary_op_token[op] num_exp[rhs] %prec BINARY {
1469         $exp = psi_num_exp_init_binary($op->type, $lhs, $rhs);
1470         $exp->token = psi_token_copy($op);
1471 }
1472 |       unary_op_token[op] num_exp[exp_] %prec UNARY {
1473         $exp = psi_num_exp_init_unary($op->type, $exp_);
1474         $exp->token = psi_token_copy($op);
1475 }
1476 |       num_exp[cond] IIF num_exp[truthy] COLON num_exp[falsy] {
1477         $exp = psi_num_exp_init_ternary($IIF->type, $cond, $truthy, $falsy);
1478         $exp->token = psi_token_copy($IIF);
1479 }
1480 ;
1481
1482 number[num]:
1483         NUMBER[token] {
1484         $num = psi_number_init($token->type, $token->text, $token->flags);
1485         $num->token = psi_token_copy($token);
1486 }
1487 |       NSNAME[token] {
1488         $num = psi_number_init($token->type, $token->text, 0);
1489         $num->token = psi_token_copy($token);
1490 }
1491 |       QUOTED_CHAR[token] {
1492         $num = psi_number_init($token->type, $token->text, 0);
1493         $num->token = psi_token_copy($token);
1494 }
1495 |       decl_var {
1496         $num = psi_number_init(PSI_T_NAME, $decl_var, 0);
1497         $num->token = psi_token_copy($decl_var->token);
1498 }
1499 |       sizeof {
1500         $num = $sizeof;
1501 }
1502 ;
1503
1504 sizeof:
1505         SIZEOF LPAREN sizeof_body[sizeof_] RPAREN {
1506         $sizeof = $sizeof_;
1507         $sizeof->token = psi_token_copy($SIZEOF);
1508 }
1509 |       SIZEOF sizeof_body_notypes[sizeof_] {
1510         $sizeof = $sizeof_;
1511         $sizeof->token = psi_token_copy($SIZEOF);
1512 }
1513 ;
1514
1515 sizeof_body[sizeof]:
1516         sizeof_body_notypes[sizeof_] {
1517         $sizeof = $sizeof_;
1518 }
1519 |       decl_type indirection {
1520         if ($indirection) {
1521                 int8_t sizeof_void_p = sizeof(void *);
1522                 $sizeof = psi_number_init(PSI_T_INT8, &sizeof_void_p, 0);
1523         } else {
1524                 $sizeof = psi_number_init(PSI_T_SIZEOF, $decl_type, 0);
1525         }
1526 }
1527 ;
1528
1529 sizeof_body_notypes[sizeof]:
1530         AMPERSAND NAME {
1531         int8_t sizeof_void_p = sizeof(void *);
1532         $sizeof = psi_number_init(PSI_T_INT8, &sizeof_void_p, 0);
1533 }
1534 |       QUOTED_CHAR {
1535         int8_t sizeof_a = sizeof('a');
1536         $sizeof = psi_number_init(PSI_T_INT8, &sizeof_a, 0);
1537 }
1538 |       QUOTED_STRING {
1539         $sizeof = psi_number_init(PSI_T_INT64, &$QUOTED_STRING->size, 0);
1540 }
1541 ;
1542
1543 enum_name[name]:
1544         ENUM optional_name[name_] {
1545         if ($name_) {
1546                 $name = psi_token_copy($name_);
1547         } else {
1548                 char digest[17];
1549
1550                 psi_token_hash($ENUM, digest);
1551                 $name = psi_token_append("@", psi_token_copy($ENUM), 1, digest);
1552         }
1553 }
1554 ;
1555
1556 union_name[name]:
1557         UNION optional_name[name_] {
1558         if ($name_) {
1559                 $name = psi_token_copy($name_);
1560         } else {
1561                 char digest[17];
1562
1563                 psi_token_hash($UNION, digest);
1564                 $name = psi_token_append("@", psi_token_copy($UNION), 1, digest);
1565         }
1566 }
1567 ;
1568
1569 struct_name[name]:
1570         STRUCT optional_name[name_] {
1571         if ($name_) {
1572                 $name = psi_token_copy($name_);
1573         } else {
1574                 char digest[17];
1575
1576                 psi_token_hash($STRUCT, digest);
1577                 $name = psi_token_append("@", psi_token_copy($STRUCT), 1, digest);
1578         }
1579 }
1580 ;
1581
1582 optional_name[name]:
1583         %empty {
1584         $name = NULL;
1585 }
1586 |       name_token {
1587         $name = $name_token;
1588         $name->type = PSI_T_NAME;
1589 }
1590 ;
1591
1592 decl_layout[l]:
1593         %empty {
1594         $l = NULL;
1595 }
1596 |       COLON NUMBER[width] {
1597         $l = psi_layout_init(0, 0, psi_layout_init(0, atol($width->text), NULL));
1598 }
1599 |       COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1600         $l = psi_layout_init(atol($align->text), atol($size->text), NULL);
1601 }
1602 |       COLON NUMBER[width] COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1603         $l = psi_layout_init(atol($align->text), atol($size->text), psi_layout_init(0, atol($width->text), NULL));
1604 }
1605 ;
1606
1607 align_and_size[as]:
1608         %empty {
1609         $as.pos = 0;
1610         $as.len = 0;
1611 }
1612 |       COLON COLON LPAREN NUMBER[align] COMMA NUMBER[size] RPAREN {
1613         $as.pos = atol($align->text);
1614         $as.len = atol($size->text);
1615 }
1616 ;
1617
1618 array_size[as]:
1619         %empty {
1620         $as = 0;
1621 }
1622 |       LBRACKET RBRACKET {
1623         $as = 0;
1624 }
1625 |       LBRACKET num_exp RBRACKET {
1626         if (psi_num_exp_validate(PSI_DATA(P), $num_exp, NULL, NULL, NULL, NULL, NULL)) {
1627                 $as = psi_long_num_exp($num_exp, NULL, &P->preproc->defs);
1628         } else {
1629                 $as = 0;
1630         }
1631 }
1632 ;
1633
1634 indirection[i]:
1635         %empty {
1636         $i = 0;
1637 }
1638 |       pointers[p] %prec UNARY {
1639         $i = $p;
1640 }
1641 ;
1642
1643 pointers[p]:
1644         asterisks
1645 |       asterisks[a] CPP_RESTRICT {
1646         $p = $a;
1647 }
1648 ;
1649
1650 asterisks[a]:
1651         asterisk {
1652         $a = 1;
1653 }
1654 |       asterisks[a_] asterisk {
1655         $a = $a_ + 1;
1656 }
1657 ;
1658
1659 asterisk:
1660         ASTERISK
1661 |       ASTERISK CONST
1662 ;
1663
1664 /*
1665  *
1666  * impl
1667  *
1668  */
1669
1670 impl:
1671         impl_func[func] LBRACE impl_stmts[stmts] RBRACE {
1672         $impl = psi_impl_init($func, $stmts);
1673 }
1674 |       STATIC impl_func[func] LBRACE impl_stmts[stmts] RBRACE {
1675         $impl = psi_impl_init($func, $stmts);
1676         $func->static_memory = 1;
1677 }
1678 ;
1679
1680 impl_func[func]:
1681         FUNCTION reference[r] NSNAME LPAREN RPAREN COLON impl_type[type] {
1682         $func = psi_impl_func_init($NSNAME->text, NULL, $type);
1683         $func->token = psi_token_copy($NSNAME);
1684         $func->return_reference = $r;
1685 }
1686 |       FUNCTION reference[r] NSNAME LPAREN impl_args[args] RPAREN COLON impl_type[type] {
1687         $func = psi_impl_func_init($NSNAME->text, $args, $type);
1688         $func->token = psi_token_copy($NSNAME);
1689         $func->return_reference = $r;
1690 }
1691 |       FUNCTION reference[r] NSNAME LPAREN impl_args[args] COMMA impl_type[va_type] reference[va_r] ELLIPSIS DOLLAR_NAME RPAREN COLON impl_type[type] {
1692         $func = psi_impl_func_init($NSNAME->text, $args, $type);
1693         $func->token = psi_token_copy($NSNAME);
1694         $func->return_reference = $r;
1695         $func->vararg = psi_impl_arg_init($va_type, psi_impl_var_init($DOLLAR_NAME->text, $va_r), NULL);
1696         $func->vararg->var->token = psi_token_copy($DOLLAR_NAME);
1697 }
1698 ;
1699
1700 impl_args[args]:
1701         impl_arg[arg] {
1702         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_impl_arg_free), &$arg);
1703 }
1704 |       impl_args[args_] COMMA impl_arg[arg] {
1705         $args = psi_plist_add($args_, &$arg);
1706 }
1707 ;
1708
1709 impl_arg[arg]:
1710         impl_type[type] impl_var[var] {
1711         $arg = psi_impl_arg_init($type, $var, NULL);
1712 }
1713 |       impl_type[type] impl_var[var] EQUALS impl_def_val[val] {
1714         $arg = psi_impl_arg_init($type, $var, $val);
1715 }
1716 ;
1717
1718 impl_var[var]:
1719         reference DOLLAR_NAME {
1720         $var = psi_impl_var_init($DOLLAR_NAME->text, $reference);
1721         $var->token = psi_token_copy($DOLLAR_NAME);
1722 }
1723 ;
1724
1725 impl_type[type]:
1726         impl_type_token[token] {
1727         $type = psi_impl_type_init($token->type, $token->text);
1728         $type->token = psi_token_copy($token);
1729 }
1730 ;
1731
1732 impl_type_token:
1733         VOID
1734 |       MIXED
1735 |       BOOL
1736 |       INT
1737 |       FLOAT
1738 |       STRING
1739 |       ARRAY
1740 |       OBJECT
1741 |       CALLABLE
1742 ;
1743
1744 impl_stmts[stmts]:
1745         impl_stmt[stmt] {
1746         $stmts = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_impl_stmt_free), &$stmt);
1747 }
1748 |       impl_stmts[stmts_] impl_stmt[stmt] {
1749         $stmts = psi_plist_add($stmts_, &$stmt);
1750 }
1751 ;
1752
1753 impl_stmt[stmt]:
1754         return_stmt[s] {
1755         $stmt = (struct psi_token **) $s;
1756 }
1757 |       let_stmt[s] {
1758         $stmt = (struct psi_token **) $s;
1759 }
1760 |       set_stmt[s] {
1761         $stmt = (struct psi_token **) $s;
1762 }
1763 |       assert_stmt[s] {
1764         $stmt = (struct psi_token **) $s;
1765 }
1766 |       free_stmt[s] {
1767         $stmt = (struct psi_token **) $s;
1768 }
1769 ;
1770
1771 let_stmt[let]:
1772         LET let_exp_assign[exp] EOS {
1773         $let = psi_let_stmt_init($exp);
1774         $let->token = psi_token_copy($LET);
1775 }
1776 |       TEMP decl_var[var] EQUALS reference decl_var[val] EOS {
1777         $let = psi_let_stmt_init(psi_let_exp_init_ex($var, PSI_LET_TMP, $val));
1778         $let->token = psi_token_copy($TEMP);
1779         $let->exp->is_reference = $reference;
1780 }
1781 ;
1782
1783 let_exp[exp]:
1784         let_exp_assign
1785 |       byref let_exp_byref[exp_] {
1786         $exp = $exp_;
1787         $exp->is_reference = true;
1788 }
1789 |       let_exp_byref[exp_] {
1790         $exp = $exp_;
1791         $exp->is_reference = false;
1792 }
1793 ;
1794
1795 let_exp_byref[exp]:
1796         NULL {
1797         $exp = psi_let_exp_init(PSI_LET_NULL, NULL);
1798 }
1799 |       let_calloc[calloc] {
1800         $exp = psi_let_exp_init(PSI_LET_CALLOC, $calloc);
1801 }
1802 |       STATIC let_calloc[calloc] {
1803         $exp = psi_let_exp_init(PSI_LET_CALLOC, $calloc);
1804         $calloc->static_memory = 1;
1805 }
1806 |       let_callback[callback] {
1807         $exp = psi_let_exp_init(PSI_LET_CALLBACK, $callback);
1808 }
1809 |       let_func[func] {
1810         $exp = psi_let_exp_init_ex(NULL, PSI_LET_FUNC, $func);
1811 }
1812 |       num_exp[num] {
1813         $exp = psi_let_exp_init_ex(NULL, PSI_LET_NUMEXP, $num);
1814 }
1815 ;
1816
1817 let_exp_assign[exp]:
1818         decl_var[var] EQUALS let_exp_byref[exp_] {
1819         $exp = $exp_;
1820         $exp->var = $var;
1821 }
1822 |       decl_var[var] EQUALS byref let_exp_byref[exp_] {
1823         $exp = $exp_;
1824         $exp->is_reference = 1;
1825         $exp->var = $var;
1826 }
1827 ;
1828
1829 let_calloc[calloc]:
1830         CALLOC LPAREN num_exp[nmemb] COMMA num_exp[size] RPAREN {
1831         $calloc = psi_let_calloc_init($nmemb, $size);
1832         $calloc->token = psi_token_copy($CALLOC);
1833 }
1834 ;
1835
1836 let_callback[callback]:
1837         CALLBACK callback_rval[func] LPAREN impl_var[var] LPAREN callback_arg_list[args] RPAREN RPAREN {
1838         $callback = psi_let_callback_init(psi_let_func_init($func->type, $func->text, $var), $args);
1839         $callback->func->token = psi_token_copy($func);
1840         $callback->token = psi_token_copy($CALLBACK);
1841 }
1842 ;
1843
1844 let_func[func]:
1845         let_func_token[token] LPAREN impl_var[var] let_func_exps[exps] RPAREN {
1846         $func = psi_let_func_init($token->type, $token->text, $var);
1847         $func->token = psi_token_copy($token);
1848         $func->inner = $exps;
1849 }
1850 ;
1851
1852 let_func_token:
1853         ZVAL
1854 |       OBJVAL
1855 |       ARRVAL
1856 |       PATHVAL
1857 |       STRLEN
1858 |       STRVAL
1859 |       FLOATVAL
1860 |       INTVAL
1861 |       BOOLVAL
1862 |       COUNT
1863 ;
1864
1865 let_func_exps[exps]:
1866         %empty {
1867         $exps = NULL;
1868 }
1869 |       COMMA let_exps[exps_] {
1870         $exps = $exps_;
1871 }
1872 ;
1873
1874 let_exps[exps]:
1875         let_exp[exp] {
1876         $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_let_exp_free), &$exp);
1877 }
1878 |       let_exps[exps_] COMMA let_exp[exp] {
1879         $exps = psi_plist_add($exps_, &$exp);
1880 }
1881 ;
1882
1883 callback_rval[rval]:
1884         VOID
1885 |       let_func_token
1886 ;
1887
1888 callback_arg_list[list]:
1889         %empty {
1890         $list = NULL;
1891 }
1892 |       callback_args[args] {
1893         $list = $args;
1894 }
1895 ;
1896
1897 callback_args[args]:
1898         set_exp[exp] {
1899         $args = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_set_exp_free), &$exp);
1900 }
1901 |       callback_args[args_] COMMA set_exp[exp] {
1902         $args = psi_plist_add($args_, &$exp);
1903 }
1904 ;
1905
1906 return_stmt[return]:
1907         RETURN set_func[func] EOS {
1908         $return = psi_return_stmt_init(psi_set_exp_init(PSI_SET_FUNC, $func));
1909         $return->token = psi_token_copy($RETURN);
1910 }
1911 ;
1912
1913 set_stmt[set]:
1914         SET set_exp[exp] EOS {
1915         $set = psi_set_stmt_init($exp);
1916         $set->token = psi_token_copy($SET);
1917 }
1918 ;
1919
1920 set_exp[exp]:
1921         set_func[func] {
1922         $exp = psi_set_exp_init(PSI_SET_FUNC, $func);
1923 }
1924 |       num_exp[num] {
1925         $exp = psi_set_exp_init(PSI_SET_NUMEXP, $num);
1926 }
1927 |       impl_var[var] EQUALS set_exp[exp_] {
1928         $exp = $exp_;
1929         $exp->var = $var;
1930 }
1931 ;
1932
1933 set_func[func]:
1934         set_func_token[token] LPAREN decl_var[var] set_func_exps[exps] RPAREN {
1935         $func = psi_set_func_init($token->type, $token->text, $var);
1936         $func->token = psi_token_copy($token);
1937         $func->inner = $exps;
1938 }
1939 |       set_func_token[token] LPAREN decl_var[var] COMMA ELLIPSIS RPAREN {
1940         $func = psi_set_func_init($token->type, $token->text, $var);
1941         $func->token = psi_token_copy($token);
1942         $func->recursive = 1;
1943 }
1944 ;
1945
1946 set_func_token:
1947         TO_OBJECT
1948 |       TO_ARRAY
1949 |       TO_STRING
1950 |       TO_INT
1951 |       TO_FLOAT
1952 |       TO_BOOL
1953 |       ZVAL
1954 |       VOID
1955 ;
1956
1957 set_func_exps[exps]:
1958         %empty {
1959         $exps = NULL;
1960 }
1961 |       COMMA set_exps[exps_] {
1962         $exps = $exps_;
1963 }
1964 ;
1965
1966 set_exps[exps]:
1967         set_exp[exp] {
1968         $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_set_exp_free), &$exp);
1969 }
1970 |       set_exps[exps_] COMMA set_exp[exp] {
1971         $exps = psi_plist_add($exps_, &$exp);
1972 }
1973 ;
1974
1975 assert_stmt[assert]:
1976         assert_stmt_token[token] num_exp[exp] EOS {
1977         $assert = psi_assert_stmt_init((enum psi_assert_kind) $token->type, $exp);
1978         $assert->token = psi_token_copy($token);
1979 }
1980 ;
1981
1982 assert_stmt_token:
1983         PRE_ASSERT
1984 |       POST_ASSERT
1985 ;
1986
1987 free_stmt[free]:
1988         FREE free_exps[exps] EOS {
1989         $free = psi_free_stmt_init($exps);
1990         $free->token = psi_token_copy($FREE);
1991 }
1992 ;
1993
1994 free_exps[exps]:
1995         free_exp[exp] {
1996         $exps = psi_plist_add(psi_plist_init((psi_plist_dtor) psi_free_exp_free), &$exp);
1997 }
1998 |       free_exps[exps_] COMMA free_exp[exp] {
1999         $exps = psi_plist_add($exps_, &$exp);
2000 }
2001 ;
2002
2003 free_exp[exp]:
2004         name_token[NAME] LPAREN decl_vars[vars] RPAREN {
2005         $NAME->type = PSI_T_NAME;
2006         $exp = psi_free_exp_init($NAME->text, $vars);
2007         $exp->token = psi_token_copy($NAME);
2008 }
2009 ;
2010
2011 reference:
2012         %empty {
2013         $reference = false;
2014 }
2015 |       byref {
2016         $reference = true;
2017 }
2018 ;
2019
2020 byref:
2021         AMPERSAND %prec UNARY
2022 ;
2023
2024 %%
2025
2026 /* epilogue */
2027
2028 static int psi_parser_proc_lex(YYSTYPE *lvalp, struct psi_parser *P, struct psi_plist *tokens, size_t *index)
2029 {
2030         struct psi_token *token;
2031
2032         if (psi_plist_get(tokens, (*index)++, &token)) {
2033                 if (P->flags & PSI_DEBUG) {
2034                         psi_token_dump(2, token);
2035                 }
2036
2037                 *((struct psi_token **)lvalp) = token;
2038                 return token->type;
2039         } else {
2040                 (*index)--;
2041                 PSI_DEBUG_PRINT(P, "EOF(%d)\n", PSI_T_EOF);
2042         }
2043
2044         return PSI_T_EOF;
2045 }
2046
2047 static void psi_parser_proc_error(struct psi_parser *P, struct psi_plist *tokens, size_t *index, const char *msg)
2048 {
2049         struct psi_token *T = NULL;
2050         size_t last;
2051
2052         if (*index == 0) {
2053                 last = 0;
2054         } else {
2055                 last = --(*index);
2056         }
2057
2058         psi_plist_get(tokens, last, &T);
2059         if (T) {
2060                 P->error(PSI_DATA(P), T, PSI_WARNING, "PSI %s at col %u", msg, T->col);
2061         } else {
2062                 P->error(PSI_DATA(P), NULL, PSI_WARNING, "PSI %s", msg);
2063         }
2064         P->errors++;
2065 }
2066