git.m6w6.name Git - awesomized/libmemcached/blob - memcached/t/whitespace.t

   1 #!/usr/bin/perl
   2 use strict;
   3 use FindBin qw($Bin);
   4 our @files;
   5
   6 BEGIN {
   7     chdir "$Bin/.." or die;
   8
   9     my @exempted = qw(Makefile.am ChangeLog doc/Makefile.am README README.md);
  10     push(@exempted, glob("doc/*.xml"));
  11     push(@exempted, glob("doc/xml2rfc/*.xsl"));
  12     push(@exempted, glob("m4/*backport*m4"));
  13     push(@exempted, glob("*.orig"));
  14     my %exempted_hash = map { $_ => 1 } @exempted;
  15
  16     my @stuff = split /\0/, `git ls-files -z -c -m -o --exclude-standard`;
  17     @files = grep { ! $exempted_hash{$_} } @stuff;
  18
  19     # We won't find any files if git isn't installed.  If git isn't
  20     # installed, they're probably not doing any useful development, or
  21     # at the very least am will clean up whitespace when we receive
  22     # their patch.
  23     unless (@files) {
  24         use Test::More;
  25         plan skip_all => "Skipping tests probably because you don't have git.";
  26         exit 0;
  27     }
  28 }
  29
  30 use Test::More tests => scalar(@files);
  31
  32 foreach my $f (@files) {
  33     open(my $fh, $f) or die "Cannot open file $f: $!";
  34     my $before = do { local $/; <$fh>; };
  35     close ($fh);
  36     my $after = $before;
  37     $after =~ s/\t/    /g;
  38     $after =~ s/ +$//mg;
  39     $after .= "\n" unless $after =~ /\n$/;
  40     ok ($after eq $before, "$f (see devtools/clean-whitespace.pl)");
  41 }