git.m6w6.name Git - awesomized/libmemcached/blob - src/libmemcached/CMakeLists.txt

   1
   2 find_package(FLEX)
   3 find_package(BISON 2.3)
   4
   5 if(${BISON_VERSION} VERSION_GREATER_EQUAL 3.0)
   6         set(BISON_WARNINGS -Wno-deprecated)
   7 endif()
   8
   9 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/csl)
  10 bison_target(CSL_PARSER csl/parser.yy ${CMAKE_CURRENT_BINARY_DIR}/csl/parser.cc
  11         DEFINES_FILE ${CMAKE_CURRENT_BINARY_DIR}/csl/parser.h
  12         COMPILE_FLAGS ${BISON_WARNINGS}
  13         )
  14 flex_target(CSL_SCANNER csl/scanner.l ${CMAKE_CURRENT_BINARY_DIR}/csl/scanner.cc
  15         DEFINES_FILE ${CMAKE_CURRENT_BINARY_DIR}/csl/scanner.h
  16         )
  17 add_flex_bison_dependency(CSL_SCANNER CSL_PARSER)
  18
  19 if(HAVE_DTRACE)
  20         add_custom_command(
  21                 OUTPUT dtrace_probes.h
  22                 COMMAND ${DTRACE_EXECUTABLE}
  23                 ARGS -h -o dtrace_probes.h -s ${CMAKE_CURRENT_SOURCE_DIR}/libmemcached_probes.d
  24                 MAIN_DEPENDENCY libmemcached_probes.d
  25         )
  26         add_custom_command(
  27                 OUTPUT libmemcached_probes.o
  28                 COMMAND ${DTRACE_EXECUTABLE}
  29                 ARGS -o libmemcached_probes.o -G -s ${CMAKE_CURRENT_SOURCE_DIR}/libmemcached_probes.d
  30                 MAIN_DEPENDENCY dtrace_probes.h
  31         )
  32         set(DTRACE_GENERATED_OUTPUT libmemcached_probes.o)
  33 endif()
  34
  35 set(LIBMEMCACHED_SOURCES
  36         csl/context.cc
  37         ${BISON_CSL_PARSER_OUTPUTS}
  38         ${FLEX_CSL_SCANNER_OUTPUTS}
  39         ${DTRACE_GENERATED_OUTPUT}
  40         allocators.cc
  41         analyze.cc
  42         array.c
  43         auto.cc
  44         backtrace.cc
  45         behavior.cc
  46         byteorder.cc
  47         callback.cc
  48         common.h
  49         connect.cc
  50         delete.cc
  51         do.cc
  52         dump.cc
  53         encoding_key.cc
  54         error.cc
  55         exist.cc
  56         fetch.cc
  57         flag.cc
  58         flush.cc
  59         flush_buffers.cc
  60         get.cc
  61         hash.cc
  62         hosts.cc
  63         initialize_query.cc
  64         instance.cc
  65         io.cc
  66         key.cc
  67         memcached.cc
  68         namespace.cc
  69         options.cc
  70         parse.cc
  71         poll.cc
  72         purge.cc
  73         quit.cc
  74         response.cc
  75         result.cc
  76         sasl.cc
  77         server.cc
  78         server_list.cc
  79         stats.cc
  80         storage.cc
  81         strerror.cc
  82         string.cc
  83         touch.cc
  84         udp.cc
  85         verbosity.cc
  86         version.cc
  87         virtual_bucket.c)
  88
  89 add_library(libmemcached SHARED
  90         ${LIBMEMCACHED_SOURCES})
  91 add_library(memcached ALIAS libmemcached)
  92 set_target_properties(libmemcached PROPERTIES
  93         LIBRARY_OUTPUT_NAME memcached
  94         INSTALL_RPATH $ORIGIN
  95         SOVERSION ${LIBMEMCACHED_SO_VERSION}
  96         VERSION v${LIBMEMCACHED_VERSION})
  97 target_compile_definitions(libmemcached PRIVATE -DBUILDING_LIBMEMCACHED)
  98 target_link_libraries(libmemcached PUBLIC libhashkit Threads::Threads ${LIBSASL_LIBRARIES} ${CMAKE_DL_LIBS})
  99 target_include_directories(libmemcached PRIVATE ${LIBSASL_INCLUDEDIR})
 100 target_include_directories(libmemcached PRIVATE
 101         ${CMAKE_SOURCE_DIR}/src
 102         ${CMAKE_BINARY_DIR}/src
 103         ${CMAKE_BINARY_DIR})
 104 target_include_directories(libmemcached PUBLIC
 105         $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/include>
 106         $<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/include>
 107         $<INSTALL_INTERFACE:include>)
 108
 109 install(TARGETS libmemcached EXPORT libmemcached
 110         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
 111 export(EXPORT libmemcached)
 112 install(EXPORT libmemcached DESTINATION ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/cmake)
 113
 114 install_public_headers(
 115         libmemcached
 116
 117         memcached.h
 118         memcached.hpp
 119         util.h
 120         )
 121
 122 add_library(libmemcachedinternal STATIC
 123         ${LIBMEMCACHED_SOURCES})
 124 add_library(memcachedinternal ALIAS libmemcachedinternal)
 125 set_target_properties(libmemcachedinternal PROPERTIES LIBRARY_OUTPUT_NAME memcachedinternal)
 126 target_compile_definitions(libmemcachedinternal PRIVATE -DBUILDING_LIBMEMCACHEDINTERNAL)
 127 target_link_libraries(libmemcachedinternal PUBLIC libhashkit Threads::Threads ${LIBSASL_LIBRARIES} ${CMAKE_DL_LIBS})
 128 target_include_directories(libmemcachedinternal PRIVATE ${LIBSASL_INCLUDEDIR})
 129 target_include_directories(libmemcachedinternal PRIVATE
 130         ${CMAKE_SOURCE_DIR}/src
 131         ${CMAKE_BINARY_DIR}/src
 132         ${CMAKE_BINARY_DIR})
 133 target_include_directories(libmemcachedinternal PUBLIC
 134         $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/include>
 135         $<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/include>
 136         $<INSTALL_INTERFACE:include>)
 137
 138 # let libmemcached depend on libmemcachedinternal to ensure that they do not
 139 # compete for the same generated dependencies
 140 add_dependencies(libmemcached libmemcachedinternal)