git.m6w6.name Git - awesomized/libmemcached/blob - configure.ac

   1 # configure.ac -*- autoconf -*- vim: filetype=config
   2 #
   3 # LibmemcacheD
   4 # Copyright (C) 2011-2013 Data Differential, http://datadifferential.com/
   5 # Copyright (C) 2006-2010 Brian Aker, Monty Taylor, Trond Norbye
   6 # All rights reserved.
   7 #
   8 # Use and distribution licensed under the BSD license.  See
   9 # the COPYING file in this directory for full text.
  10
  11 m4_include([version.m4])
  12
  13 AC_PREREQ([2.61])
  14 AC_INIT([libmemcached],VERSION_NUMBER,[http://libmemcached.org/])
  15
  16 AC_CONFIG_AUX_DIR([build-aux])
  17 AC_CONFIG_MACRO_DIR([m4])
  18
  19 # Setup the compilers early on
  20 AC_PROG_CC([cc gcc clang])
  21 AC_PROG_CXX([c++ g++ clang++])
  22
  23 AC_CANONICAL_HOST
  24 AC_ARG_PROGRAM
  25 AC_USE_SYSTEM_EXTENSIONS
  26
  27 AM_INIT_AUTOMAKE([1.11 color-tests -Wno-portability subdir-objects foreign tar-ustar])
  28
  29 AC_CONFIG_HEADERS([mem_config.h:mem_config.in])dnl Keep filename to 8.3 for MS-DOS.
  30 AC_SUBST([AUTOHEADER_FILE],[mem_config.h])
  31 AC_CONFIG_SRCDIR([libmemcached/memcached.cc])
  32
  33 #shared library versioning
  34 MEMCACHED_UTIL_LIBRARY_VERSION=2:0:0
  35 MEMCACHED_PROTOCAL_LIBRARY_VERSION=0:0:0
  36 MEMCACHED_LIBRARY_VERSION=11:0:0
  37 #                         | | |
  38 #                  +------+ | +---+
  39 #                  |        |     |
  40 #                 current:revision:age
  41 #                  |        |     |
  42 #                  |        |     +- increment if interfaces have been added
  43 #                  |        |        set to zero if interfaces have been removed or changed
  44 #                  |        +- increment if source code has changed
  45 #                  |           set to zero if current is incremented
  46 #                  +- increment if interfaces have been added, removed or changed
  47 AC_SUBST([MEMCACHED_UTIL_LIBRARY_VERSION])
  48 AC_SUBST([MEMCACHED_PROTOCAL_LIBRARY_VERSION])
  49 AC_SUBST([MEMCACHED_LIBRARY_VERSION])
  50
  51 AX_HEX_VERSION([LIBMEMCACHED],[$VERSION])
  52 AX_HEX_VERSION([LIBHASHKIT],[1.0.0])
  53 AC_SUBST([RPM_RELEASE],[1])
  54
  55 m4_include([libhashkit/include.m4])
  56
  57 LT_PREREQ([2.2])
  58 LT_INIT([dlopen])
  59 LT_LANG([C++])
  60 LT_LIB_M
  61
  62 AC_SUBST([lt_cv_dlopen_libs])
  63
  64
  65 AC_PROG_CC_C99
  66 AS_IF([test "x${ac_cv_prog_cc_c99}" == "xno"],[AC_MSG_ERROR([No c99 compatible compiler found])])
  67
  68 AC_DEFUN([CHECK_CXX0X],[
  69           AC_LANG_PUSH([C++])
  70           AX_CHECK_COMPILE_FLAG([-std=c++0x],[
  71                                  CXX="$CXX -std=c++0x"])
  72           AC_LANG_POP([C++])
  73           ])
  74 CHECK_CXX0X
  75
  76
  77 AC_LANG_PUSH([C])
  78 AX_COMPILER_VENDOR
  79 AX_COMPILER_VERSION
  80 AC_LANG_POP([C])
  81 AC_LANG_PUSH([C++])
  82 AX_COMPILER_VENDOR
  83 AX_COMPILER_VERSION
  84 AC_LANG_POP([C++])
  85
  86
  87 AX_ASSERT
  88
  89 AX_PLATFORM
  90 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  91
  92 AC_DEFUN([LIBMEMCACHED_PROTOCOL],
  93          [AC_ARG_ENABLE([libmemcachedprotocol],
  94                         [AS_HELP_STRING([--enable-libmemcachedprotocol],
  95                                         [Enable libmemcachedprotocol])],
  96                                         [ax_enable_libmemcachedprotocol=yes],
  97                                         [ax_enable_libmemcachedprotocol=no])
  98
  99          AM_CONDITIONAL([BUILD_LIBMEMCACHED_PROTOCOL],[test "$ax_enable_libmemcachedprotocol" = "yes"])
 100
 101          AC_MSG_CHECKING([for libmemcachedprotocol])
 102          AC_MSG_RESULT([$ax_enable_libmemcachedprotocol])
 103          ])
 104 LIBMEMCACHED_PROTOCOL
 105
 106 # Adding support for libtest
 107 m4_include([libtest/yatl.m4])
 108
 109 CHECK_FOR_GEARMAND
 110 CHECK_FOR_LIBGEARMAND
 111
 112 AM_CONDITIONAL([BUILDING_LIBMEMCACHED],[true])
 113 AM_CONDITIONAL([HAVE_LIBMEMCACHED],[false])
 114 AM_CONDITIONAL([HAVE_LIBDRIZZLE],[false])
 115 AC_DEFINE([HAVE_LIBMEMCACHED],[1],[Enables libmemcached Support])
 116
 117 AM_CONDITIONAL([BUILDING_GEARMAN],[false])
 118
 119 # Specialty checks
 120 AX_CXX_CINTTYPES
 121 CONFIG_EXTRA
 122 DETECT_BYTEORDER
 123 SETSOCKOPT_SANITY
 124 ENABLE_HSIEH_HASH
 125 ENABLE_MURMUR_HASH
 126 ENABLE_FNV64_HASH
 127 ENABLE_MEMASLAP
 128 PROTOCOL_BINARY_TEST
 129 ENABLE_DEPRECATED
 130
 131 # Checks for programs.
 132 AC_CHECK_PROGS([DPKG_GENSYMBOLS],[dpkg-gensymbols])
 133 AC_CHECK_PROGS([LEX],['flex'],[:])
 134 AC_CHECK_PROGS([PERL],[perl])
 135 AC_CHECK_PROGS([VALGRIND],['valgrind'])
 136 AC_CHECK_PROGS([WINE],['wine'])
 137 AC_CHECK_PROGS([YACC],['bison --warnings=all'],[:])
 138 AC_CHECK_PROGS([RPMBUILD],[rpmbuild --nocheck])
 139 AC_CHECK_PROGS([RPMDEV_SETUPTREE],[rpmdev-setuptree])
 140 AC_CHECK_PROGS([RPM],[rpm])
 141 AC_PROG_AWK
 142 AC_PROG_MKDIR_P
 143 AC_PROG_SED
 144 AX_PROG_MEMCACHED
 145 AX_PROG_SPHINX_BUILD(,[AC_MSG_WARN([sphinx-build version 1.0 or greater is required to build man pages])])
 146 AX_WITH_PROG([LCOV],[lcov])
 147 AX_WITH_PROG([LCOV_GENHTML],[genhtml])
 148 AC_DEFINE([HAVE_MEMCACHED_SASL_BINARY],[0],[If Memcached binary with sasl support is available])
 149
 150 # Checks for libraries.
 151 AC_SEARCH_LIBS([getopt_long],[gnugetopt])
 152 AC_SEARCH_LIBS([gethostbyname],[nsl])
 153
 154 # Checks for header files.
 155 AC_CHECK_HEADERS_ONCE([arpa/inet.h])
 156 AC_CHECK_HEADERS_ONCE([errno.h])
 157 AC_CHECK_HEADERS_ONCE([execinfo.h])
 158 AC_CHECK_HEADERS_ONCE([fcntl.h])
 159 AC_CHECK_HEADERS_ONCE([features.h])
 160 AC_CHECK_HEADERS_ONCE([fnmatch.h])
 161 AC_CHECK_HEADERS_ONCE([inttypes.h])
 162 AC_CHECK_HEADERS_ONCE([libintl.h])
 163 AC_CHECK_HEADERS_ONCE([limits.h])
 164 AC_CHECK_HEADERS_ONCE([linux/sysctl.h])
 165 AC_CHECK_HEADERS_ONCE([mach/mach.h])
 166 AC_CHECK_HEADERS_ONCE([malloc.h])
 167 AC_CHECK_HEADERS_ONCE([math.h])
 168 AC_CHECK_HEADERS_ONCE([netdb.h])
 169 AC_CHECK_HEADERS_ONCE([netinet/in.h])
 170 AC_CHECK_HEADERS_ONCE([netinet/tcp.h])
 171 AC_CHECK_HEADERS_ONCE([poll.h])
 172 AC_CHECK_HEADERS_ONCE([pthread.h])
 173 AC_CHECK_HEADERS_ONCE([spawn.h])
 174 AC_CHECK_HEADERS_ONCE([stdarg.h])
 175 AC_CHECK_HEADERS_ONCE([stddef.h])
 176 AC_CHECK_HEADERS_ONCE([stdio.h])
 177 AC_CHECK_HEADERS_ONCE([stdlib.h])
 178 AC_CHECK_HEADERS_ONCE([sys/socket.h])
 179 AC_CHECK_HEADERS_ONCE([sys/sysctl.h])
 180 AC_CHECK_HEADERS_ONCE([sys/time.h])
 181 AC_CHECK_HEADERS_ONCE([sys/types.h])
 182 AC_CHECK_HEADERS_ONCE([sys/un.h])
 183 AC_CHECK_HEADERS_ONCE([sys/wait.h])
 184 AC_CHECK_HEADERS_ONCE([syslog.h])
 185 AC_CHECK_HEADERS_ONCE([time.h])
 186 AC_CHECK_HEADERS_ONCE([unistd.h])
 187
 188 # Windows only
 189 AC_CHECK_HEADERS_ONCE([winsock2.h])
 190 AC_CHECK_HEADERS_ONCE([ws2tcpip.h])
 191
 192 # Checks for typedefs, structures, and compiler characteristics.
 193
 194 # Checks for library functions.
 195
 196 AC_CHECK_FUNCS([alarm])
 197 AC_CHECK_FUNCS([atexit])
 198 AC_CHECK_FUNCS([clock_gettime])
 199 AC_CHECK_FUNCS([dup2])
 200 AC_CHECK_FUNCS([fcntl])
 201 AC_CHECK_FUNCS([floor])
 202 AC_CHECK_FUNCS([getcwd])
 203 AC_CHECK_FUNCS([getline])
 204 AC_CHECK_FUNCS([gettimeofday])
 205 AC_CHECK_FUNCS([inet_ntoa])
 206 AC_CHECK_FUNCS([memchr])
 207 AC_CHECK_FUNCS([memmove])
 208 AC_CHECK_FUNCS([memset])
 209 AC_CHECK_FUNCS([pipe2])
 210 AC_CHECK_FUNCS([putenv])
 211 AC_CHECK_FUNCS([select])
 212 AC_CHECK_FUNCS([setenv])
 213 AC_CHECK_FUNCS([sigignore])
 214 AC_CHECK_FUNCS([socket])
 215 AC_CHECK_FUNCS([sqrt])
 216 AC_CHECK_FUNCS([strcasecmp])
 217 AC_CHECK_FUNCS([strchr])
 218 AC_CHECK_FUNCS([strdup])
 219 AC_CHECK_FUNCS([strerror])
 220 AC_CHECK_FUNCS([strstr])
 221 AC_CHECK_FUNCS([strtol])
 222 AC_CHECK_FUNCS([strtoul])
 223 AC_CHECK_FUNCS([strtoull])
 224 AC_FUNC_ALLOCA
 225 AC_FUNC_ERROR_AT_LINE
 226 AC_FUNC_FORK
 227 AC_FUNC_STRERROR_R
 228
 229 AC_CHECK_HEADER([umem.h],
 230                 [AC_DEFINE([HAVE_UMEM_H],[1],[Define this if you have umem.h])
 231                 build_cache=no],
 232                 [build_cache=yes])
 233
 234 AM_CONDITIONAL([BUILD_CACHE],[test "x$build_cache" = "xyes"])
 235
 236 AC_CHECK_TYPES([in_port_t],,,[[
 237                 #ifdef HAVE_SYS_TYPES_H
 238                 # include <sys/types.h>
 239                 #endif
 240                 #ifdef HAVE_NETINET_IN_H
 241                 # include <netinet/in.h>
 242                 #endif
 243                 #ifdef HAVE_NETDB_H
 244                 # include <netdb.h>
 245                 #endif]])
 246 AC_CHECK_TYPES([ptrdiff_t])
 247 AC_HEADER_STDBOOL
 248 AC_TYPE_INT16_T
 249 AC_TYPE_INT32_T
 250 AC_TYPE_INT64_T
 251 AC_TYPE_INT8_T
 252 AC_TYPE_OFF_T
 253 AC_TYPE_PID_T
 254 AC_TYPE_SSIZE_T
 255 AC_TYPE_UINT16_T
 256 AC_TYPE_UINT32_T
 257 AC_TYPE_UINT64_T
 258 AC_TYPE_UINT8_T
 259
 260 AC_C_BIGENDIAN
 261 AC_C_CONST
 262 AC_C_INLINE
 263 AC_C_VOLATILE
 264 AC_C_RESTRICT
 265
 266 AX_CXX_GCC_ABI_DEMANGLE
 267
 268 AX_LIBEVENT
 269
 270 AC_CHECK_LIB([rt],[clock_gettime],
 271              [AC_SUBST([RT_LIB],[-lrt])
 272              AC_DEFINE([HAVE_CLOCK_GETTIME],[1],[Have clock_gettime])],
 273              [AC_DEFINE([HAVE_CLOCK_GETTIME],[0],[Have clock_gettime])])
 274
 275
 276 AC_CHECK_HEADERS([atomic.h])
 277 AS_IF([test "x$ac_cv_header_atomic_h" = "xyes"],
 278       [AC_CHECK_FUNCS([atomic_add_64])
 279       AC_CHECK_FUNCS([atomic_add_32])
 280       AS_IF([test "x$ac_cv_func_atomic_add_64" = "xyes" -a "x$ac_cv_func_atomic_add_32" = "xyes"],
 281             [AC_DEFINE([USE_ATOMIC_H],[1],[Define to true if you want to use functions from atomic.h])])])
 282
 283 AC_DEFINE([HAVE_LIBDRIZZLE],[0],[Support for libdrizzle])
 284 AC_DEFINE([HAVE_DRIZZLED_BINARY],[0],[Support for DrizzleD])
 285 AC_DEFINE([DRIZZLED_BINARY],[0],[Support for DrizzleD])
 286 AC_DEFINE([GEARMAND_BLOBSLAP_WORKER],[0],[Support for Gearman Blobslap worker])
 287 AC_DEFINE([HAVE_LIBPQ],[0],[Support for Postgres])
 288 AC_DEFINE([HAVE_LIBCURL],[0],[Support for libcurl])
 289
 290 # Check for the requirements for running memcached with less privileges
 291 # than the default privilege set. On Solaris we need setppriv and priv.h
 292 # If you want to add support for other platforms you should check for
 293 # your requirements, define HAVE_DROP_PRIVILEGES, and make sure you add
 294 # the source file containing the implementation into memcached_SOURCE
 295 # in Makefile.am
 296 AC_CHECK_FUNCS([setppriv],
 297                [AC_CHECK_HEADER([priv.h],
 298                                 [AC_DEFINE([HAVE_DROP_PRIVILEGES],
 299                                            [1],
 300                                            [Define this if you have an implementation of drop_privileges()])
 301                                 build_solaris_privs=yes])
 302                ])
 303
 304 AM_CONDITIONAL([BUILD_POLL],[test "x$ac_cv_header_poll_h" = "xno"])
 305 AM_CONDITIONAL([BUILD_WIN32_WRAPPERS],[test "x$ac_cv_header_winsock2_h" = "xyes"])
 306 AS_IF([test "x$ac_cv_header_winsock2_h" = "xyes"],
 307       [AM_LDFLAGS="$AM_LDFLAGS -lws2_32"
 308        AM_CFLAGS="$AM_CFLAGS $NO_WERROR"
 309        AM_CXXFLAGS="$AM_CXXFLAGS $NO_WERROR"
 310        ])
 311 SOCKET_SEND_FLAGS
 312
 313 AX_UUID_GENERATE_TIME_SAFE
 314
 315 AC_DEFUN([CHECK_FOR_PTHREAD_AND_SASL],
 316          [AC_LANG_PUSH([C++])
 317          AX_PTHREAD(, [AC_MSG_ERROR([could not find libpthread])])
 318          AX_PTHREAD_TIMEDJOIN_NP
 319          AC_LANG_POP([C++])
 320
 321          # The sasl functions should only be visible if we build with sasl support
 322          #
 323          AX_SASL_OPTION
 324          AS_IF([test "x$ac_enable_sasl" = xyes],
 325                [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 1"],
 326                [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 0"])
 327          AC_SUBST([LIBMEMCACHED_WITH_SASL_SUPPORT])
 328          ])
 329 CHECK_FOR_PTHREAD_AND_SASL
 330
 331 # backtrace(), others require shared builds
 332 AC_DEFUN([__ENABLE_SHARED],
 333          [AC_REQUIRE([AX_PLATFORM])
 334          AS_IF([test "x${TARGET_WINDOWS}" = "xtrue"],[enable_shared=no])
 335          AS_IF([test "x$enable_shared" = "xyes"],
 336                [AC_DEFINE([HAVE_SHARED_ENABLED],[1],[Enable code which requires shared library support. Like backtrace().])])])
 337 AM_CONDITIONAL([SHARED_ENABLED],[test "x$enable_shared" = "xyes"])
 338
 339 PANDORA_ENABLE_DTRACE
 340 HAVE_GCC_ATOMICS
 341 AX_ENDIAN
 342 AX_ASSERT
 343 AX_HARDEN_COMPILER_FLAGS
 344
 345 AX_AM_JOBSERVER([yes])
 346
 347 AC_CONFIG_FILES([Makefile
 348                  docs/source/conf.py
 349                  libmemcached-1.0/configure.h
 350                  support/libmemcached.pc
 351                  support/libmemcached.spec
 352                  ])
 353 AC_OUTPUT
 354
 355 echo "---"
 356 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 357 echo ""
 358 echo "   * Installation prefix:       $prefix"
 359 echo "   * System type:               $host_vendor-$host_os"
 360 echo "   * Host CPU:                  $host_cpu"
 361 echo "   * C Compiler:                $ax_cv_c_compiler_vendor $ax_cv_c_compiler_version"
 362 echo "   * C Flags:                   $CFLAGS"
 363 echo "   * C++ Compiler:              $ax_cv_cxx_compiler_vendor $ax_cv_cxx_compiler_version"
 364 echo "   * C++ Flags:                 $CXXFLAGS"
 365 echo "   * CPP Flags:                 $CPPFLAGS"
 366 echo "   * LIB Flags:                 $LIB"
 367 echo "   * Assertions enabled:        $ax_enable_assert"
 368 echo "   * Debug enabled:             $ax_enable_debug"
 369 echo "   * Shared:                    $enable_shared"
 370 echo "   * Warnings as failure:       $ac_cv_warnings_as_errors"
 371 echo "   * SASL support:              $ac_enable_sasl"
 372 echo "   * make -j:                   $enable_jobserver"
 373 echo "   * VCS checkout:              $ac_cv_vcs_checkout"
 374 echo ""
 375 echo "---"
 376
 377 case "$host_os" in
 378   *freebsd*)
 379     echo "*****"
 380     echo "*"
 381     echo "*  NOTE: You are on FreeBSD. BSD make will not work."
 382     echo "*"
 383     echo "*   use 'gmake' To build libmemcached"
 384     echo "*"
 385     echo "*****"
 386   ;;
 387 esac
 388