git.m6w6.name Git - awesomized/libmemcached/blob - configure.ac

   1 # configure.ac -*- autoconf -*- vim: filetype=config
   2 #
   3 # LibmemcacheD
   4 # Copyright (C) 2011-2013 Data Differential, http://datadifferential.com/
   5 # Copyright (C) 2006-2010 Brian Aker, Monty Taylor, Trond Norbye
   6 # All rights reserved.
   7 #
   8 # Use and distribution licensed under the BSD license.  See
   9 # the COPYING file in this directory for full text.
  10
  11 m4_include([version.m4])
  12
  13 AC_PREREQ([2.61])
  14 AC_INIT([libmemcached],VERSION_NUMBER,[http://libmemcached.org/])
  15
  16 AC_CONFIG_AUX_DIR([build-aux])
  17 AC_CONFIG_MACRO_DIR([m4])
  18
  19 # Setup the compilers early on
  20 AC_PROG_CC([cc gcc clang])
  21 AC_PROG_CXX([c++ g++ clang++])
  22
  23 AC_CANONICAL_HOST
  24 AC_ARG_PROGRAM
  25 AC_USE_SYSTEM_EXTENSIONS
  26
  27 AM_INIT_AUTOMAKE([1.11 color-tests -Wno-portability subdir-objects foreign tar-ustar])
  28
  29 AC_CONFIG_HEADERS([mem_config.h:mem_config.in])dnl Keep filename to 8.3 for MS-DOS.
  30 AC_SUBST([AUTOHEADER_FILE],[mem_config.h])
  31 AC_CONFIG_SRCDIR([libmemcached/memcached.cc])
  32
  33 #shared library versioning
  34 MEMCACHED_UTIL_LIBRARY_VERSION=2:0:0
  35 MEMCACHED_PROTOCAL_LIBRARY_VERSION=0:0:0
  36 MEMCACHED_LIBRARY_VERSION=11:0:0
  37 #                         | | |
  38 #                  +------+ | +---+
  39 #                  |        |     |
  40 #                 current:revision:age
  41 #                  |        |     |
  42 #                  |        |     +- increment if interfaces have been added
  43 #                  |        |        set to zero if interfaces have been removed or changed
  44 #                  |        +- increment if source code has changed
  45 #                  |           set to zero if current is incremented
  46 #                  +- increment if interfaces have been added, removed or changed
  47 AC_SUBST([MEMCACHED_UTIL_LIBRARY_VERSION])
  48 AC_SUBST([MEMCACHED_PROTOCAL_LIBRARY_VERSION])
  49 AC_SUBST([MEMCACHED_LIBRARY_VERSION])
  50
  51 AX_HEX_VERSION([LIBMEMCACHED],[$VERSION])
  52 AX_HEX_VERSION([LIBHASHKIT],[1.0.0])
  53 AC_SUBST([RPM_RELEASE],[1])
  54
  55 m4_include([libhashkit/include.m4])
  56
  57 LT_PREREQ([2.2])
  58 LT_INIT([dlopen])
  59 LT_LANG([C++])
  60 LT_LIB_M
  61
  62 AC_SUBST([lt_cv_dlopen_libs])
  63
  64
  65 AC_PROG_CC_C99
  66 AS_IF([test "x${ac_cv_prog_cc_c99}" == "xno"],[AC_MSG_ERROR([No c99 compatible compiler found])])
  67
  68 AC_DEFUN([CHECK_CXX0X],[
  69           AC_LANG_PUSH([C++])
  70           AX_CHECK_COMPILE_FLAG([-std=c++0x],[
  71                                  CXX="$CXX -std=c++0x"])
  72           AC_LANG_POP([C++])
  73           ])
  74 CHECK_CXX0X
  75
  76 AX_ASSERT
  77
  78 AX_PLATFORM
  79 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  80
  81 AC_DEFUN([LIBMEMCACHED_PROTOCOL],
  82          [AC_ARG_ENABLE([libmemcachedprotocol],
  83                         [AS_HELP_STRING([--enable-libmemcachedprotocol],
  84                                         [Enable libmemcachedprotocol])],
  85                                         [ax_enable_libmemcachedprotocol=yes],
  86                                         [ax_enable_libmemcachedprotocol=no])
  87
  88          AM_CONDITIONAL([BUILD_LIBMEMCACHED_PROTOCOL],[test "$ax_enable_libmemcachedprotocol" = "yes"])
  89
  90          AC_MSG_CHECKING([for libmemcachedprotocol])
  91          AC_MSG_RESULT([$ax_enable_libmemcachedprotocol])
  92          ])
  93 LIBMEMCACHED_PROTOCOL
  94
  95 # Adding support for libtest
  96 m4_include([libtest/yatl.m4])
  97
  98 CHECK_FOR_GEARMAND
  99 CHECK_FOR_LIBGEARMAND
 100
 101 AM_CONDITIONAL([BUILDING_LIBMEMCACHED],[true])
 102 AM_CONDITIONAL([HAVE_LIBMEMCACHED],[false])
 103 AM_CONDITIONAL([HAVE_LIBDRIZZLE],[false])
 104 AC_DEFINE([HAVE_LIBMEMCACHED],[1],[Enables libmemcached Support])
 105
 106 AM_CONDITIONAL([BUILDING_GEARMAN],[false])
 107
 108 # Specialty checks
 109 AX_CXX_CINTTYPES
 110 CONFIG_EXTRA
 111 DETECT_BYTEORDER
 112 SETSOCKOPT_SANITY
 113 ENABLE_HSIEH_HASH
 114 ENABLE_MURMUR_HASH
 115 ENABLE_FNV64_HASH
 116 ENABLE_MEMASLAP
 117 PROTOCOL_BINARY_TEST
 118 ENABLE_DEPRECATED
 119
 120 # Checks for programs.
 121 AC_CHECK_PROGS([DPKG_GENSYMBOLS],[dpkg-gensymbols])
 122 AC_CHECK_PROGS([LEX],['flex'],[:])
 123 AC_CHECK_PROGS([PERL],[perl])
 124 AC_CHECK_PROGS([VALGRIND],['valgrind'])
 125 AC_CHECK_PROGS([WINE],['wine'])
 126 AC_CHECK_PROGS([YACC],['bison --warnings=all'],[:])
 127 AC_CHECK_PROGS([RPMBUILD],[rpmbuild --nocheck])
 128 AC_CHECK_PROGS([RPMDEV_SETUPTREE],[rpmdev-setuptree])
 129 AC_CHECK_PROGS([RPM],[rpm])
 130 AC_PROG_AWK
 131 AC_PROG_MKDIR_P
 132 AC_PROG_SED
 133 AX_PROG_MEMCACHED
 134 AX_PROG_SPHINX_BUILD(,[AC_MSG_WARN([sphinx-build version 1.0 or greater is required to build man pages])])
 135 AX_WITH_PROG([LCOV],[lcov])
 136 AX_WITH_PROG([LCOV_GENHTML],[genhtml])
 137 AC_DEFINE([HAVE_MEMCACHED_SASL_BINARY],[0],[If Memcached binary with sasl support is available])
 138
 139 # Checks for libraries.
 140 AC_SEARCH_LIBS([getopt_long],[gnugetopt])
 141 AC_SEARCH_LIBS([gethostbyname],[nsl])
 142
 143 # Checks for header files.
 144 AC_CHECK_HEADERS_ONCE([arpa/inet.h])
 145 AC_CHECK_HEADERS_ONCE([errno.h])
 146 AC_CHECK_HEADERS_ONCE([execinfo.h])
 147 AC_CHECK_HEADERS_ONCE([fcntl.h])
 148 AC_CHECK_HEADERS_ONCE([features.h])
 149 AC_CHECK_HEADERS_ONCE([fnmatch.h])
 150 AC_CHECK_HEADERS_ONCE([inttypes.h])
 151 AC_CHECK_HEADERS_ONCE([libintl.h])
 152 AC_CHECK_HEADERS_ONCE([limits.h])
 153 AC_CHECK_HEADERS_ONCE([linux/sysctl.h])
 154 AC_CHECK_HEADERS_ONCE([mach/mach.h])
 155 AC_CHECK_HEADERS_ONCE([malloc.h])
 156 AC_CHECK_HEADERS_ONCE([math.h])
 157 AC_CHECK_HEADERS_ONCE([netdb.h])
 158 AC_CHECK_HEADERS_ONCE([netinet/in.h])
 159 AC_CHECK_HEADERS_ONCE([netinet/tcp.h])
 160 AC_CHECK_HEADERS_ONCE([poll.h])
 161 AC_CHECK_HEADERS_ONCE([pthread.h])
 162 AC_CHECK_HEADERS_ONCE([spawn.h])
 163 AC_CHECK_HEADERS_ONCE([stdarg.h])
 164 AC_CHECK_HEADERS_ONCE([stddef.h])
 165 AC_CHECK_HEADERS_ONCE([stdio.h])
 166 AC_CHECK_HEADERS_ONCE([stdlib.h])
 167 AC_CHECK_HEADERS_ONCE([sys/socket.h])
 168 AC_CHECK_HEADERS_ONCE([sys/sysctl.h])
 169 AC_CHECK_HEADERS_ONCE([sys/time.h])
 170 AC_CHECK_HEADERS_ONCE([sys/types.h])
 171 AC_CHECK_HEADERS_ONCE([sys/un.h])
 172 AC_CHECK_HEADERS_ONCE([sys/wait.h])
 173 AC_CHECK_HEADERS_ONCE([syslog.h])
 174 AC_CHECK_HEADERS_ONCE([time.h])
 175 AC_CHECK_HEADERS_ONCE([unistd.h])
 176
 177 # Windows only
 178 AC_CHECK_HEADERS_ONCE([winsock2.h])
 179 AC_CHECK_HEADERS_ONCE([ws2tcpip.h])
 180
 181 # Checks for typedefs, structures, and compiler characteristics.
 182
 183 # Checks for library functions.
 184
 185 AC_CHECK_FUNCS([alarm])
 186 AC_CHECK_FUNCS([atexit])
 187 AC_CHECK_FUNCS([clock_gettime])
 188 AC_CHECK_FUNCS([dup2])
 189 AC_CHECK_FUNCS([fcntl])
 190 AC_CHECK_FUNCS([floor])
 191 AC_CHECK_FUNCS([getcwd])
 192 AC_CHECK_FUNCS([getline])
 193 AC_CHECK_FUNCS([gettimeofday])
 194 AC_CHECK_FUNCS([inet_ntoa])
 195 AC_CHECK_FUNCS([memchr])
 196 AC_CHECK_FUNCS([memmove])
 197 AC_CHECK_FUNCS([memset])
 198 AC_CHECK_FUNCS([pipe2])
 199 AC_CHECK_FUNCS([putenv])
 200 AC_CHECK_FUNCS([select])
 201 AC_CHECK_FUNCS([setenv])
 202 AC_CHECK_FUNCS([sigignore])
 203 AC_CHECK_FUNCS([socket])
 204 AC_CHECK_FUNCS([sqrt])
 205 AC_CHECK_FUNCS([strcasecmp])
 206 AC_CHECK_FUNCS([strchr])
 207 AC_CHECK_FUNCS([strdup])
 208 AC_CHECK_FUNCS([strerror])
 209 AC_CHECK_FUNCS([strstr])
 210 AC_CHECK_FUNCS([strtol])
 211 AC_CHECK_FUNCS([strtoul])
 212 AC_CHECK_FUNCS([strtoull])
 213 AC_FUNC_ALLOCA
 214 AC_FUNC_ERROR_AT_LINE
 215 AC_FUNC_FORK
 216 AC_FUNC_STRERROR_R
 217
 218 AC_CHECK_HEADER([umem.h],
 219                 [AC_DEFINE([HAVE_UMEM_H],[1],[Define this if you have umem.h])
 220                 build_cache=no],
 221                 [build_cache=yes])
 222
 223 AM_CONDITIONAL([BUILD_CACHE],[test "x$build_cache" = "xyes"])
 224
 225 AX_COMPILER_VENDOR
 226
 227 AC_CHECK_TYPES([in_port_t],,,[[
 228                 #ifdef HAVE_SYS_TYPES_H
 229                 # include <sys/types.h>
 230                 #endif
 231                 #ifdef HAVE_NETINET_IN_H
 232                 # include <netinet/in.h>
 233                 #endif
 234                 #ifdef HAVE_NETDB_H
 235                 # include <netdb.h>
 236                 #endif]])
 237 AC_CHECK_TYPES([ptrdiff_t])
 238 AC_HEADER_STDBOOL
 239 AC_TYPE_INT16_T
 240 AC_TYPE_INT32_T
 241 AC_TYPE_INT64_T
 242 AC_TYPE_INT8_T
 243 AC_TYPE_OFF_T
 244 AC_TYPE_PID_T
 245 AC_TYPE_SSIZE_T
 246 AC_TYPE_UINT16_T
 247 AC_TYPE_UINT32_T
 248 AC_TYPE_UINT64_T
 249 AC_TYPE_UINT8_T
 250
 251 AC_C_BIGENDIAN
 252 AC_C_CONST
 253 AC_C_INLINE
 254 AC_C_VOLATILE
 255 AC_C_RESTRICT
 256
 257 AX_CXX_GCC_ABI_DEMANGLE
 258
 259 AX_LIBEVENT
 260
 261 AC_CHECK_LIB([rt],[clock_gettime],
 262              [AC_SUBST([RT_LIB],[-lrt])
 263              AC_DEFINE([HAVE_CLOCK_GETTIME],[1],[Have clock_gettime])],
 264              [AC_DEFINE([HAVE_CLOCK_GETTIME],[0],[Have clock_gettime])])
 265
 266
 267 AC_CHECK_HEADERS([atomic.h])
 268 AS_IF([test "x$ac_cv_header_atomic_h" = "xyes"],
 269       [AC_CHECK_FUNCS([atomic_add_64])
 270       AC_CHECK_FUNCS([atomic_add_32])
 271       AS_IF([test "x$ac_cv_func_atomic_add_64" = "xyes" -a "x$ac_cv_func_atomic_add_32" = "xyes"],
 272             [AC_DEFINE([USE_ATOMIC_H],[1],[Define to true if you want to use functions from atomic.h])])])
 273
 274 AC_DEFINE([HAVE_LIBDRIZZLE],[0],[Support for libdrizzle])
 275 AC_DEFINE([HAVE_DRIZZLED_BINARY],[0],[Support for DrizzleD])
 276 AC_DEFINE([DRIZZLED_BINARY],[0],[Support for DrizzleD])
 277 AC_DEFINE([GEARMAND_BLOBSLAP_WORKER],[0],[Support for Gearman Blobslap worker])
 278 AC_DEFINE([HAVE_LIBPQ],[0],[Support for Postgres])
 279 AC_DEFINE([HAVE_LIBCURL],[0],[Support for libcurl])
 280
 281 # Check for the requirements for running memcached with less privileges
 282 # than the default privilege set. On Solaris we need setppriv and priv.h
 283 # If you want to add support for other platforms you should check for
 284 # your requirements, define HAVE_DROP_PRIVILEGES, and make sure you add
 285 # the source file containing the implementation into memcached_SOURCE
 286 # in Makefile.am
 287 AC_CHECK_FUNCS([setppriv],
 288                [AC_CHECK_HEADER([priv.h],
 289                                 [AC_DEFINE([HAVE_DROP_PRIVILEGES],
 290                                            [1],
 291                                            [Define this if you have an implementation of drop_privileges()])
 292                                 build_solaris_privs=yes])
 293                ])
 294
 295 AM_CONDITIONAL([BUILD_POLL],[test "x$ac_cv_header_poll_h" = "xno"])
 296 AM_CONDITIONAL([BUILD_WIN32_WRAPPERS],[test "x$ac_cv_header_winsock2_h" = "xyes"])
 297 AS_IF([test "x$ac_cv_header_winsock2_h" = "xyes"],
 298       [AM_LDFLAGS="$AM_LDFLAGS -lws2_32"
 299        AM_CFLAGS="$AM_CFLAGS $NO_WERROR"
 300        AM_CXXFLAGS="$AM_CXXFLAGS $NO_WERROR"
 301        ])
 302 SOCKET_SEND_FLAGS
 303
 304 AX_UUID_GENERATE_TIME_SAFE
 305
 306 AC_DEFUN([CHECK_FOR_PTHREAD_AND_SASL],
 307          [AC_LANG_PUSH([C++])
 308          AX_PTHREAD(, [AC_MSG_ERROR([could not find libpthread])])
 309          AX_PTHREAD_TIMEDJOIN_NP
 310          AC_LANG_POP([C++])
 311
 312          # The sasl functions should only be visible if we build with sasl support
 313          #
 314          AX_SASL_OPTION
 315          AS_IF([test "x$ac_enable_sasl" = xyes],
 316                [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 1"],
 317                [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 0"])
 318          AC_SUBST([LIBMEMCACHED_WITH_SASL_SUPPORT])
 319          ])
 320 CHECK_FOR_PTHREAD_AND_SASL
 321
 322 # backtrace(), others require shared builds
 323 AC_DEFUN([__ENABLE_SHARED],
 324          [AC_REQUIRE([AX_PLATFORM])
 325          AS_IF([test "x${TARGET_WINDOWS}" = "xtrue"],[enable_shared=no])
 326          AS_IF([test "x$enable_shared" = "xyes"],
 327                [AC_DEFINE([HAVE_SHARED_ENABLED],[1],[Enable code which requires shared library support. Like backtrace().])])])
 328 AM_CONDITIONAL([SHARED_ENABLED],[test "x$enable_shared" = "xyes"])
 329
 330 PANDORA_ENABLE_DTRACE
 331 HAVE_GCC_ATOMICS
 332 AX_ENDIAN
 333 AX_ASSERT
 334 AX_HARDEN_COMPILER_FLAGS
 335
 336 AX_AM_JOBSERVER([yes])
 337
 338 AC_CONFIG_FILES([Makefile
 339                  docs/source/conf.py
 340                  libmemcached-1.0/configure.h
 341                  support/libmemcached.pc
 342                  support/libmemcached.spec
 343                  ])
 344 AC_OUTPUT
 345
 346 echo "---"
 347 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 348 echo ""
 349 echo "   * Installation prefix:       $prefix"
 350 echo "   * System type:               $host_vendor-$host_os"
 351 echo "   * Host CPU:                  $host_cpu"
 352 echo "   * C Compiler:                $CC_VERSION"
 353 echo "   * C Flags:                   $CFLAGS"
 354 echo "   * C++ Compiler:              $CXX_VERSION"
 355 echo "   * C++ Flags:                 $CXXFLAGS"
 356 echo "   * CPP Flags:                 $CPPFLAGS"
 357 echo "   * LIB Flags:                 $LIB"
 358 echo "   * Assertions enabled:        $ax_enable_assert"
 359 echo "   * Debug enabled:             $ax_enable_debug"
 360 echo "   * Shared:                    $enable_shared"
 361 echo "   * Warnings as failure:       $ac_cv_warnings_as_errors"
 362 echo "   * SASL support:              $ac_enable_sasl"
 363 echo "   * make -j:                   $enable_jobserver"
 364 echo "   * VCS checkout:              $ac_cv_vcs_checkout"
 365 echo ""
 366 echo "---"
 367
 368 case "$host_os" in
 369   *freebsd*)
 370     echo "*****"
 371     echo "*"
 372     echo "*  NOTE: You are on FreeBSD. BSD make will not work."
 373     echo "*"
 374     echo "*   use 'gmake' To build libmemcached"
 375     echo "*"
 376     echo "*****"
 377   ;;
 378 esac
 379