git.m6w6.name Git - awesomized/libmemcached/blob - m4/pandora_canonical.m4

   1 dnl  Copyright (C) 2009 Sun Microsystems, Inc.
   2 dnl This file is free software; Sun Microsystems, Inc.
   3 dnl gives unlimited permission to copy and/or distribute it,
   4 dnl with or without modifications, as long as this notice is preserved.
   5
   6 dnl Which version of the canonical setup we're using
   7 AC_DEFUN([PANDORA_CANONICAL_VERSION],[0.175])
   8
   9 AC_DEFUN([PANDORA_BLOCK_BAD_OPTIONS],[
  10   AS_IF([test "x${prefix}" = "x"],[
  11     AC_MSG_ERROR([--prefix requires an argument])
  12   ])
  13 ])
  14
  15 dnl The standard setup for how we build Pandora projects
  16 AC_DEFUN([PANDORA_CANONICAL_TARGET],[
  17   ifdef([m4_define],,[define([m4_define],   defn([define]))])
  18   ifdef([m4_undefine],,[define([m4_undefine],   defn([undefine]))])
  19   m4_define([PCT_ALL_ARGS],[$*])
  20   m4_define([PCT_REQUIRE_CXX],[no])
  21   m4_define([PCT_FORCE_GCC42],[no])
  22   m4_define([PCT_DONT_SUPPRESS_INCLUDE],[no])
  23   m4_define([PCT_NO_VC_CHANGELOG],[no])
  24   m4_define([PCT_VERSION_FROM_VC],[no])
  25   m4_define([PCT_USE_VISIBILITY],[yes])
  26   m4_foreach([pct_arg],[$*],[
  27     m4_case(pct_arg,
  28       [require-cxx], [
  29         m4_undefine([PCT_REQUIRE_CXX])
  30         m4_define([PCT_REQUIRE_CXX],[yes])
  31       ],
  32       [force-gcc42], [
  33         m4_undefine([PCT_FORCE_GCC42])
  34         m4_define([PCT_FORCE_GCC42],[yes])
  35       ],
  36       [skip-visibility], [
  37         m4_undefine([PCT_USE_VISIBILITY])
  38         m4_define([PCT_USE_VISIBILITY],[no])
  39       ],
  40       [dont-suppress-include], [
  41         m4_undefine([PCT_DONT_SUPPRESS_INCLUDE])
  42         m4_define([PCT_DONT_SUPPRESS_INCLUDE],[yes])
  43       ],
  44       [version-from-vc], [
  45         m4_undefine([PCT_VERSION_FROM_VC])
  46         m4_define([PCT_VERSION_FROM_VC],[yes])
  47     ])
  48   ])
  49
  50   PANDORA_BLOCK_BAD_OPTIONS
  51
  52   # We need to prevent canonical target
  53   # from injecting -O2 into CFLAGS - but we won't modify anything if we have
  54   # set CFLAGS on the command line, since that should take ultimate precedence
  55   AS_IF([test "x${ac_cv_env_CFLAGS_set}" = "x"],
  56         [CFLAGS=""])
  57   AS_IF([test "x${ac_cv_env_CXXFLAGS_set}" = "x"],
  58         [CXXFLAGS=""])
  59
  60   AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects foreign tar-ustar])
  61
  62   m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  63
  64   m4_if(m4_substr(m4_esyscmd(test -d gnulib && echo 0),0,1),0,[
  65     gl_EARLY
  66   ],[
  67     PANDORA_EXTENSIONS
  68   ])
  69
  70   AC_REQUIRE([AC_PROG_CC])
  71   m4_if(PCT_FORCE_GCC42, [yes], [
  72     AC_REQUIRE([PANDORA_ENSURE_GCC_VERSION])
  73   ])
  74   AC_REQUIRE([PANDORA_64BIT])
  75
  76   m4_if(PCT_NO_VC_CHANGELOG,yes,[
  77     vc_changelog=no
  78   ],[
  79     vc_changelog=yes
  80   ])
  81   m4_if(PCT_VERSION_FROM_VC,yes,[
  82     PANDORA_VC_INFO_HEADER
  83   ],[
  84     PANDORA_TEST_VC_DIR
  85
  86     changequote(<<, >>)dnl
  87     PANDORA_RELEASE_ID=`echo $VERSION | sed 's/[^0-9]//g'`
  88     changequote([, ])dnl
  89
  90     PANDORA_RELEASE_COMMENT=""
  91     AC_DEFINE_UNQUOTED([PANDORA_RELEASE_VERSION],["$VERSION"],
  92                        [Version of the software])
  93
  94     AC_SUBST(PANDORA_RELEASE_COMMENT)
  95     AC_SUBST(PANDORA_RELEASE_VERSION)
  96     AC_SUBST(PANDORA_RELEASE_ID)
  97   ])
  98   PANDORA_VERSION
  99
 100   dnl Once we can use a modern autoconf, we can use this
 101   dnl AC_PROG_CC_C99
 102   AC_REQUIRE([AC_PROG_CXX])
 103   PANDORA_EXTENSIONS
 104   AM_PROG_CC_C_O
 105
 106
 107
 108   PANDORA_PLATFORM
 109
 110   dnl autoconf doesn't automatically provide a fail-if-no-C++ macro
 111   dnl so we check c++98 features and fail if we don't have them, mainly
 112   dnl for that reason
 113   m4_if(PCT_REQUIRE_CXX, [yes], [
 114     AS_IF([test "$ac_cv_cxx_stdcxx_98" = "no"],[
 115       AC_MSG_ERROR([No working C++ Compiler has been found. ${PACKAGE} requires a C++ compiler that can handle C++98])
 116     ])
 117   ])
 118
 119   m4_if(m4_substr(m4_esyscmd(test -d gnulib && echo 0),0,1),0,[
 120     gl_INIT
 121     AC_CONFIG_LIBOBJ_DIR([gnulib])
 122   ])
 123
 124   PANDORA_CHECK_CXX_VERSION
 125
 126   AC_HEADER_TIME
 127   AC_STRUCT_TM
 128   AC_TYPE_SIZE_T
 129   AC_SYS_LARGEFILE
 130   PANDORA_CLOCK_GETTIME
 131
 132   AC_CHECK_HEADERS(sys/socket.h)
 133
 134   # off_t is not a builtin type
 135   AC_CHECK_SIZEOF(off_t, 4)
 136   AS_IF([test "$ac_cv_sizeof_off_t" -eq 0],[
 137     AC_MSG_ERROR("${PACKAGE} needs an off_t type.")
 138   ])
 139
 140   AC_CHECK_SIZEOF(size_t)
 141   AS_IF([test "$ac_cv_sizeof_size_t" -eq 0],[
 142     AC_MSG_ERROR("${PACKAGE} needs an size_t type.")
 143   ])
 144
 145   AC_DEFINE_UNQUOTED([SIZEOF_SIZE_T],[$ac_cv_sizeof_size_t],[Size of size_t as computed by sizeof()])
 146   AC_CHECK_SIZEOF(long long)
 147   AC_DEFINE_UNQUOTED([SIZEOF_LONG_LONG],[$ac_cv_sizeof_long_long],[Size of long long as computed by sizeof()])
 148   AC_CACHE_CHECK([if time_t is unsigned], [ac_cv_time_t_unsigned],[
 149   AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 150       [[
 151 #include <time.h>
 152       ]],
 153       [[
 154       int array[(((time_t)-1) > 0) ? 1 : -1];
 155       ]])
 156     ],[
 157       ac_cv_time_t_unsigned=yes
 158     ],[
 159       ac_cv_time_t_unsigned=no
 160     ])
 161   ])
 162   AS_IF([test "$ac_cv_time_t_unsigned" = "yes"],[
 163     AC_DEFINE([TIME_T_UNSIGNED], 1, [Define to 1 if time_t is unsigned])
 164   ])
 165
 166   AC_CHECK_FUNC(setsockopt, [], [AC_CHECK_LIB(socket, setsockopt)])
 167   AC_CHECK_FUNC(bind, [], [AC_CHECK_LIB(bind, bind)])
 168
 169
 170
 171   PANDORA_OPTIMIZE
 172
 173   PANDORA_HAVE_GCC_ATOMICS
 174
 175   PANDORA_WARNINGS(PCT_ALL_ARGS)
 176
 177   PANDORA_ENABLE_DTRACE
 178
 179   AC_LIB_PREFIX
 180   PANDORA_HAVE_BETTER_MALLOC
 181
 182   m4_if(m4_substr(m4_esyscmd(test -d src && echo 0),0,1),0,[
 183     AM_CPPFLAGS="-I\$(top_srcdir)/src -I\$(top_builddir)/src ${AM_CPPFLAGS}"
 184   ],[
 185     AM_CPPFLAGS="-I\$(top_srcdir) -I\$(top_builddir) ${AM_CPPFLAGS}"
 186   ])
 187
 188   PANDORA_USE_PIPE
 189
 190   AM_CFLAGS="-std=c99 ${AM_CFLAGS} ${CC_WARNINGS} ${CC_PROFILING} ${CC_COVERAGE}"
 191   AM_CXXFLAGS="${AM_CXXFLAGS} ${CXX_WARNINGS} ${CC_PROFILING} ${CC_COVERAGE}"
 192
 193   AC_SUBST([AM_CFLAGS])
 194   AC_SUBST([AM_CXXFLAGS])
 195   AC_SUBST([AM_CPPFLAGS])
 196   AC_SUBST([AM_LDFLAGS])
 197
 198 ])