git.m6w6.name Git - m6w6/ext-psi/blob - m4/psi/psi.m4

   1 dnl Generated headers with pre-defined types, structs, consts and decls.
   2 PSI_STDINC=$PHP_PSI_SRCDIR/php_psi_stdinc.h
   3 PSI_STDTYPES=$PHP_PSI_SRCDIR/php_psi_stdtypes.h
   4 PSI_TYPES=$PHP_PSI_SRCDIR/php_psi_types.h
   5 PSI_STRUCTS=$PHP_PSI_SRCDIR/php_psi_structs.h
   6 PSI_UNIONS=$PHP_PSI_SRCDIR/php_psi_unions.h
   7 PSI_CONSTS=$PHP_PSI_SRCDIR/php_psi_consts.h
   8 PSI_REDIRS=$PHP_PSI_SRCDIR/php_psi_redirs.h
   9 PSI_MACROS=$PHP_PSI_SRCDIR/php_psi_macros.h
  10 PSI_DECLS=$PHP_PSI_SRCDIR/php_psi_decls.h
  11 PSI_VA_DECLS=$PHP_PSI_SRCDIR/php_psi_va_decls.h
  12 PSI_FN_DECLS=$PHP_PSI_SRCDIR/php_psi_fn_decls.h
  13
  14 dnl PSI_CONFIG_INIT()
  15 dnl Creates stubs of the headers with pre-defined types etc.
  16 dnl These headers are included by src/context.c.
  17 dnl This macro must be called prior any checks for a type, struct, decl etc.
  18 AC_DEFUN(PSI_CONFIG_INIT, [
  19         for i in $PSI_STDTYPES $PSI_TYPES $PSI_STRUCTS $PSI_UNIONS $PSI_CONSTS $PSI_REDIRS $PSI_MACROS $PSI_DECLS $PSI_VA_DECLS $PSI_FN_DECLS; do
  20                 cat >$i <<EOF
  21 /* generated by configure */
  22 #include "php_psi_stdinc.h"
  23 EOF
  24         done
  25         cat >>$PSI_STDTYPES <<EOF
  26 static struct psi_std_type {
  27         token_t type_tag;
  28         const char *type_name;
  29         const char *alias;
  30 } psi_std_types@<:@@:>@ = {
  31         {PSI_T_INT8, "int8_t", NULL},
  32         {PSI_T_INT16, "int16_t", NULL},
  33         {PSI_T_INT32, "int32_t", NULL},
  34         {PSI_T_INT64, "int64_t", NULL},
  35         {PSI_T_UINT8, "uint8_t", NULL},
  36         {PSI_T_UINT16, "uint16_t", NULL},
  37         {PSI_T_UINT32, "uint32_t", NULL},
  38         {PSI_T_UINT64, "uint64_t", NULL},
  39 EOF
  40         cat >>$PSI_TYPES <<EOF
  41 static struct psi_predef_type {
  42         token_t type_tag;
  43         const char *type_name;
  44         const char *alias;
  45 } psi_predef_types@<:@@:>@ = {
  46 EOF
  47         cat >>$PSI_STRUCTS <<EOF
  48 static struct psi_predef_struct {
  49         token_t type_tag;
  50         const char *type_name;
  51         const char *var_name;
  52         size_t offset;
  53         size_t size;
  54         size_t pointer_level;
  55         size_t array_size;
  56 } psi_predef_structs@<:@@:>@ = {
  57 EOF
  58         cat >>$PSI_UNIONS <<EOF
  59 static struct psi_predef_union {
  60         token_t type_tag;
  61         const char *type_name;
  62         const char *var_name;
  63         size_t offset;
  64         size_t size;
  65         size_t pointer_level;
  66         size_t array_size;
  67 } psi_predef_unions@<:@@:>@ = {
  68 EOF
  69         cat >>$PSI_CONSTS <<EOF
  70 static struct psi_predef_const {
  71         token_t type_tag;
  72         const char *type_name;
  73         const char *var_name;
  74         const char *val_text;
  75         token_t val_type_tag;
  76 } psi_predef_consts@<:@@:>@ = {
  77 EOF
  78         cat >>$PSI_REDIRS <<EOF
  79 typedef void (*psi_func_ptr)();
  80 static struct psi_func_redir {
  81         const char *name;
  82         psi_func_ptr func;
  83 } psi_func_redirs@<:@@:>@ = {
  84 EOF
  85         cat >>$PSI_MACROS <<EOF
  86 EOF
  87         cat >>$PSI_DECLS <<EOF
  88 static struct psi_predef_decl {
  89         token_t type_tag;
  90         const char *type_name;
  91         const char *var_name;
  92         size_t pointer_level;
  93         size_t array_size;
  94 } psi_predef_decls@<:@@:>@ = {
  95 EOF
  96         cat >>$PSI_VA_DECLS <<EOF
  97 static struct psi_predef_decl psi_predef_vararg_decls@<:@@:>@ = {
  98 EOF
  99         cat >>$PSI_FN_DECLS <<EOF
 100 static struct psi_predef_decl psi_predef_functor_decls@<:@@:>@ = {
 101 EOF
 102 ])
 103
 104 dnl PSI_CONFIG_DONE()
 105 dnl Finish the headers with the pre-defined types etc.
 106 AC_DEFUN(PSI_CONFIG_DONE, [
 107         cat >$PSI_STDINC <<EOF
 108 /* generated by configure */
 109 #ifndef PSI_STDINC_H
 110 #define PSI_STDINC_H
 111
 112 #ifdef HAVE_CONFIG_H
 113 # include "config.h"
 114 #else
 115 # include "php_config.h"
 116 #endif
 117
 118 #ifndef _GNU_SOURCE
 119 # define _GNU_SOURCE
 120 #endif
 121 #ifndef _REENTRANT
 122 # define _REENTRANT
 123 #endif
 124
 125 PSI_INCLUDES
 126 #endif
 127 EOF
 128         for i in $PSI_STDTYPES $PSI_TYPES $PSI_STRUCTS $PSI_UNIONS $PSI_CONSTS $PSI_REDIRS $PSI_DECLS $PSI_VA_DECLS $PSI_FN_DECLS; do
 129                 cat >>$i <<EOF
 130         {0}
 131 };
 132 EOF
 133         done
 134 ])
 135
 136 dnl PSI_SH_CONFIG_POSIX_ENABLED(section)
 137 dnl Expand to $psi_config_posix_<section>
 138 AC_DEFUN(PSI_SH_CONFIG_POSIX_ENABLED, [$AS_TR_SH([psi_config_posix_]$1)])
 139
 140 dnl PSI_CONFIG_POSIX_ENABLED(section, action-if-yes, action-if-not)
 141 dnl Internal. Used to check if --enable-psi-posix=section was given.
 142 AC_DEFUN(PSI_CONFIG_POSIX_ENABLED, [
 143         AS_TR_SH([psi_config_posix_]$1)=false
 144         case "$PHP_PSI_POSIX" in
 145         yes|all)
 146                 AS_TR_SH([psi_config_posix_]$1)=true
 147                 ;;
 148         *)
 149                 if expr "$PHP_PSI_POSIX" : '\b$1\b' >/dev/null; then
 150                         AS_TR_SH([psi_config_posix_]$1)=true
 151                 fi
 152                 ;;
 153         esac
 154         if $AS_TR_SH([psi_config_posix_]$1); then
 155                 ifelse([$2],,:,[$2])
 156         else
 157                 ifelse([$3],,:,[$3])
 158         fi
 159 ])
 160
 161 dnl PSI_TEST_POSIX_ENABLED(section, action-if-yes, action-if-not)
 162 dnl Shell-if test if PSI POSIX section was configured.
 163 AC_DEFUN(PSI_SH_TEST_POSIX_ENABLED, [
 164         if test "PSI_SH_CONFIG_POSIX_ENABLED([$1])" && $PSI_SH_CONFIG_POSIX_ENABLED([$1]); then
 165                 ifelse([$2],,:,[$2])
 166         else
 167                 ifelse([$3],,:,[$3])
 168         fi
 169 ])
 170
 171 dnl PSI_CONFIG_POSIX(section, headers)
 172 AC_DEFUN(PSI_CONFIG_POSIX, [
 173         PSI_CONFIG_POSIX_ENABLED($1, [
 174                 PHP_CONFIGURE_PART(Configuring PSI POSIX: $1)
 175                 ifelse([$2],,:,[AC_CHECK_HEADERS($2)])
 176         ], [
 177                 return 0
 178         ])
 179 ])
 180
 181 AC_DEFUN(PSI_PTHREAD_ONCE, [
 182         AX_PTHREAD([
 183                 LIBS="$PTHREAD_LIBS $LIBS"
 184                 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 185         ])
 186 ])
 187 AC_DEFUN(PSI_PTHREAD, [
 188         AC_REQUIRE([PSI_PTHREAD_ONCE])
 189 ])
 190
 191 dnl PSI_INCLUDES()
 192 dnl Expands to a complete list of include statements including
 193 dnl AC_INCLUDES_DEFAULT().
 194 AC_DEFUN(PSI_INCLUDES, [#define PSI_INCLUDES
 195 #ifndef _GNU_SOURCE
 196 # define _GNU_SOURCE
 197 #endif
 198 #ifndef _REENTRANT
 199 # define _REENTRANT
 200 #endif
 201 AC_INCLUDES_DEFAULT()
 202 #ifdef HAVE_STDBOOL_H
 203 # include <stdbool.h>
 204 #else
 205 # ifndef HAVE__BOOL
 206 #  ifdef __cplusplus
 207 typedef bool _Bool;
 208 #  else
 209 #   define _Bool signed char
 210 #  endif
 211 # endif
 212 # define bool _Bool
 213 # define false 0
 214 # define true 1
 215 # define __bool_true_false_are_defined 1
 216 #endif
 217 #ifdef HAVE_ERRNO_H
 218 # include <errno.h>
 219 #endif
 220 #ifdef HAVE_GLOB_H
 221 # include <glob.h>
 222 #endif
 223 #ifdef HAVE_LOCALE_H
 224 # include <locale.h>
 225 #endif
 226 #ifdef HAVE_XLOCALE_H
 227 # include <xlocale.h>
 228 #endif
 229 #ifdef HAVE_NETINET_IN_H
 230 # include <netinet/in.h>
 231 #endif
 232 #ifdef HAVE_NETINET_TCP_H
 233 # include <netinet/tcp.h>
 234 #endif
 235 #ifdef HAVE_ARPA_NAMESER_H
 236 # include <arpa/nameser.h>
 237 #endif
 238 #ifdef HAVE_FCNTL_H
 239 # include <fcntl.h>
 240 #endif
 241 #ifdef HAVE_RELIC_H
 242 # include <relic.h>
 243 #elif HAVE_NDBM_H
 244 # include <ndbm.h>
 245 #elif HAVE_GDBM_NDBM_H
 246 # include <gdbm-ndbm.h>
 247 #endif
 248 #ifdef HAVE_NETDB_H
 249 # include <netdb.h>
 250 #endif
 251 #ifdef HAVE_POLL_H
 252 # include <poll.h>
 253 #endif
 254 #ifdef HAVE_RESOLV_H
 255 # include <resolv.h>
 256 #endif
 257 #ifdef HAVE_SYS_SELECT_H
 258 # include <sys/select.h>
 259 #endif
 260 #ifdef HAVE_SYS_SOCKET_H
 261 # include <sys/socket.h>
 262 #endif
 263 #ifdef HAVE_SYS_TIME_H
 264 # include <sys/time.h>
 265 #endif
 266 #ifdef HAVE_SYS_TIMES_H
 267 # include <sys/times.h>
 268 #endif
 269 #ifdef HAVE_SYS_UIO_H
 270 # include <sys/uio.h>
 271 #endif
 272 #ifdef HAVE_SYS_UTSNAME_H
 273 # include <sys/utsname.h>
 274 #endif
 275 #ifdef HAVE_TIME_H
 276 # include <time.h>
 277 #endif
 278 #ifdef HAVE_SIGNAL_H
 279 # include <signal.h>
 280 #endif
 281 #ifdef HAVE_SYSLOG_H
 282 # include <syslog.h>
 283 #endif
 284 #ifdef HAVE_WCHAR_H
 285 # include <wchar.h>
 286 #endif
 287 #ifdef HAVE_WCTYPE_H
 288 # include <wctype.h>
 289 #endif
 290 ])
 291
 292 dnl PSI_LEMON()
 293 dnl Declare $LEMON precious, and check for a `lemon` in $PATH.
 294 AC_DEFUN(PSI_LEMON, [
 295         AC_ARG_VAR(LEMON, The lemon parser generator of the SQLite project)
 296         AC_PATH_PROG(LEMON, lemon, ./lemon)
 297         PHP_SUBST(LEMON)
 298 ])
 299
 300 dnl PSI_PKG_CONFIG()
 301 dnl Check for `pkg-config` and add possible libjit and libffi directories to
 302 dnl $PKG_CONFIG_PATH, because those libs often ship with headers etc. in
 303 dnl arch-dependent locations.
 304 AC_DEFUN([PSI_PKG_CONFIG], [
 305         if test -z "$PKG_CONFIG"
 306         then
 307                 AC_PATH_PROG(PKG_CONFIG, pkg-config, false)
 308         fi
 309         export PKG_CONFIG_PATH="$PHP_PSI_LIBFFI/lib/pkgconfig:$PHP_PSI_LIBJIT/lib/pkgconfig:$PKG_CONFIG_PATH"
 310 ])
 311
 312 dnl PSI_SH_SIZEOF(type)
 313 dnl expand to shell variable $ac_cv_sizeof_<TYPE>
 314 AC_DEFUN([PSI_SH_SIZEOF], [$AS_TR_SH([ac_cv_sizeof_]$1)])
 315
 316 dnl PSI_SH_OFFSETOF(type)
 317 dnl Expand to shell variable $ac_cv_offsetof_<TYPE>
 318 AC_DEFUN([PSI_SH_OFFSETOF], [$AS_TR_SH([ac_cv_offsetof_]$1)])
 319
 320 dnl PSI_SH_ALIGNOF(type)
 321 dnl Expand to shell variable $ac_cv_offsetof_<TYPE>
 322 AC_DEFUN([PSI_SH_ALIGNOF], [$AS_TR_SH([ac_cv_alignof_]$1)])
 323
 324 dnl PSI_SH_TEST_SIZEOF(type)
 325 dnl `if` condition to test if $ac_cv_sizeof_$1 is greater than 0.
 326 AC_DEFUN([PSI_SH_TEST_SIZEOF], [test -n "$AS_TR_SH([ac_cv_sizeof_]$1)" && test "$AS_TR_SH([ac_cv_sizeof_]$1)" -gt 0])
 327
 328 dnl PSI_SH_TEST_ALIGNOF(type)
 329 dnl `if` condition to test if $ac_cv_alignof_$1 is greater than 0.
 330 AC_DEFUN([PSI_SH_TEST_ALIGNOF], [test -n "$AS_TR_SH([ac_cv_alignof_]$1)" && test "$AS_TR_SH([ac_cv_alignof_]$1)" -gt 0])
 331
 332 dnl PSI_CHECK_SIZEOF(type, special-includes)
 333 dnl AC_CHECK_SIZEOF wrapper with PSI_INCLUDES
 334 dnl Defines psi\\SIZEOF_<TYPE> pre-defined constant in $PSI_CONSTS.
 335 AC_DEFUN(PSI_CHECK_SIZEOF, [
 336         AC_CHECK_SIZEOF($1, [], PSI_INCLUDES
 337                 $2)
 338         if PSI_SH_TEST_SIZEOF($1); then
 339                 psi_add_int_const "AS_TR_CPP([SIZEOF_]$1)" "$AS_TR_SH([ac_cv_sizeof_]$1)"
 340         fi
 341 ])
 342
 343 dnl PSI_CHECK_ALIGNOF(type, special-includes)
 344 dnl AC_CHECK_ALIGNOF wrapper with PSI_INCLUDES
 345 dnl Defines psi\\ALIGNOF_<TYPE> pre-defined constant in $PSI_CONSTS.
 346 AC_DEFUN(PSI_CHECK_ALIGNOF, [
 347         AC_CHECK_ALIGNOF($1, PSI_INCLUDES
 348                 $2)
 349         if PSI_SH_TEST_ALIGNOF($1); then
 350                 psi_add_int_const "AS_TR_CPP([ALIGNOF_]$1)" "$AS_TR_SH([ac_cv_alignof_]$1)"
 351         fi
 352 ])
 353
 354 dnl PSI_CHECK_OFFSETOF(struct, element)
 355 dnl Check the offset of a struct element, implemented in the similar manner
 356 dnl like AC_CHECK_SIZEOF.
 357 dnl AC_DEFINEs OFFSETOF_<STRUCT>_<ELEMENT>.
 358 AC_DEFUN(PSI_CHECK_OFFSETOF, [
 359         _AC_CACHE_CHECK_INT(
 360                 [offset of $2 in $1],
 361                 [AS_TR_SH([ac_cv_offsetof_$1_$2])],
 362                 [(long int) (offsetof ($1, $2))],
 363                 [PSI_INCLUDES],
 364                 [AC_MSG_FAILURE([cannot compute offsetof ($1, $2)])]
 365         )
 366         AC_DEFINE_UNQUOTED(
 367                 AS_TR_CPP(offsetof_$1_$2),
 368                 $AS_TR_SH([ac_cv_offsetof_$1_$2]),
 369                 [The offset of `$2' in `$1', as computed by offsetof.]
 370         )
 371 ])
 372
 373
 374 dnl PSI_COMPUTE_STR(variable, string or expression)
 375 dnl Compute a string constant value in a similar manner like AC_COMPUTE_INT.
 376 AC_DEFUN(PSI_COMPUTE_STR, [
 377         AC_TRY_RUN(
 378                 PSI_INCLUDES
 379                 [int main() {
 380                         return EOF == fputs($2, fopen("conftest.out", "w"));
 381                 }
 382         ], [
 383                 eval $1=\\\"`cat conftest.out`\\\"
 384         ])
 385 ])
 386
 387 dnl PSI_CHECK_LIBJIT()
 388 dnl Check for libjit in $PHP_PSI_LIBJIT or standard locations
 389 dnl AC_DEFINEs HAVE_LIBJIT.
 390 AC_DEFUN(PSI_CHECK_LIBJIT, [
 391         AC_CACHE_CHECK(for libjit, psi_cv_libjit_dir, [
 392                 for psi_cv_libjit_dir in $PHP_PSI_LIBJIT {/usr{,/local},/opt}{,/libjit}
 393                 do
 394                         if test -e $psi_cv_libjit_dir/include/jit/jit.h
 395                         then
 396                                 break
 397                         fi
 398                         psi_cv_libjit_dir=
 399                 done
 400         ])
 401         if test -n "$psi_cv_libjit_dir"
 402         then
 403                 PHP_ADD_INCLUDE($psi_cv_libjit_dir/include)
 404                 PHP_ADD_LIBRARY_WITH_PATH(jit, $psi_cv_libjit_dir/$PHP_LIBDIR, PSI_SHARED_LIBADD)
 405                 AC_DEFINE(HAVE_LIBJIT, 1, Have libjit)
 406         else
 407                 AC_MSG_WARN([Could not find libjit, please provide the base install path])
 408         fi
 409 ])
 410
 411 dnl PSI_CHECK_LIBFFI()
 412 dnl Check for libffi with `pkg-config`. If that fails, `configure` looks into
 413 dnl $PHP_PSI_LIBFFI or standard locations to find libjit deps.
 414 dnl Checks for availability of recent closure API:
 415 dnl \ffi_closure_alloc and \ffi_prep_closure.
 416 dnl Checks for availability of recent vararg API:
 417 dnl \ffi_prep_cif_var.
 418 dnl AC_DEFINEs HAVE_LIBFFI, PSI_HAVE_FFI_CLOSURE_ALLOC,
 419 dnl PSI_HAVE_FFI_PREP_CLOSURE and PSI_HAVE_FFO_PREP_VIF_VAR.
 420 AC_DEFUN(PSI_CHECK_LIBFFI, [
 421         AC_REQUIRE([PSI_PKG_CONFIG])dnl
 422
 423         AC_CACHE_CHECK(for libffi through pkg-config, psi_cv_libffi, [
 424         if $PKG_CONFIG --exists libffi
 425         then
 426                 psi_cv_libffi=true
 427         else
 428                 psi_cv_libffi=false
 429         fi])
 430
 431         if $psi_cv_libffi
 432         then
 433                 AC_MSG_CHECKING(for libffi)
 434                 psi_cv_libffi_dir=`$PKG_CONFIG --variable=prefix libffi`
 435                 AC_MSG_RESULT($psi_cv_libffi_dir)
 436                 PHP_EVAL_INCLINE(`$PKG_CONFIG --cflags libffi`)
 437                 PHP_EVAL_LIBLINE(`$PKG_CONFIG --libs libffi`, PSI_SHARED_LIBADD)
 438                 AC_DEFINE(HAVE_LIBFFI, 1, Have libffi)
 439                 AC_DEFINE_UNQUOTED([PHP_PSI_LIBFFI_VERSION], ["`$PKG_CONFIG --modversion libffi`"], [libffi version])
 440         else
 441                 AC_CACHE_CHECK(for libffi, psi_cv_libffi_dir, [
 442                 for psi_cv_libffi_dir in $PHP_PSI_LIBFFI {/usr{,/local},/opt}{,/libffi}
 443                 do
 444                         if test -e $psi_cv_libffi_dir/include/ffi/ffi.h
 445                         then
 446                                 break
 447                         fi
 448                         psi_cv_libffi_dir=
 449                 done])
 450                 if test -n "$psi_cv_libffi_dir"
 451                 then
 452                         PHP_ADD_INCLUDE($psi_cv_libffi_dir/include/ffi)
 453                         PHP_ADD_LIBRARY_WITH_PATH(ffi, $psi_cv_libffi_dir/$PHP_LIBDIR, PSI_SHARED_LIBADD)
 454                         AC_DEFINE(HAVE_LIBFFI, 1, Have libffi)
 455                 else
 456                         AC_MSG_WARN([Could not find libffi, please provide the base install path])
 457                 fi
 458         fi
 459         PHP_CHECK_LIBRARY(ffi, ffi_closure_alloc, [
 460                 PHP_CHECK_LIBRARY(ffi, ffi_prep_closure_loc, [
 461                         AC_DEFINE(PSI_HAVE_FFI_PREP_CLOSURE_LOC, 1, [ ])
 462                 ], [], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 463                 AC_DEFINE(PSI_HAVE_FFI_CLOSURE_ALLOC, 1, [ ])
 464         ], [
 465                 PHP_CHECK_LIBRARY(ffi, ffi_prep_closure, [
 466                         AC_CHECK_HEADERS(sys/mman.h)
 467                         PHP_CHECK_FUNC(mmap)
 468                         AC_DEFINE(PSI_HAVE_FFI_PREP_CLOSURE, 1, [ ])
 469                 ], [
 470                 ], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 471         ], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 472         PHP_CHECK_LIBRARY(ffi, ffi_prep_cif_var, [
 473                 AC_DEFINE(PSI_HAVE_FFI_PREP_CIF_VAR, 1, [ ])
 474         ], [
 475         ], -L$psi_cv_libffi_dir/$PHP_LIBDIR)
 476 ])