git.m6w6.name Git - awesomized/libmemcached/blob - memcached/t/slabs_reassign.t

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5 use Test::More tests => 130;
   6 use FindBin qw($Bin);
   7 use lib "$Bin/lib";
   8 use MemcachedTest;
   9
  10 # Enable manual slab reassign, cap at 6 slabs
  11 my $server = new_memcached('-o slab_reassign -m 4');
  12 my $stats = mem_stats($server->sock, ' settings');
  13 is($stats->{slab_reassign}, "yes");
  14
  15 my $sock = $server->sock;
  16
  17 # Fill a largeish slab until it evicts (honors the -m 6)
  18 my $bigdata = 'x' x 70000; # slab 31
  19 for (1 .. 60) {
  20     print $sock "set bfoo$_ 0 0 70000\r\n", $bigdata, "\r\n";
  21     is(scalar <$sock>, "STORED\r\n", "stored key");
  22 }
  23
  24 # Fill a smaller slab until it evicts
  25 my $smalldata = 'y' x 20000; # slab 25
  26 for (1 .. 60) {
  27     print $sock "set sfoo$_ 0 0 20000\r\n", $smalldata, "\r\n";
  28     is(scalar <$sock>, "STORED\r\n", "stored key");
  29 }
  30
  31 my $items_before = mem_stats($sock, "items");
  32 isnt($items_before->{"items:31:evicted"}, 0, "slab 31 evicted is nonzero");
  33 isnt($items_before->{"items:25:evicted"}, 0, "slab 25 evicted is nonzero");
  34
  35 my $slabs_before = mem_stats($sock, "slabs");
  36 # Move a large slab to the smaller slab
  37 print $sock "slabs reassign 31 25\r\n";
  38 is(scalar <$sock>, "OK\r\n", "slab rebalancer started");
  39
  40 # Still working out how/if to signal the thread. For now, just sleep.
  41 sleep 2;
  42
  43 # Check that stats counters increased
  44 my $slabs_after = mem_stats($sock, "slabs");
  45 $stats = mem_stats($sock);
  46
  47 isnt($stats->{slabs_moved}, 0, "slabs moved is nonzero");
  48
  49 # Check that slab stats reflect the change
  50 ok($slabs_before->{"31:total_pages"} != $slabs_after->{"31:total_pages"},
  51     "slab 31 pagecount changed");
  52 ok($slabs_before->{"25:total_pages"} != $slabs_after->{"25:total_pages"},
  53     "slab 25 pagecount changed");
  54
  55 # Try to move another slab, see that you can move two in a row
  56 print $sock "slabs reassign 31 25\r\n";
  57 like(scalar <$sock>, qr/^OK/, "Cannot re-run against class with empty space");
  58
  59 # Try to move a page backwards. Should complain that source class isn't "safe"
  60 # to move from.
  61 # TODO: Wait until the above command completes, then try to move it back?
  62 # Seems pointless...
  63 #print $sock "slabs reassign 25 31\r\n";
  64 #like(scalar <$sock>, qr/^UNSAFE/, "Cannot move an unsafe slab back");
  65
  66 # Try to insert items into both slabs
  67 print $sock "set bfoo51 0 0 70000\r\n", $bigdata, "\r\n";
  68 is(scalar <$sock>, "STORED\r\n", "stored key");
  69
  70 print $sock "set sfoo51 0 0 20000\r\n", $smalldata, "\r\n";
  71 is(scalar <$sock>, "STORED\r\n", "stored key");
  72
  73 # Do need to come up with better automated tests for this.