git.m6w6.name Git - awesomized/libmemcached/blob - test/CMakeLists.txt

   1 if(NOT BUILD_TESTING OR NOT CMAKE_PROJECT_NAME STREQUAL PROJECT_NAME)
   2     return()
   3 endif()
   4
   5 include(CMake/Catch.cmake)
   6
   7 if(NOT MEMCACHED_BINARY)
   8     message(SEND_ERROR "Could not find memcached(1) binary")
   9     set(ENV{INVALID_CONFIGURATION} 1)
  10 endif()
  11
  12 check_decl(pipe2 unistd.h)
  13 check_decl(SOCK_NONBLOCK sys/socket.h)
  14 check_decl(SOCK_CLOEXEC sys/socket.h)
  15 check_header(execution)
  16
  17 file(GLOB_RECURSE TESTING_SRC RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} *.cpp)
  18 set(TESTING_ROOT ${CMAKE_CURRENT_BINARY_DIR})
  19 set_source_files_properties(main.cpp PROPERTIES SKIP_UNITY_BUILD_INCLUSION ON)
  20 configure_file(conf.h.in conf.h @ONLY)
  21 add_executable(runtests ${TESTING_SRC})
  22 set_target_properties(runtests PROPERTIES CXX_STANDARD 17)
  23 target_include_directories(runtests PRIVATE
  24         ${CMAKE_SOURCE_DIR}
  25         ${CMAKE_BINARY_DIR}
  26         ${CMAKE_SOURCE_DIR}/src
  27         ${CMAKE_BINARY_DIR}/src)
  28 target_link_libraries(runtests PRIVATE libhashkit libmemcachedinternal libmemcachedutil)
  29 add_dependencies(runtests ${CLIENTS})
  30 if(HAVE_MEMASLAP)
  31     add_dependencies(runtests memaslap)
  32 endif()
  33
  34 catch_discover_tests(runtests
  35         TEST_SPEC "lib*")
  36 catch_discover_tests(runtests
  37         TEST_SPEC "hashkit*")
  38 catch_discover_tests(runtests
  39         TEST_SPEC "memcached*")
  40 catch_discover_tests(runtests
  41         TEST_SPEC "bin/*")