git.m6w6.name Git - awesomized/libmemcached/blob - src/libmemcached/CMakeLists.txt

   1
   2 find_package(FLEX)
   3 find_package(BISON 2.3)
   4
   5 if("${BISON_VERSION}" VERSION_GREATER_EQUAL 3.0)
   6         set(BISON_WARNINGS -Wno-deprecated)
   7 endif()
   8
   9 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/csl)
  10 bison_target(CSL_PARSER csl/parser.yy ${CMAKE_CURRENT_BINARY_DIR}/csl/parser.cc
  11         DEFINES_FILE ${CMAKE_CURRENT_BINARY_DIR}/csl/parser.h
  12         COMPILE_FLAGS ${BISON_WARNINGS}
  13         )
  14 set_source_files_properties(${BISON_CSL_PARSER_OUTPUTS} PROPERTIES SKIP_UNITY_BUILD_INCLUSION ON)
  15 if(NOT HAVE_UNISTD_H)
  16         set(FLEX_FLAGS --nounistd)
  17 endif()
  18 flex_target(CSL_SCANNER csl/scanner.l ${CMAKE_CURRENT_BINARY_DIR}/csl/scanner.cc
  19         DEFINES_FILE ${CMAKE_CURRENT_BINARY_DIR}/csl/scanner.h
  20         COMPILE_FLAGS "${FLEX_FLAGS}"
  21         )
  22 set_source_files_properties(${FLEX_CSL_SCANNER_OUTPUTS} PROPERTIES SKIP_UNITY_BUILD_INCLUSION ON)
  23 add_flex_bison_dependency(CSL_SCANNER CSL_PARSER)
  24
  25 set(LIBMEMCACHED_SOURCES
  26         csl/context.cc
  27         ${BISON_CSL_PARSER_OUTPUTS}
  28         ${FLEX_CSL_SCANNER_OUTPUTS}
  29         allocators.cc
  30         analyze.cc
  31         array.cc
  32         auto.cc
  33         backtrace.cc
  34         behavior.cc
  35         byteorder.cc
  36         callback.cc
  37         common.h
  38         connect.cc
  39         delete.cc
  40         do.cc
  41         dump.cc
  42         encoding_key.cc
  43         error.cc
  44         exist.cc
  45         fetch.cc
  46         flag.cc
  47         flush.cc
  48         flush_buffers.cc
  49         get.cc
  50         hash.cc
  51         hosts.cc
  52         initialize_query.cc
  53         instance.cc
  54         io.cc
  55         key.cc
  56         memcached.cc
  57         namespace.cc
  58         options.cc
  59         parse.cc
  60         purge.cc
  61         quit.cc
  62         response.cc
  63         result.cc
  64         sasl.cc
  65         server.cc
  66         server_list.cc
  67         stats.cc
  68         storage.cc
  69         strerror.cc
  70         string.cc
  71         touch.cc
  72         udp.cc
  73         verbosity.cc
  74         version.cc
  75         virtual_bucket.cc)
  76
  77 check_cxx_compiler_flag(-Wno-deprecated-register W_NO_DEPRECATED_REGISTER)
  78
  79 if(W_NO_DEPRECATED_REGISTER)
  80         set_source_files_properties(
  81                 ${FLEX_CSL_SCANNER_OUTPUTS}
  82                 ${BISON_CSL_PARSER_OUTPUTS}
  83                 PROPERTIES COMPILE_OPTIONS -Wno-deprecated-register
  84         )
  85 endif()
  86
  87 add_library(libmemcached SHARED
  88         ${LIBMEMCACHED_SOURCES})
  89 add_library(memcached ALIAS libmemcached)
  90 set_target_properties(libmemcached PROPERTIES
  91         CXX_STANDARD ${CXX_STANDARD}
  92         LIBRARY_OUTPUT_NAME memcached
  93         LIBRARY_OUTPUT_NAME_DEBUG memcached-dbg
  94         SOVERSION ${LIBMEMCACHED_SO_SOVERSION}
  95         VERSION ${LIBMEMCACHED_SO_VERSION})
  96 target_compile_definitions(libmemcached PRIVATE -DBUILDING_LIBMEMCACHED)
  97 target_link_libraries(libmemcached PUBLIC libhashkit Threads::Threads ${CMAKE_DL_LIBS})
  98 target_link_libraries(libmemcached PRIVATE p9y)
  99 if(MSVC)
 100     target_link_libraries(libmemcached PUBLIC wsock32 ws2_32)
 101 endif()
 102 if(HAVE_BACKTRACE)
 103     target_link_libraries(libmemcached PUBLIC ${BACKTRACE})
 104 endif()
 105 if(HAVE_LIBSASL)
 106     target_link_libraries(libmemcached PUBLIC ${LIBSASL})
 107 endif()
 108 if(CMAKE_CXX_COMPILER_ID STREQUAL "SunPro")
 109     # see https://docs.oracle.com/cd/E77782_01/html/E77789/bkamq.html#OSSCPgrxeu
 110     target_link_libraries(libmemcached INTERFACE stdc++ gcc_s CrunG3 c)
 111 endif()
 112 target_include_directories(libmemcached PRIVATE
 113         ${CMAKE_SOURCE_DIR}/src
 114         ${CMAKE_BINARY_DIR}/src
 115         ${CMAKE_BINARY_DIR})
 116 target_include_directories(libmemcached PUBLIC
 117         $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/include>
 118         $<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/include>
 119         $<INSTALL_INTERFACE:include>)
 120
 121 enable_dtrace_for(libmemcached libmemcached_probes.d dtrace_probes.h)
 122
 123 install(TARGETS libmemcached EXPORT libmemcached-targets
 124         RUNTIME COMPONENT bin DESTINATION ${CMAKE_INSTALL_BINDIR}
 125         ARCHIVE COMPONENT lib DESTINATION ${CMAKE_INSTALL_LIBDIR}
 126         LIBRARY COMPONENT lib DESTINATION ${CMAKE_INSTALL_LIBDIR}
 127         ${TARGET_NAMELINK_COMPONENT}
 128         )
 129 export(EXPORT libmemcached-targets NAMESPACE libmemcached::)
 130 install(EXPORT libmemcached-targets NAMESPACE libmemcached::
 131         COMPONENT dev
 132         DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME})
 133
 134 install_public_headers(
 135         libmemcached
 136
 137         memcached.h
 138         memcached.hpp
 139         util.h
 140         )
 141
 142 add_library(libmemcachedinternal STATIC
 143         ${LIBMEMCACHED_SOURCES})
 144 add_library(memcachedinternal ALIAS libmemcachedinternal)
 145 set_target_properties(libmemcachedinternal PROPERTIES CXX_STANDARD ${CXX_STANDARD} LIBRARY_OUTPUT_NAME memcachedinternal)
 146 target_compile_definitions(libmemcachedinternal PRIVATE -DBUILDING_LIBMEMCACHEDINTERNAL)
 147 target_link_libraries(libmemcachedinternal PUBLIC libhashkit Threads::Threads ${CMAKE_DL_LIBS})
 148 target_link_libraries(libmemcachedinternal PRIVATE p9y)
 149 if(MSVC OR MINGW)
 150     target_link_libraries(libmemcached PUBLIC wsock32 ws2_32)
 151 endif()
 152 if(HAVE_LIBSASL)
 153     target_link_libraries(libmemcachedinternal PUBLIC ${LIBSASL})
 154 endif()
 155 if(HAVE_BACKTRACE)
 156     target_link_libraries(libmemcachedinternal PUBLIC ${BACKTRACE})
 157 endif()
 158 target_include_directories(libmemcachedinternal PRIVATE
 159         ${CMAKE_SOURCE_DIR}/src
 160         ${CMAKE_BINARY_DIR}/src
 161         ${CMAKE_BINARY_DIR})
 162 target_include_directories(libmemcachedinternal PUBLIC
 163         $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/include>
 164         $<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/include>
 165         $<INSTALL_INTERFACE:include>)
 166
 167 enable_dtrace_for(libmemcachedinternal libmemcached_probes.d dtrace_probes.h)
 168
 169 # let libmemcached depend on libmemcachedinternal to ensure that they do not
 170 # compete for the same generated dependencies
 171 add_dependencies(libmemcached libmemcachedinternal)