git.m6w6.name Git - awesomized/libmemcached/blob - configure.ac

   1 # LibmemcacheD
   2 # Copyright (C) 2011-2012 Data Differential, http://datadifferential.com/
   3 # Copyright (C) 2006-2010 Brian Aker, Monty Taylor, Trond Norbye
   4 # All rights reserved.
   5 #
   6 # Use and distribution licensed under the BSD license.  See
   7 # the COPYING file in this directory for full text.
   8
   9 AC_INIT([libmemcached],[1.0.16],[http://libmemcached.org/])
  10 AC_CONFIG_AUX_DIR([build-aux])
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 AC_CANONICAL_TARGET
  14 AC_ARG_PROGRAM
  15 AC_USE_SYSTEM_EXTENSIONS
  16
  17 AM_INIT_AUTOMAKE([1.11 color-tests -Wno-portability subdir-objects foreign tar-ustar])
  18
  19 AC_PREREQ([2.61])
  20
  21 AC_CONFIG_HEADERS([mem_config.h:mem_config.in])dnl Keep filename to 8.3 for MS-DOS.
  22 AC_SUBST([AUTOHEADER_FILE],[mem_config.h])
  23 AC_CONFIG_SRCDIR([libmemcached/memcached.cc])
  24
  25 #shared library versioning
  26 MEMCACHED_UTIL_LIBRARY_VERSION=2:0:0
  27 MEMCACHED_PROTOCAL_LIBRARY_VERSION=0:0:0
  28 MEMCACHED_LIBRARY_VERSION=11:0:0
  29 #                         | | |
  30 #                  +------+ | +---+
  31 #                  |        |     |
  32 #                 current:revision:age
  33 #                  |        |     |
  34 #                  |        |     +- increment if interfaces have been added
  35 #                  |        |        set to zero if interfaces have been removed or changed
  36 #                  |        +- increment if source code has changed
  37 #                  |           set to zero if current is incremented
  38 #                  +- increment if interfaces have been added, removed or changed
  39 AC_SUBST([MEMCACHED_UTIL_LIBRARY_VERSION])
  40 AC_SUBST([MEMCACHED_PROTOCAL_LIBRARY_VERSION])
  41 AC_SUBST([MEMCACHED_LIBRARY_VERSION])
  42
  43 AX_HEX_VERSION([LIBMEMCACHED],[$VERSION])
  44 AX_HEX_VERSION([LIBHASHKIT],[1.0.0])
  45
  46 m4_include([libhashkit/include.m4])
  47
  48 LT_PREREQ([2.2])
  49 LT_INIT
  50 LT_LANG([C++])
  51 LT_LIB_M
  52
  53 AX_ASSERT
  54
  55 AX_PLATFORM
  56
  57 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  58
  59 AX_CXX_HEADER_STDCXX_98
  60 AS_IF([test "x$ax_cv_cxx_stdcxx_98" = "xno"],
  61       [AC_MSG_ERROR([Your system lacks a new enough C++ compiler])])
  62
  63 AC_DEFUN([LIBMEMCACHED_PROTOCOL],
  64          [AC_ARG_ENABLE([libmemcachedprotocol],
  65                         [AS_HELP_STRING([--enable-libmemcachedprotocol],
  66                                         [Enable libmemcachedprotocol])],
  67                                         [ax_enable_libmemcachedprotocol=yes],
  68                                         [ax_enable_libmemcachedprotocol=no])
  69
  70          AM_CONDITIONAL([BUILD_LIBMEMCACHED_PROTOCOL],[test "$ax_enable_libmemcachedprotocol" = "yes"])
  71
  72          AC_MSG_CHECKING([for libmemcachedprotocol])
  73          AC_MSG_RESULT([$ax_enable_libmemcachedprotocol])
  74          ])
  75 LIBMEMCACHED_PROTOCOL
  76
  77 # Adding support for libtest
  78 m4_include([libtest/yatl.m4])
  79
  80 CHECK_FOR_GEARMAND
  81 CHECK_FOR_LIBGEARMAND
  82
  83 AM_CONDITIONAL([BUILDING_LIBMEMCACHED],[true])
  84 AM_CONDITIONAL([HAVE_LIBMEMCACHED],[false])
  85 AM_CONDITIONAL([HAVE_LIBDRIZZLE],[false])
  86 AC_DEFINE([HAVE_LIBMEMCACHED],[1],[Enables libmemcached Support])
  87
  88 AM_CONDITIONAL([BUILDING_GEARMAN],[false])
  89
  90 # Specialty checks
  91 AX_CXX_CINTTYPES
  92 CONFIG_EXTRA
  93 DETECT_BYTEORDER
  94 SETSOCKOPT_SANITY
  95 ENABLE_HSIEH_HASH
  96 ENABLE_MURMUR_HASH
  97 ENABLE_FNV64_HASH
  98 ENABLE_MEMASLAP
  99 PROTOCOL_BINARY_TEST
 100 ENABLE_DEPRECATED
 101
 102 # Checks for programs.
 103 AC_CHECK_PROGS([LEX],['flex'],[:])
 104 AC_CHECK_PROGS([YACC],['bison'],[:])
 105 AX_PROG_SPHINX_BUILD
 106
 107 # Checks for libraries.
 108 AC_SEARCH_LIBS([getopt_long],[gnugetopt])
 109 AC_SEARCH_LIBS([gethostbyname],[nsl])
 110
 111 # Checks for header files.
 112 AC_CHECK_HEADERS_ONCE([arpa/inet.h])
 113 AC_CHECK_HEADERS_ONCE([errno.h])
 114 AC_CHECK_HEADERS_ONCE([execinfo.h])
 115 AC_CHECK_HEADERS_ONCE([fcntl.h])
 116 AC_CHECK_HEADERS_ONCE([features.h])
 117 AC_CHECK_HEADERS_ONCE([fnmatch.h])
 118 AC_CHECK_HEADERS_ONCE([inttypes.h])
 119 AC_CHECK_HEADERS_ONCE([libintl.h])
 120 AC_CHECK_HEADERS_ONCE([limits.h])
 121 AC_CHECK_HEADERS_ONCE([mach/mach.h])
 122 AC_CHECK_HEADERS_ONCE([malloc.h])
 123 AC_CHECK_HEADERS_ONCE([math.h])
 124 AC_CHECK_HEADERS_ONCE([netdb.h])
 125 AC_CHECK_HEADERS_ONCE([netinet/in.h])
 126 AC_CHECK_HEADERS_ONCE([netinet/tcp.h])
 127 AC_CHECK_HEADERS_ONCE([poll.h])
 128 AC_CHECK_HEADERS_ONCE([pthread.h])
 129 AC_CHECK_HEADERS_ONCE([spawn.h])
 130 AC_CHECK_HEADERS_ONCE([stdarg.h])
 131 AC_CHECK_HEADERS_ONCE([stddef.h])
 132 AC_CHECK_HEADERS_ONCE([stdio.h])
 133 AC_CHECK_HEADERS_ONCE([stdlib.h])
 134 AC_CHECK_HEADERS_ONCE([sys/socket.h])
 135 AC_CHECK_HEADERS_ONCE([sys/sysctl.h])
 136 AC_CHECK_HEADERS_ONCE([sys/time.h])
 137 AC_CHECK_HEADERS_ONCE([sys/types.h])
 138 AC_CHECK_HEADERS_ONCE([sys/un.h])
 139 AC_CHECK_HEADERS_ONCE([sys/wait.h])
 140 AC_CHECK_HEADERS_ONCE([syslog.h])
 141 AC_CHECK_HEADERS_ONCE([time.h])
 142 AC_CHECK_HEADERS_ONCE([unistd.h])
 143
 144 # Windows only
 145 AC_CHECK_HEADERS_ONCE([winsock2.h])
 146 AC_CHECK_HEADERS_ONCE([ws2tcpip.h])
 147
 148 # Checks for typedefs, structures, and compiler characteristics.
 149
 150 # Checks for library functions.
 151
 152 AC_CHECK_FUNCS([alarm])
 153 AC_CHECK_FUNCS([atexit])
 154 AC_CHECK_FUNCS([clock_gettime])
 155 AC_CHECK_FUNCS([dup2])
 156 AC_CHECK_FUNCS([fcntl])
 157 AC_CHECK_FUNCS([floor])
 158 AC_CHECK_FUNCS([getcwd])
 159 AC_CHECK_FUNCS([getline])
 160 AC_CHECK_FUNCS([gettimeofday])
 161 AC_CHECK_FUNCS([inet_ntoa])
 162 AC_CHECK_FUNCS([memchr])
 163 AC_CHECK_FUNCS([memmove])
 164 AC_CHECK_FUNCS([memset])
 165 AC_CHECK_FUNCS([pipe2])
 166 AC_CHECK_FUNCS([putenv])
 167 AC_CHECK_FUNCS([select])
 168 AC_CHECK_FUNCS([setenv])
 169 AC_CHECK_FUNCS([sigignore])
 170 AC_CHECK_FUNCS([socket])
 171 AC_CHECK_FUNCS([sqrt])
 172 AC_CHECK_FUNCS([strcasecmp])
 173 AC_CHECK_FUNCS([strchr])
 174 AC_CHECK_FUNCS([strdup])
 175 AC_CHECK_FUNCS([strerror])
 176 AC_CHECK_FUNCS([strstr])
 177 AC_CHECK_FUNCS([strtol])
 178 AC_CHECK_FUNCS([strtoul])
 179 AC_CHECK_FUNCS([strtoull])
 180 AC_FUNC_ALLOCA
 181 AC_FUNC_ERROR_AT_LINE
 182 AC_FUNC_FORK
 183 AC_FUNC_STRERROR_R
 184
 185 AC_CHECK_HEADER([umem.h],
 186                 [AC_DEFINE([HAVE_UMEM_H],[1],[Define this if you have umem.h])
 187                 build_cache=no],
 188                 [build_cache=yes])
 189
 190 AM_CONDITIONAL([BUILD_CACHE],[test "x$build_cache" = "xyes"])
 191
 192 AX_COMPILER_VENDOR
 193
 194 AC_CHECK_TYPES([in_port_t],,,[[
 195                 #ifdef HAVE_SYS_TYPES_H
 196                 # include <sys/types.h>
 197                 #endif
 198                 #ifdef HAVE_NETINET_IN_H
 199                 # include <netinet/in.h>
 200                 #endif
 201                 #ifdef HAVE_NETDB_H
 202                 # include <netdb.h>
 203                 #endif]])
 204 AC_CHECK_TYPES([ptrdiff_t])
 205 AC_HEADER_STDBOOL
 206 AC_TYPE_INT16_T
 207 AC_TYPE_INT32_T
 208 AC_TYPE_INT64_T
 209 AC_TYPE_INT8_T
 210 AC_TYPE_OFF_T
 211 AC_TYPE_PID_T
 212 AC_TYPE_SSIZE_T
 213 AC_TYPE_UINT16_T
 214 AC_TYPE_UINT32_T
 215 AC_TYPE_UINT64_T
 216 AC_TYPE_UINT8_T
 217
 218 AC_C_BIGENDIAN
 219 AC_C_CONST
 220 AC_C_INLINE
 221 AC_C_VOLATILE
 222 AC_C_RESTRICT
 223
 224 AX_CXX_GCC_ABI_DEMANGLE
 225
 226 AX_LIBEVENT
 227
 228 AC_CHECK_LIB([rt],[clock_gettime],
 229              [AC_SUBST([RT_LIB],[-lrt])
 230              AC_DEFINE([HAVE_CLOCK_GETTIME],[1],[Have clock_gettime])],
 231              [AC_DEFINE([HAVE_CLOCK_GETTIME],[0],[Have clock_gettime])])
 232
 233
 234 # Check for the ability to call dlopen (used in libhostile)
 235 AX_DLOPEN
 236
 237 AC_CHECK_HEADERS([atomic.h])
 238 AS_IF([test "x$ac_cv_header_atomic_h" = "xyes"],
 239       [AC_CHECK_FUNCS([atomic_add_64])
 240       AC_CHECK_FUNCS([atomic_add_32])
 241       AS_IF([test "x$ac_cv_func_atomic_add_64" = "xyes" -a "x$ac_cv_func_atomic_add_32" = "xyes"],
 242             [AC_DEFINE([USE_ATOMIC_H],[1],[Define to true if you want to use functions from atomic.h])])])
 243
 244 AC_DEFINE([HAVE_LIBDRIZZLE],[0],[Support for libdrizzle])
 245 AC_DEFINE([HAVE_DRIZZLED_BINARY],[0],[Support for DrizzleD])
 246 AC_DEFINE([DRIZZLED_BINARY],[0],[Support for DrizzleD])
 247 AC_DEFINE([GEARMAND_BLOBSLAP_WORKER],[0],[Support for Gearman Blobslap worker])
 248 AC_DEFINE([HAVE_LIBPQ],[0],[Support for Postgres])
 249 AC_DEFINE([HAVE_LIBCURL],[0],[Support for libcurl])
 250
 251 # Check for the requirements for running memcached with less privileges
 252 # than the default privilege set. On Solaris we need setppriv and priv.h
 253 # If you want to add support for other platforms you should check for
 254 # your requirements, define HAVE_DROP_PRIVILEGES, and make sure you add
 255 # the source file containing the implementation into memcached_SOURCE
 256 # in Makefile.am
 257 AC_CHECK_FUNCS([setppriv],
 258                [AC_CHECK_HEADER([priv.h],
 259                                 [AC_DEFINE([HAVE_DROP_PRIVILEGES],
 260                                            [1],
 261                                            [Define this if you have an implementation of drop_privileges()])
 262                                 build_solaris_privs=yes])
 263                ])
 264
 265 AM_CONDITIONAL([BUILD_POLL],[test "x$ac_cv_header_poll_h" = "xno"])
 266 AM_CONDITIONAL([BUILD_WIN32_WRAPPERS],[test "x$ac_cv_header_winsock2_h" = "xyes"])
 267 AS_IF([test "x$ac_cv_header_winsock2_h" = "xyes"],
 268       [AM_LDFLAGS="$AM_LDFLAGS -lws2_32"
 269        AM_CFLAGS="$AM_CFLAGS $NO_WERROR"
 270        AM_CXXFLAGS="$AM_CXXFLAGS $NO_WERROR"
 271        ])
 272 SOCKET_SEND_FLAGS
 273
 274 AX_UUID_GENERATE_TIME_SAFE
 275
 276 AC_DEFUN([CHECK_FOR_PTHREAD_AND_SASL],
 277          [AX_PTHREAD(, [AC_MSG_ERROR([could not find libpthread])])
 278          AX_PTHREAD_TIMEDJOIN_NP
 279
 280          # The sasl functions should only be visible if we build with sasl support
 281          #
 282          AX_SASL_OPTION
 283          AS_IF([test "x$ac_enable_sasl" = xyes],
 284                [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 1"],
 285                [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 0"])
 286          AC_SUBST([LIBMEMCACHED_WITH_SASL_SUPPORT])
 287          ])
 288 CHECK_FOR_PTHREAD_AND_SASL
 289
 290
 291 # backtrace(), others require shared builds
 292 AS_IF([test "x$enable_shared" = "xyes"],
 293       [AC_DEFINE([HAVE_SHARED_ENABLED],[1],[Enable code which requires shared library support. Like backtrace().])])
 294 AM_CONDITIONAL([SHARED_ENABLED],[test "x$enable_shared" = "xyes"])
 295
 296 PANDORA_ENABLE_DTRACE
 297 HAVE_GCC_ATOMICS
 298 AX_ENDIAN
 299 AX_ASSERT
 300 AX_HARDEN_COMPILER_FLAGS
 301
 302 AX_AM_JOBSERVER([yes])
 303
 304 AC_CONFIG_FILES([Makefile
 305                  docs/conf.py
 306                  libmemcached-1.0/configure.h
 307                  support/libmemcached.pc
 308                  support/libmemcached.spec
 309                  ])
 310 AC_OUTPUT
 311
 312 echo "---"
 313 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 314 echo ""
 315 echo "   * Installation prefix:       $prefix"
 316 echo "   * System type:               $host_vendor-$host_os"
 317 echo "   * Host CPU:                  $host_cpu"
 318 echo "   * C Compiler:                $CC_VERSION"
 319 echo "   * C Flags:                   $CFLAGS"
 320 echo "   * C++ Compiler:              $CXX_VERSION"
 321 echo "   * C++ Flags:                 $CXXFLAGS"
 322 echo "   * CPP Flags:                 $CPPFLAGS"
 323 echo "   * LIB Flags:                 $LIB"
 324 echo "   * Assertions enabled:        $ax_enable_assert"
 325 echo "   * Debug enabled:             $ax_enable_debug"
 326 echo "   * Shared:                    $enable_shared"
 327 echo "   * Warnings as failure:       $ac_cv_warnings_as_errors"
 328 echo "   * SASL support:              $ac_enable_sasl"
 329 echo "   * make -j:                   $enable_jobserver"
 330 echo "   * VCS checkout:              $ac_cv_vcs_checkout"
 331 echo ""
 332 echo "---"
 333
 334 case "$host_os" in
 335   *freebsd*)
 336     echo "*****"
 337     echo "*"
 338     echo "*  NOTE: You are on FreeBSD. BSD make will not work."
 339     echo "*"
 340     echo "*   use 'gmake' To build libmemcached"
 341     echo "*"
 342     echo "*****"
 343   ;;
 344 esac
 345