git.m6w6.name Git - awesomized/libmemcached/blob - src/libmemcachedprotocol/CMakeLists.txt

   1 check_include(umem.h)
   2
   3 add_library(libmemcachedprotocol SHARED
   4         ascii_handler.c
   5         binary_handler.c
   6         cache.c
   7         common.h
   8         handler.c
   9         pedantic.c
  10         ../libmemcached/byteorder.cc
  11         )
  12 add_library(memcachedprotocol ALIAS libmemcachedprotocol)
  13 set_target_properties(libmemcachedprotocol PROPERTIES
  14         CXX_STANDARD ${CXX_STANDARD}
  15         LIBRARY_OUTPUT_NAME memcachedprotocol
  16         LIBRARY_OUTPUT_NAME_DEBUG memcachedprotocol-dbg
  17         SOVERSION ${LIBMEMCACHEDPROTOCOL_SO_SOVERSION}
  18         VERSION ${LIBMEMCACHEDPROTOCOL_SO_VERSION})
  19 target_compile_definitions(libmemcachedprotocol PRIVATE -DBUILDING_LIBMEMCACHED)
  20 if(CMAKE_CXX_COMPILER_ID STREQUAL AppleClang)
  21         set_target_properties(libmemcachedprotocol PROPERTIES
  22                 LINK_FLAGS "-Wl,-undefined,dynamic_lookup"
  23                 )
  24 endif()
  25 target_link_libraries(libmemcachedprotocol PRIVATE p9y)
  26 target_link_libraries(libmemcachedprotocol PUBLIC Threads::Threads)
  27 if(MSVC OR MINGW)
  28     target_link_libraries(libmemcachedprotocol PUBLIC wsock32 ws2_32)
  29 endif()
  30 target_include_directories(libmemcachedprotocol PRIVATE
  31         ${CMAKE_SOURCE_DIR}/src
  32         ${CMAKE_BINARY_DIR}/src
  33         ${CMAKE_BINARY_DIR})
  34 target_include_directories(libmemcachedprotocol PUBLIC
  35         $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/include>
  36         $<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/include>
  37         $<INSTALL_INTERFACE:include>)
  38
  39 install(TARGETS libmemcachedprotocol EXPORT libmemcachedprotocol-targets
  40         RUNTIME COMPONENT bin DESTINATION ${CMAKE_INSTALL_BINDIR}
  41         ARCHIVE COMPONENT lib DESTINATION ${CMAKE_INSTALL_LIBDIR}
  42         LIBRARY COMPONENT lib DESTINATION ${CMAKE_INSTALL_LIBDIR}
  43         ${TARGET_NAMELINK_COMPONENT}
  44         )
  45 export(EXPORT libmemcachedprotocol-targets NAMESPACE libmemcached::)
  46 install(EXPORT libmemcachedprotocol-targets NAMESPACE libmemcached::
  47         COMPONENT dev
  48         DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME})