git.m6w6.name Git - awesomized/libmemcached/blob - configure.ac

   1 # LibmemcacheD
   2 # Copyright (C) 2011-2012 Data Differential, http://datadifferential.com/
   3 # Copyright (C) 2006-2010 Brian Aker, Monty Taylor, Trond Norbye
   4 # All rights reserved.
   5 #
   6 # Use and distribution licensed under the BSD license.  See
   7 # the COPYING file in this directory for full text.
   8
   9 AC_INIT([libmemcached],[1.0.15],[http://libmemcached.org/])
  10 AC_CONFIG_AUX_DIR([build-aux])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_CANONICAL_TARGET
  14 AC_ARG_PROGRAM
  15 AC_USE_SYSTEM_EXTENSIONS
  16
  17 AM_INIT_AUTOMAKE([1.11 color-tests -Wno-portability subdir-objects foreign tar-ustar])
  18
  19 AC_PREREQ([2.61])
  20
  21 AC_CONFIG_HEADERS([mem_config.h:mem_config.in])dnl Keep filename to 8.3 for MS-DOS.
  22 AC_SUBST([AUTOHEADER_FILE],[mem_config.h])
  23 AC_CONFIG_SRCDIR([libmemcached/memcached.cc])
  24
  25 #shared library versioning
  26 MEMCACHED_UTIL_LIBRARY_VERSION=2:0:0
  27 MEMCACHED_PROTOCAL_LIBRARY_VERSION=0:0:0
  28 MEMCACHED_LIBRARY_VERSION=11:0:0
  29 #                         | | |
  30 #                  +------+ | +---+
  31 #                  |        |     |
  32 #                 current:revision:age
  33 #                  |        |     |
  34 #                  |        |     +- increment if interfaces have been added
  35 #                  |        |        set to zero if interfaces have been removed or changed
  36 #                  |        +- increment if source code has changed
  37 #                  |           set to zero if current is incremented
  38 #                  +- increment if interfaces have been added, removed or changed
  39 AC_SUBST([MEMCACHED_UTIL_LIBRARY_VERSION])
  40 AC_SUBST([MEMCACHED_PROTOCAL_LIBRARY_VERSION])
  41 AC_SUBST([MEMCACHED_LIBRARY_VERSION])
  42
  43 AX_HEX_VERSION([LIBMEMCACHED],[$VERSION])
  44 AX_HEX_VERSION([LIBHASHKIT],[1.0.0])
  45
  46 m4_include([libhashkit/include.m4])
  47
  48 LT_PREREQ([2.2])
  49 LT_INIT
  50 LT_LANG([C++])
  51 LT_LIB_M
  52
  53 AX_ASSERT
  54
  55 AX_PLATFORM
  56
  57 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  58
  59 AX_CXX_HEADER_STDCXX_98
  60 AS_IF([test "x$ax_cv_cxx_stdcxx_98" = "xno"],
  61       [AC_MSG_ERROR([Your system lacks a new enough C++ compiler])])
  62
  63 AC_DEFUN([LIBMEMCACHED_PROTOCOL],
  64          [AC_ARG_ENABLE([libmemcachedprotocol],
  65                         [AS_HELP_STRING([--enable-libmemcachedprotocol],
  66                                         [Enable libmemcachedprotocol])],
  67                                         [ax_enable_libmemcachedprotocol=yes],
  68                                         [ax_enable_libmemcachedprotocol=no])
  69
  70          AM_CONDITIONAL([BUILD_LIBMEMCACHED_PROTOCOL],[test "$ax_enable_libmemcachedprotocol" = "yes"])
  71
  72          AC_MSG_CHECKING([for libmemcachedprotocol])
  73          AC_MSG_RESULT([$ax_enable_libmemcachedprotocol])
  74          ])
  75 LIBMEMCACHED_PROTOCOL
  76
  77 # Adding support for libtest
  78 m4_include([libtest/yatl.m4])
  79
  80 CHECK_FOR_GEARMAND
  81 CHECK_FOR_LIBGEARMAND
  82
  83 AM_CONDITIONAL([BUILDING_LIBMEMCACHED],[true])
  84 AM_CONDITIONAL([HAVE_LIBMEMCACHED],[false])
  85 AM_CONDITIONAL([HAVE_LIBDRIZZLE],[false])
  86 AC_DEFINE([HAVE_LIBMEMCACHED],[1],[Enables libmemcached Support])
  87 AC_SUBST([LIBMEMCACHED_CFLAGS])
  88 AC_SUBST([LIBMEMCACHED_LIB],[libmemcached/libmemcached.la])
  89
  90 AM_CONDITIONAL([BUILDING_GEARMAN],[false])
  91
  92 # Specialty checks
  93 AX_CXX_CINTTYPES
  94 CONFIG_EXTRA
  95 DETECT_BYTEORDER
  96 SETSOCKOPT_SANITY
  97 ENABLE_HSIEH_HASH
  98 ENABLE_MURMUR_HASH
  99 ENABLE_FNV64_HASH
 100 ENABLE_MEMASLAP
 101 PROTOCOL_BINARY_TEST
 102 ENABLE_DEPRECATED
 103
 104 # Checks for programs.
 105 AC_CHECK_PROGS([LEX],['flex'],[:])
 106 AC_CHECK_PROGS([YACC],['bison'],[:])
 107 AX_PROG_SPHINX_BUILD
 108
 109 # Checks for libraries.
 110 AC_SEARCH_LIBS([getopt_long],[gnugetopt])
 111 AC_SEARCH_LIBS([gethostbyname],[nsl])
 112
 113 # Checks for header files.
 114 AC_CHECK_HEADERS_ONCE([arpa/inet.h])
 115 AC_CHECK_HEADERS_ONCE([errno.h])
 116 AC_CHECK_HEADERS_ONCE([execinfo.h])
 117 AC_CHECK_HEADERS_ONCE([fcntl.h])
 118 AC_CHECK_HEADERS_ONCE([features.h])
 119 AC_CHECK_HEADERS_ONCE([fnmatch.h])
 120 AC_CHECK_HEADERS_ONCE([inttypes.h])
 121 AC_CHECK_HEADERS_ONCE([libintl.h])
 122 AC_CHECK_HEADERS_ONCE([limits.h])
 123 AC_CHECK_HEADERS_ONCE([mach/mach.h])
 124 AC_CHECK_HEADERS_ONCE([malloc.h])
 125 AC_CHECK_HEADERS_ONCE([math.h])
 126 AC_CHECK_HEADERS_ONCE([netdb.h])
 127 AC_CHECK_HEADERS_ONCE([netinet/in.h])
 128 AC_CHECK_HEADERS_ONCE([netinet/tcp.h])
 129 AC_CHECK_HEADERS_ONCE([poll.h])
 130 AC_CHECK_HEADERS_ONCE([pthread.h])
 131 AC_CHECK_HEADERS_ONCE([spawn.h])
 132 AC_CHECK_HEADERS_ONCE([stdarg.h])
 133 AC_CHECK_HEADERS_ONCE([stddef.h])
 134 AC_CHECK_HEADERS_ONCE([stdio.h])
 135 AC_CHECK_HEADERS_ONCE([stdlib.h])
 136 AC_CHECK_HEADERS_ONCE([sys/socket.h])
 137 AC_CHECK_HEADERS_ONCE([sys/sysctl.h])
 138 AC_CHECK_HEADERS_ONCE([sys/time.h])
 139 AC_CHECK_HEADERS_ONCE([sys/types.h])
 140 AC_CHECK_HEADERS_ONCE([sys/un.h])
 141 AC_CHECK_HEADERS_ONCE([sys/wait.h])
 142 AC_CHECK_HEADERS_ONCE([syslog.h])
 143 AC_CHECK_HEADERS_ONCE([time.h])
 144 AC_CHECK_HEADERS_ONCE([unistd.h])
 145
 146 # Windows only
 147 AC_CHECK_HEADERS_ONCE([winsock2.h])
 148 AC_CHECK_HEADERS_ONCE([ws2tcpip.h])
 149
 150 # Checks for typedefs, structures, and compiler characteristics.
 151
 152 # Checks for library functions.
 153
 154 AC_CHECK_FUNCS([alarm])
 155 AC_CHECK_FUNCS([atexit])
 156 AC_CHECK_FUNCS([clock_gettime])
 157 AC_CHECK_FUNCS([dup2])
 158 AC_CHECK_FUNCS([fcntl])
 159 AC_CHECK_FUNCS([floor])
 160 AC_CHECK_FUNCS([getcwd])
 161 AC_CHECK_FUNCS([getline])
 162 AC_CHECK_FUNCS([gettimeofday])
 163 AC_CHECK_FUNCS([inet_ntoa])
 164 AC_CHECK_FUNCS([memchr])
 165 AC_CHECK_FUNCS([memmove])
 166 AC_CHECK_FUNCS([memset])
 167 AC_CHECK_FUNCS([pipe2])
 168 AC_CHECK_FUNCS([putenv])
 169 AC_CHECK_FUNCS([select])
 170 AC_CHECK_FUNCS([setenv])
 171 AC_CHECK_FUNCS([sigignore])
 172 AC_CHECK_FUNCS([socket])
 173 AC_CHECK_FUNCS([sqrt])
 174 AC_CHECK_FUNCS([strcasecmp])
 175 AC_CHECK_FUNCS([strchr])
 176 AC_CHECK_FUNCS([strdup])
 177 AC_CHECK_FUNCS([strerror])
 178 AC_CHECK_FUNCS([strstr])
 179 AC_CHECK_FUNCS([strtol])
 180 AC_CHECK_FUNCS([strtoul])
 181 AC_CHECK_FUNCS([strtoull])
 182 AC_FUNC_ALLOCA
 183 AC_FUNC_ERROR_AT_LINE
 184 AC_FUNC_FORK
 185 AC_FUNC_STRERROR_R
 186
 187 AC_CHECK_HEADER([umem.h],
 188                 [AC_DEFINE([HAVE_UMEM_H],[1],[Define this if you have umem.h])
 189                 build_cache=no],
 190                 [build_cache=yes])
 191
 192 AM_CONDITIONAL([BUILD_CACHE],[test "x$build_cache" = "xyes"])
 193
 194 AX_COMPILER_VENDOR
 195
 196 AC_CHECK_TYPES([in_port_t],,,[[
 197                 #ifdef HAVE_SYS_TYPES_H
 198                 # include <sys/types.h>
 199                 #endif
 200                 #ifdef HAVE_NETINET_IN_H
 201                 # include <netinet/in.h>
 202                 #endif
 203                 #ifdef HAVE_NETDB_H
 204                 # include <netdb.h>
 205                 #endif]])
 206 AC_CHECK_TYPES([ptrdiff_t])
 207 AC_HEADER_STDBOOL
 208 AC_TYPE_INT16_T
 209 AC_TYPE_INT32_T
 210 AC_TYPE_INT64_T
 211 AC_TYPE_INT8_T
 212 AC_TYPE_OFF_T
 213 AC_TYPE_PID_T
 214 AC_TYPE_SSIZE_T
 215 AC_TYPE_UINT16_T
 216 AC_TYPE_UINT32_T
 217 AC_TYPE_UINT64_T
 218 AC_TYPE_UINT8_T
 219
 220 AC_C_BIGENDIAN
 221 AC_C_CONST
 222 AC_C_INLINE
 223 AC_C_VOLATILE
 224 AC_C_RESTRICT
 225
 226 AX_CXX_GCC_ABI_DEMANGLE
 227
 228 AX_LIBEVENT
 229
 230 AC_CHECK_LIB([rt],[clock_gettime],
 231              [AC_SUBST([RT_LIB],[-lrt])
 232              AC_DEFINE([HAVE_CLOCK_GETTIME],[1],[Have clock_gettime])],
 233              [AC_DEFINE([HAVE_CLOCK_GETTIME],[0],[Have clock_gettime])])
 234
 235
 236 # Check for the ability to call dlopen (used in libhostile)
 237 AX_DLOPEN
 238
 239 AC_CHECK_HEADERS([atomic.h])
 240 AS_IF([test "x$ac_cv_header_atomic_h" = "xyes"],
 241       [AC_CHECK_FUNCS([atomic_add_64])
 242       AC_CHECK_FUNCS([atomic_add_32])
 243       AS_IF([test "x$ac_cv_func_atomic_add_64" = "xyes" -a "x$ac_cv_func_atomic_add_32" = "xyes"],
 244             [AC_DEFINE([USE_ATOMIC_H],[1],[Define to true if you want to use functions from atomic.h])])])
 245
 246 AC_DEFINE([HAVE_LIBDRIZZLE],[0],[Support for libdrizzle])
 247 AC_DEFINE([HAVE_DRIZZLED_BINARY],[0],[Support for DrizzleD])
 248 AC_DEFINE([DRIZZLED_BINARY],[0],[Support for DrizzleD])
 249 AC_DEFINE([GEARMAND_BLOBSLAP_WORKER],[0],[Support for Gearman Blobslap worker])
 250 AC_DEFINE([HAVE_LIBPQ],[0],[Support for Postgres])
 251 AC_DEFINE([HAVE_LIBCURL],[0],[Support for libcurl])
 252
 253 # Check for the requirements for running memcached with less privileges
 254 # than the default privilege set. On Solaris we need setppriv and priv.h
 255 # If you want to add support for other platforms you should check for
 256 # your requirements, define HAVE_DROP_PRIVILEGES, and make sure you add
 257 # the source file containing the implementation into memcached_SOURCE
 258 # in Makefile.am
 259 AC_CHECK_FUNCS([setppriv],
 260                [AC_CHECK_HEADER([priv.h],
 261                                 [AC_DEFINE([HAVE_DROP_PRIVILEGES],
 262                                            [1],
 263                                            [Define this if you have an implementation of drop_privileges()])
 264                                 build_solaris_privs=yes])
 265                ])
 266
 267 AM_CONDITIONAL([BUILD_POLL],[test "x$ac_cv_header_poll_h" = "xno"])
 268 AM_CONDITIONAL([BUILD_WIN32_WRAPPERS],[test "x$ac_cv_header_winsock2_h" = "xyes"])
 269 AS_IF([test "x$ac_cv_header_winsock2_h" = "xyes"],
 270       [AM_LDFLAGS="$AM_LDFLAGS -lws2_32"
 271        AM_CFLAGS="$AM_CFLAGS $NO_WERROR"
 272        AM_CXXFLAGS="$AM_CXXFLAGS $NO_WERROR"
 273        ])
 274 SOCKET_SEND_FLAGS
 275
 276 AX_UUID_GENERATE_TIME_SAFE
 277
 278 AC_DEFUN([CHECK_FOR_PTHREAD_AND_SASL],
 279          [AX_PTHREAD(, [AC_MSG_ERROR([could not find libpthread])])
 280          AX_PTHREAD_TIMEDJOIN_NP
 281
 282          # The sasl functions should only be visible if we build with sasl support
 283          #
 284          AX_SASL_OPTION
 285          AS_IF([test "x$ac_enable_sasl" = xyes],
 286                [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 1"],
 287                [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 0"])
 288          AC_SUBST([LIBMEMCACHED_WITH_SASL_SUPPORT])
 289          ])
 290 CHECK_FOR_PTHREAD_AND_SASL
 291
 292
 293 # backtrace(), others require shared builds
 294 AS_IF([test "x$enable_shared" = "xyes"],
 295       [AC_DEFINE([HAVE_SHARED_ENABLED],[1],[Enable code which requires shared library support. Like backtrace().])])
 296 AM_CONDITIONAL([SHARED_ENABLED],[test "x$enable_shared" = "xyes"])
 297
 298 PANDORA_ENABLE_DTRACE
 299 HAVE_GCC_ATOMICS
 300 AX_ENDIAN
 301 AX_ASSERT
 302 AX_HARDEN_COMPILER_FLAGS
 303
 304 AX_AM_JOBSERVER([yes])
 305
 306 AC_CONFIG_FILES([Makefile
 307                  docs/conf.py
 308                  libmemcached-1.0/configure.h
 309                  support/libmemcached.pc
 310                  support/libmemcached.spec
 311                  ])
 312 AC_OUTPUT
 313
 314 echo "---"
 315 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 316 echo ""
 317 echo "   * Installation prefix:       $prefix"
 318 echo "   * System type:               $host_vendor-$host_os"
 319 echo "   * Host CPU:                  $host_cpu"
 320 echo "   * C Compiler:                $CC_VERSION"
 321 echo "   * C Flags:                   $CFLAGS"
 322 echo "   * C++ Compiler:              $CXX_VERSION"
 323 echo "   * C++ Flags:                 $CXXFLAGS"
 324 echo "   * CPP Flags:                 $CPPFLAGS"
 325 echo "   * LIB Flags:                 $LIB"
 326 echo "   * Assertions enabled:        $ax_enable_assert"
 327 echo "   * Debug enabled:             $ax_enable_debug"
 328 echo "   * Shared:                    $enable_shared"
 329 echo "   * Warnings as failure:       $ac_cv_warnings_as_errors"
 330 echo "   * SASL support:              $ac_enable_sasl"
 331 echo "   * make -j:                   $enable_jobserver"
 332 echo "   * VCS checkout:              $ac_cv_vcs_checkout"
 333 echo ""
 334 echo "---"
 335
 336 case "$host_os" in
 337   *freebsd*)
 338     echo "*****"
 339     echo "*"
 340     echo "*  NOTE: You are on FreeBSD. BSD make will not work."
 341     echo "*"
 342     echo "*   use 'gmake' To build libmemcached"
 343     echo "*"
 344     echo "*****"
 345   ;;
 346 esac
 347