git.m6w6.name Git - awesomized/libmemcached/blob - configure.ac

   1 # configure.ac -*- autoconf -*- vim: filetype=config
   2 #
   3 # LibmemcacheD
   4 # Copyright (C) 2011-2013 Data Differential, http://datadifferential.com/
   5 # Copyright (C) 2006-2010 Brian Aker, Monty Taylor, Trond Norbye
   6 # All rights reserved.
   7 #
   8 # Use and distribution licensed under the BSD license.  See
   9 # the COPYING file in this directory for full text.
  10
  11 m4_include([version.m4])
  12
  13 AC_PREREQ([2.61])
  14 AC_INIT([libmemcached],VERSION_NUMBER,[http://libmemcached.org/])
  15
  16 AC_CONFIG_AUX_DIR([build-aux])
  17 AC_CONFIG_MACRO_DIR([m4])
  18
  19 # Setup the compilers early on
  20 AC_PROG_CC([cc gcc clang])
  21 AC_PROG_CXX([c++ g++ clang++])
  22
  23 AC_CANONICAL_HOST
  24 AC_ARG_PROGRAM
  25 AC_USE_SYSTEM_EXTENSIONS
  26
  27 AM_INIT_AUTOMAKE([1.11 color-tests -Wno-portability subdir-objects foreign tar-ustar])
  28
  29 AC_CONFIG_HEADERS([mem_config.h:mem_config.in])dnl Keep filename to 8.3 for MS-DOS.
  30 AC_SUBST([AUTOHEADER_FILE],[mem_config.h])
  31 AC_CONFIG_SRCDIR([libmemcached/memcached.cc])
  32
  33 #shared library versioning
  34 MEMCACHED_UTIL_LIBRARY_VERSION=2:0:0
  35 MEMCACHED_PROTOCAL_LIBRARY_VERSION=0:0:0
  36 MEMCACHED_LIBRARY_VERSION=11:0:0
  37 #                         | | |
  38 #                  +------+ | +---+
  39 #                  |        |     |
  40 #                 current:revision:age
  41 #                  |        |     |
  42 #                  |        |     +- increment if interfaces have been added
  43 #                  |        |        set to zero if interfaces have been removed or changed
  44 #                  |        +- increment if source code has changed
  45 #                  |           set to zero if current is incremented
  46 #                  +- increment if interfaces have been added, removed or changed
  47 AC_SUBST([MEMCACHED_UTIL_LIBRARY_VERSION])
  48 AC_SUBST([MEMCACHED_PROTOCAL_LIBRARY_VERSION])
  49 AC_SUBST([MEMCACHED_LIBRARY_VERSION])
  50
  51 AX_HEX_VERSION([LIBMEMCACHED],[$VERSION])
  52 AX_HEX_VERSION([LIBHASHKIT],[1.0.0])
  53 AC_SUBST([RPM_RELEASE],[1])
  54
  55 m4_include([libhashkit/include.m4])
  56
  57 LT_PREREQ([2.2])
  58 LT_INIT([dlopen])
  59 LT_LANG([C++])
  60 LT_LIB_M
  61
  62 AC_SUBST([lt_cv_dlopen_libs])
  63
  64
  65 AC_PROG_CC_C99
  66 AS_IF([test "x${ac_cv_prog_cc_c99}" == "xno"],[AC_MSG_ERROR([No c99 compatible compiler found])])
  67
  68 AC_DEFUN([CHECK_CXX0X],[
  69           AC_LANG_PUSH([C++])
  70           AX_CHECK_COMPILE_FLAG([-std=c++0x],[
  71                                  CXX="$CXX -std=c++0x"])
  72           AC_LANG_POP([C++])
  73           ])
  74 CHECK_CXX0X
  75
  76
  77 AC_LANG_PUSH([C])
  78 AX_COMPILER_VENDOR
  79 AX_COMPILER_VERSION
  80 AC_LANG_POP([C])
  81 AC_LANG_PUSH([C++])
  82 AX_COMPILER_VENDOR
  83 AX_COMPILER_VERSION
  84 AC_LANG_POP([C++])
  85
  86 AX_ASSERT
  87
  88 AX_PLATFORM
  89 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  90
  91 AC_DEFUN([LIBMEMCACHED_PROTOCOL],
  92          [AC_ARG_ENABLE([libmemcachedprotocol],
  93                         [AS_HELP_STRING([--enable-libmemcachedprotocol],
  94                                         [Enable libmemcachedprotocol])],
  95                                         [ax_enable_libmemcachedprotocol=yes],
  96                                         [ax_enable_libmemcachedprotocol=no])
  97
  98          AM_CONDITIONAL([BUILD_LIBMEMCACHED_PROTOCOL],[test "$ax_enable_libmemcachedprotocol" = "yes"])
  99
 100          AC_MSG_CHECKING([for libmemcachedprotocol])
 101          AC_MSG_RESULT([$ax_enable_libmemcachedprotocol])
 102          ])
 103 LIBMEMCACHED_PROTOCOL
 104
 105 # Adding support for libtest
 106 m4_include([libtest/yatl.m4])
 107
 108 CHECK_FOR_GEARMAND
 109 CHECK_FOR_LIBGEARMAND
 110
 111 AM_CONDITIONAL([BUILDING_LIBMEMCACHED],[true])
 112 AM_CONDITIONAL([HAVE_LIBMEMCACHED],[false])
 113 AM_CONDITIONAL([HAVE_LIBDRIZZLE],[false])
 114 AC_DEFINE([HAVE_LIBMEMCACHED],[1],[Enables libmemcached Support])
 115
 116 AM_CONDITIONAL([BUILDING_GEARMAN],[false])
 117
 118 # Specialty checks
 119 AX_CXX_CINTTYPES
 120 CONFIG_EXTRA
 121 DETECT_BYTEORDER
 122 SETSOCKOPT_SANITY
 123 ENABLE_HSIEH_HASH
 124 ENABLE_MURMUR_HASH
 125 ENABLE_FNV64_HASH
 126 ENABLE_MEMASLAP
 127 PROTOCOL_BINARY_TEST
 128 ENABLE_DEPRECATED
 129
 130 # Checks for programs.
 131 AC_CHECK_PROGS([DPKG_GENSYMBOLS],[dpkg-gensymbols])
 132 AC_CHECK_PROGS([LEX],['flex'],[:])
 133 AC_CHECK_PROGS([PERL],[perl])
 134 AC_CHECK_PROGS([VALGRIND],['valgrind'])
 135 AC_CHECK_PROGS([WINE],['wine'])
 136 AC_CHECK_PROGS([YACC],['bison --warnings=all'],[:])
 137 AC_CHECK_PROGS([RPMBUILD],[rpmbuild --nocheck])
 138 AC_CHECK_PROGS([RPMDEV_SETUPTREE],[rpmdev-setuptree])
 139 AC_CHECK_PROGS([RPM],[rpm])
 140 AC_PROG_AWK
 141 AC_PROG_MKDIR_P
 142 AC_PROG_SED
 143 AX_PROG_MEMCACHED
 144 AX_PROG_SPHINX_BUILD(,[AC_MSG_WARN([sphinx-build version 1.0 or greater is required to build man pages])])
 145 AX_WITH_PROG([LCOV],[lcov])
 146 AX_WITH_PROG([LCOV_GENHTML],[genhtml])
 147 AC_DEFINE([HAVE_MEMCACHED_SASL_BINARY],[0],[If Memcached binary with sasl support is available])
 148
 149 # Checks for libraries.
 150 AC_SEARCH_LIBS([getopt_long],[gnugetopt])
 151 AC_SEARCH_LIBS([gethostbyname],[nsl])
 152
 153 # Checks for header files.
 154 AC_CHECK_HEADERS_ONCE([arpa/inet.h])
 155 AC_CHECK_HEADERS_ONCE([errno.h])
 156 AC_CHECK_HEADERS_ONCE([execinfo.h])
 157 AC_CHECK_HEADERS_ONCE([fcntl.h])
 158 AC_CHECK_HEADERS_ONCE([features.h])
 159 AC_CHECK_HEADERS_ONCE([fnmatch.h])
 160 AC_CHECK_HEADERS_ONCE([inttypes.h])
 161 AC_CHECK_HEADERS_ONCE([libintl.h])
 162 AC_CHECK_HEADERS_ONCE([limits.h])
 163 AC_CHECK_HEADERS_ONCE([linux/sysctl.h])
 164 AC_CHECK_HEADERS_ONCE([mach/mach.h])
 165 AC_CHECK_HEADERS_ONCE([malloc.h])
 166 AC_CHECK_HEADERS_ONCE([math.h])
 167 AC_CHECK_HEADERS_ONCE([netdb.h])
 168 AC_CHECK_HEADERS_ONCE([netinet/in.h])
 169 AC_CHECK_HEADERS_ONCE([netinet/tcp.h])
 170 AC_CHECK_HEADERS_ONCE([poll.h])
 171 AC_CHECK_HEADERS_ONCE([pthread.h])
 172 AC_CHECK_HEADERS_ONCE([spawn.h])
 173 AC_CHECK_HEADERS_ONCE([stdarg.h])
 174 AC_CHECK_HEADERS_ONCE([stddef.h])
 175 AC_CHECK_HEADERS_ONCE([stdio.h])
 176 AC_CHECK_HEADERS_ONCE([stdlib.h])
 177 AC_CHECK_HEADERS_ONCE([sys/socket.h])
 178 AC_CHECK_HEADERS_ONCE([sys/sysctl.h])
 179 AC_CHECK_HEADERS_ONCE([sys/time.h])
 180 AC_CHECK_HEADERS_ONCE([sys/types.h])
 181 AC_CHECK_HEADERS_ONCE([sys/un.h])
 182 AC_CHECK_HEADERS_ONCE([sys/wait.h])
 183 AC_CHECK_HEADERS_ONCE([syslog.h])
 184 AC_CHECK_HEADERS_ONCE([time.h])
 185 AC_CHECK_HEADERS_ONCE([unistd.h])
 186
 187 # Windows only
 188 AC_CHECK_HEADERS_ONCE([winsock2.h])
 189 AC_CHECK_HEADERS_ONCE([ws2tcpip.h])
 190
 191 # Checks for typedefs, structures, and compiler characteristics.
 192
 193 # Checks for library functions.
 194
 195 AC_CHECK_FUNCS([alarm])
 196 AC_CHECK_FUNCS([atexit])
 197 AC_CHECK_FUNCS([clock_gettime])
 198 AC_CHECK_FUNCS([dup2])
 199 AC_CHECK_FUNCS([fcntl])
 200 AC_CHECK_FUNCS([floor])
 201 AC_CHECK_FUNCS([getcwd])
 202 AC_CHECK_FUNCS([getline])
 203 AC_CHECK_FUNCS([gettimeofday])
 204 AC_CHECK_FUNCS([inet_ntoa])
 205 AC_CHECK_FUNCS([memchr])
 206 AC_CHECK_FUNCS([memmove])
 207 AC_CHECK_FUNCS([memset])
 208 AC_CHECK_FUNCS([pipe2])
 209 AC_CHECK_FUNCS([putenv])
 210 AC_CHECK_FUNCS([select])
 211 AC_CHECK_FUNCS([setenv])
 212 AC_CHECK_FUNCS([sigignore])
 213 AC_CHECK_FUNCS([socket])
 214 AC_CHECK_FUNCS([sqrt])
 215 AC_CHECK_FUNCS([strcasecmp])
 216 AC_CHECK_FUNCS([strchr])
 217 AC_CHECK_FUNCS([strdup])
 218 AC_CHECK_FUNCS([strerror])
 219 AC_CHECK_FUNCS([strstr])
 220 AC_CHECK_FUNCS([strtol])
 221 AC_CHECK_FUNCS([strtoul])
 222 AC_CHECK_FUNCS([strtoull])
 223 AC_FUNC_ALLOCA
 224 AC_FUNC_ERROR_AT_LINE
 225 AC_FUNC_FORK
 226 AC_FUNC_STRERROR_R
 227
 228 AC_CHECK_HEADER([umem.h],
 229                 [AC_DEFINE([HAVE_UMEM_H],[1],[Define this if you have umem.h])
 230                 build_cache=no],
 231                 [build_cache=yes])
 232
 233 AM_CONDITIONAL([BUILD_CACHE],[test "x$build_cache" = "xyes"])
 234
 235 AC_CHECK_TYPES([in_port_t],,,[[
 236                 #ifdef HAVE_SYS_TYPES_H
 237                 # include <sys/types.h>
 238                 #endif
 239                 #ifdef HAVE_NETINET_IN_H
 240                 # include <netinet/in.h>
 241                 #endif
 242                 #ifdef HAVE_NETDB_H
 243                 # include <netdb.h>
 244                 #endif]])
 245 AC_CHECK_TYPES([ptrdiff_t])
 246 AC_HEADER_STDBOOL
 247 AC_TYPE_INT16_T
 248 AC_TYPE_INT32_T
 249 AC_TYPE_INT64_T
 250 AC_TYPE_INT8_T
 251 AC_TYPE_OFF_T
 252 AC_TYPE_PID_T
 253 AC_TYPE_SSIZE_T
 254 AC_TYPE_UINT16_T
 255 AC_TYPE_UINT32_T
 256 AC_TYPE_UINT64_T
 257 AC_TYPE_UINT8_T
 258
 259 AC_C_BIGENDIAN
 260 AC_C_CONST
 261 AC_C_INLINE
 262 AC_C_VOLATILE
 263 AC_C_RESTRICT
 264
 265 AX_CXX_GCC_ABI_DEMANGLE
 266
 267 AX_LIBEVENT
 268
 269 AC_CHECK_LIB([rt],[clock_gettime],
 270              [AC_SUBST([RT_LIB],[-lrt])
 271              AC_DEFINE([HAVE_CLOCK_GETTIME],[1],[Have clock_gettime])],
 272              [AC_DEFINE([HAVE_CLOCK_GETTIME],[0],[Have clock_gettime])])
 273
 274
 275 AC_CHECK_HEADERS([atomic.h])
 276 AS_IF([test "x$ac_cv_header_atomic_h" = "xyes"],
 277       [AC_CHECK_FUNCS([atomic_add_64])
 278       AC_CHECK_FUNCS([atomic_add_32])
 279       AS_IF([test "x$ac_cv_func_atomic_add_64" = "xyes" -a "x$ac_cv_func_atomic_add_32" = "xyes"],
 280             [AC_DEFINE([USE_ATOMIC_H],[1],[Define to true if you want to use functions from atomic.h])])])
 281
 282 AC_DEFINE([HAVE_LIBDRIZZLE],[0],[Support for libdrizzle])
 283 AC_DEFINE([HAVE_DRIZZLED_BINARY],[0],[Support for DrizzleD])
 284 AC_DEFINE([DRIZZLED_BINARY],[0],[Support for DrizzleD])
 285 AC_DEFINE([GEARMAND_BLOBSLAP_WORKER],[0],[Support for Gearman Blobslap worker])
 286 AC_DEFINE([HAVE_LIBPQ],[0],[Support for Postgres])
 287 AC_DEFINE([HAVE_LIBCURL],[0],[Support for libcurl])
 288
 289 # Check for the requirements for running memcached with less privileges
 290 # than the default privilege set. On Solaris we need setppriv and priv.h
 291 # If you want to add support for other platforms you should check for
 292 # your requirements, define HAVE_DROP_PRIVILEGES, and make sure you add
 293 # the source file containing the implementation into memcached_SOURCE
 294 # in Makefile.am
 295 AC_CHECK_FUNCS([setppriv],
 296                [AC_CHECK_HEADER([priv.h],
 297                                 [AC_DEFINE([HAVE_DROP_PRIVILEGES],
 298                                            [1],
 299                                            [Define this if you have an implementation of drop_privileges()])
 300                                 build_solaris_privs=yes])
 301                ])
 302
 303 AM_CONDITIONAL([BUILD_POLL],[test "x$ac_cv_header_poll_h" = "xno"])
 304 AM_CONDITIONAL([BUILD_WIN32_WRAPPERS],[test "x$ac_cv_header_winsock2_h" = "xyes"])
 305 AS_IF([test "x$ac_cv_header_winsock2_h" = "xyes"],
 306       [AM_LDFLAGS="$AM_LDFLAGS -lws2_32"
 307        AM_CFLAGS="$AM_CFLAGS $NO_WERROR"
 308        AM_CXXFLAGS="$AM_CXXFLAGS $NO_WERROR"
 309        ])
 310 SOCKET_SEND_FLAGS
 311
 312 AX_UUID_GENERATE_TIME_SAFE
 313
 314 AC_DEFUN([CHECK_FOR_PTHREAD_AND_SASL],
 315          [AC_LANG_PUSH([C++])
 316          AX_PTHREAD(, [AC_MSG_ERROR([could not find libpthread])])
 317          AX_PTHREAD_TIMEDJOIN_NP
 318          AC_LANG_POP([C++])
 319
 320          # The sasl functions should only be visible if we build with sasl support
 321          #
 322          AX_SASL_OPTION
 323          AS_IF([test "x$ac_enable_sasl" = xyes],
 324                [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 1"],
 325                [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 0"])
 326          AC_SUBST([LIBMEMCACHED_WITH_SASL_SUPPORT])
 327          ])
 328 CHECK_FOR_PTHREAD_AND_SASL
 329
 330 # backtrace(), others require shared builds
 331 AC_DEFUN([__ENABLE_SHARED],
 332          [AC_REQUIRE([AX_PLATFORM])
 333          AS_IF([test "x${TARGET_WINDOWS}" = "xtrue"],[enable_shared=no])
 334          AS_IF([test "x$enable_shared" = "xyes"],
 335                [AC_DEFINE([HAVE_SHARED_ENABLED],[1],[Enable code which requires shared library support. Like backtrace().])])])
 336 AM_CONDITIONAL([SHARED_ENABLED],[test "x$enable_shared" = "xyes"])
 337
 338 PANDORA_ENABLE_DTRACE
 339 HAVE_GCC_ATOMICS
 340 AX_ENDIAN
 341 AX_ASSERT
 342 AX_HARDEN_COMPILER_FLAGS
 343
 344 AC_ARG_ENABLE([warnings-as-errors], AS_HELP_STRING([--enable-warnings-as-errors],
 345   [Build with -Werror enabled]), , [enable_warnings_as_errors=no])
 346 AC_CACHE_CHECK([if all warnings should produce an error], [ac_cv_warnings_as_errors], [
 347   AS_IF([test "x$enable_warnings_as_errors" = "xyes"], [
 348     ac_cv_warnings_as_errors=yes
 349   ], [
 350     ac_cv_warnings_as_errors=no
 351   ])
 352 ])
 353
 354 AX_AM_JOBSERVER([yes])
 355
 356 AC_CONFIG_FILES([Makefile
 357                  docs/source/conf.py
 358                  libmemcached-1.0/configure.h
 359                  support/libmemcached.pc
 360                  support/libmemcached.spec
 361                  ])
 362 AC_OUTPUT
 363
 364 echo "---"
 365 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 366 echo ""
 367 echo "   * Installation prefix:       $prefix"
 368 echo "   * System type:               $host_vendor-$host_os"
 369 echo "   * Host CPU:                  $host_cpu"
 370 echo "   * C Compiler:                $ax_cv_c_compiler_vendor $ax_cv_c_compiler_version"
 371 echo "   * C Flags:                   $CFLAGS"
 372 echo "   * C++ Compiler:              $ax_cv_cxx_compiler_vendor $ax_cv_cxx_compiler_version"
 373 echo "   * C++ Flags:                 $CXXFLAGS"
 374 echo "   * CPP Flags:                 $CPPFLAGS"
 375 echo "   * LIB Flags:                 $LIB"
 376 echo "   * Assertions enabled:        $ax_enable_assert"
 377 echo "   * Debug enabled:             $ax_enable_debug"
 378 echo "   * Shared:                    $enable_shared"
 379 echo "   * Warnings as failure:       $ac_cv_warnings_as_errors"
 380 echo "   * SASL support:              $ac_enable_sasl"
 381 echo "   * make -j:                   $enable_jobserver"
 382 echo "   * VCS checkout:              $ac_cv_vcs_checkout"
 383 echo ""
 384 echo "---"
 385
 386 case "$host_os" in
 387   *freebsd*)
 388     echo "*****"
 389     echo "*"
 390     echo "*  NOTE: You are on FreeBSD. BSD make will not work."
 391     echo "*"
 392     echo "*   use 'gmake' To build libmemcached"
 393     echo "*"
 394     echo "*****"
 395   ;;
 396 esac
 397