git.m6w6.name Git - awesomized/libmemcached/blob - test/CMakeLists.txt

   1 if(NOT BUILD_TESTING OR NOT CMAKE_PROJECT_NAME STREQUAL PROJECT_NAME)
   2     return()
   3 endif()
   4
   5 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMake")
   6 include(Catch)
   7 include(CheckTbb)
   8
   9 if(NOT MEMCACHED_BINARY)
  10     message(SEND_ERROR "Could not find memcached(1) binary")
  11     set(ENV{INVALID_CONFIGURATION} 1)
  12 endif()
  13
  14 check_decl(pipe2 unistd.h)
  15 check_decl(SOCK_NONBLOCK sys/socket.h)
  16 check_decl(SOCK_CLOEXEC sys/socket.h)
  17
  18 file(GLOB_RECURSE TESTING_SRC RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} *.cpp)
  19 set(TESTING_ROOT ${CMAKE_CURRENT_BINARY_DIR})
  20 set_source_files_properties(main.cpp PROPERTIES SKIP_UNITY_BUILD_INCLUSION ON)
  21 configure_file(conf.h.in conf.h @ONLY)
  22 add_executable(runtests ${TESTING_SRC})
  23 set_target_properties(runtests PROPERTIES CXX_STANDARD 17)
  24 target_include_directories(runtests PRIVATE
  25         ${CMAKE_SOURCE_DIR}
  26         ${CMAKE_BINARY_DIR}
  27         ${CMAKE_SOURCE_DIR}/src
  28         ${CMAKE_BINARY_DIR}/src)
  29 target_link_libraries(runtests PRIVATE libhashkit libmemcachedinternal libmemcachedutil)
  30
  31 check_tbb()
  32 if(HAVE_TBB)
  33     message("HAVE TBB")
  34     target_link_libraries(runtests PRIVATE ${LIBTBB})
  35 endif()
  36
  37 add_dependencies(runtests ${CLIENTS})
  38 if(HAVE_MEMASLAP)
  39     add_dependencies(runtests memaslap)
  40 endif()
  41
  42 catch_discover_tests(runtests
  43         TEST_SPEC "lib*")
  44 catch_discover_tests(runtests
  45         TEST_SPEC "hashkit*")
  46 catch_discover_tests(runtests
  47         TEST_SPEC "memcached*")
  48 catch_discover_tests(runtests
  49         TEST_SPEC "bin/*")