git.m6w6.name Git - awesomized/libmemcached/blob - configure.ac

   1 # LibmemcacheD
   2 # Copyright (C) 2011-2013 Data Differential, http://datadifferential.com/
   3 # Copyright (C) 2006-2010 Brian Aker, Monty Taylor, Trond Norbye
   4 # All rights reserved.
   5 #
   6 # Use and distribution licensed under the BSD license.  See
   7 # the COPYING file in this directory for full text.
   8
   9 m4_include([version.m4])
  10 AC_INIT([libmemcached],VERSION_NUMBER,[http://libmemcached.org/])
  11 AC_CONFIG_AUX_DIR([build-aux])
  12 AC_CONFIG_MACRO_DIR([m4])
  13
  14 AC_CANONICAL_TARGET
  15 AC_ARG_PROGRAM
  16 AC_USE_SYSTEM_EXTENSIONS
  17
  18 AM_INIT_AUTOMAKE([1.11 color-tests -Wno-portability subdir-objects foreign tar-ustar])
  19
  20 AC_PREREQ([2.61])
  21
  22 AC_CONFIG_HEADERS([mem_config.h:mem_config.in])dnl Keep filename to 8.3 for MS-DOS.
  23 AC_SUBST([AUTOHEADER_FILE],[mem_config.h])
  24 AC_CONFIG_SRCDIR([libmemcached/memcached.cc])
  25
  26 #shared library versioning
  27 MEMCACHED_UTIL_LIBRARY_VERSION=2:0:0
  28 MEMCACHED_PROTOCAL_LIBRARY_VERSION=0:0:0
  29 MEMCACHED_LIBRARY_VERSION=11:0:0
  30 #                         | | |
  31 #                  +------+ | +---+
  32 #                  |        |     |
  33 #                 current:revision:age
  34 #                  |        |     |
  35 #                  |        |     +- increment if interfaces have been added
  36 #                  |        |        set to zero if interfaces have been removed or changed
  37 #                  |        +- increment if source code has changed
  38 #                  |           set to zero if current is incremented
  39 #                  +- increment if interfaces have been added, removed or changed
  40 AC_SUBST([MEMCACHED_UTIL_LIBRARY_VERSION])
  41 AC_SUBST([MEMCACHED_PROTOCAL_LIBRARY_VERSION])
  42 AC_SUBST([MEMCACHED_LIBRARY_VERSION])
  43
  44 AX_HEX_VERSION([LIBMEMCACHED],[$VERSION])
  45 AX_HEX_VERSION([LIBHASHKIT],[1.0.0])
  46
  47 m4_include([libhashkit/include.m4])
  48
  49 LT_PREREQ([2.2])
  50 LT_INIT([dlopen])
  51 LT_LANG([C++])
  52 LT_LIB_M
  53
  54 AC_SUBST([lt_cv_dlopen_libs])
  55
  56
  57 AC_PROG_CC_C99
  58 AS_IF([test "x${ac_cv_prog_cc_c99}" == "xno"],[AC_MSG_ERROR([No c99 compatible compiler found])])
  59
  60 AC_DEFUN([CHECK_CXX0X],[
  61           AC_LANG_PUSH([C++])
  62           AX_CHECK_COMPILE_FLAG([-std=c++0x],[
  63                                  CXXFLAGS="$CXXFLAGS -std=c++0x"])
  64           AC_LANG_POP([C++])
  65           ])
  66 CHECK_CXX0X
  67
  68 AX_ASSERT
  69
  70 AX_PLATFORM
  71
  72 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  73
  74 AX_CXX_HEADER_STDCXX_98
  75 AS_IF([test "x$ax_cv_cxx_stdcxx_98" = "xno"],
  76       [AC_MSG_ERROR([Your system lacks a new enough C++ compiler])])
  77
  78 AC_DEFUN([LIBMEMCACHED_PROTOCOL],
  79          [AC_ARG_ENABLE([libmemcachedprotocol],
  80                         [AS_HELP_STRING([--enable-libmemcachedprotocol],
  81                                         [Enable libmemcachedprotocol])],
  82                                         [ax_enable_libmemcachedprotocol=yes],
  83                                         [ax_enable_libmemcachedprotocol=no])
  84
  85          AM_CONDITIONAL([BUILD_LIBMEMCACHED_PROTOCOL],[test "$ax_enable_libmemcachedprotocol" = "yes"])
  86
  87          AC_MSG_CHECKING([for libmemcachedprotocol])
  88          AC_MSG_RESULT([$ax_enable_libmemcachedprotocol])
  89          ])
  90 LIBMEMCACHED_PROTOCOL
  91
  92 # Adding support for libtest
  93 m4_include([libtest/yatl.m4])
  94
  95 CHECK_FOR_GEARMAND
  96 CHECK_FOR_LIBGEARMAND
  97
  98 AM_CONDITIONAL([BUILDING_LIBMEMCACHED],[true])
  99 AM_CONDITIONAL([HAVE_LIBMEMCACHED],[false])
 100 AM_CONDITIONAL([HAVE_LIBDRIZZLE],[false])
 101 AC_DEFINE([HAVE_LIBMEMCACHED],[1],[Enables libmemcached Support])
 102
 103 AM_CONDITIONAL([BUILDING_GEARMAN],[false])
 104
 105 # Specialty checks
 106 AX_CXX_CINTTYPES
 107 CONFIG_EXTRA
 108 DETECT_BYTEORDER
 109 SETSOCKOPT_SANITY
 110 ENABLE_HSIEH_HASH
 111 ENABLE_MURMUR_HASH
 112 ENABLE_FNV64_HASH
 113 ENABLE_MEMASLAP
 114 PROTOCOL_BINARY_TEST
 115 ENABLE_DEPRECATED
 116
 117 # Checks for programs.
 118 AC_CHECK_PROGS([DPKG_GENSYMBOLS],[dpkg-gensymbols])
 119 AC_CHECK_PROGS([LEX],['flex'],[:])
 120 AC_CHECK_PROGS([PERL],[perl])
 121 AC_CHECK_PROGS([VALGRIND],['valgrind'])
 122 AC_CHECK_PROGS([WINE],['wine'])
 123 AC_CHECK_PROGS([YACC],['bison --warnings=all'],[:])
 124 AC_PROG_AWK
 125 AC_PROG_MKDIR_P
 126 AC_PROG_SED
 127 AX_PROG_MEMCACHED
 128 AX_PROG_SPHINX_BUILD(,[AC_MSG_WARN([sphinx-build version 1.0 or greater is required to build man pages])])
 129 AX_WITH_PROG([LCOV],[lcov])
 130 AX_WITH_PROG([LCOV_GENHTML],[genhtml])
 131 AC_DEFINE([HAVE_MEMCACHED_SASL_BINARY],[0],[If Memcached binary with sasl support is available])
 132
 133 # Checks for libraries.
 134 AC_SEARCH_LIBS([getopt_long],[gnugetopt])
 135 AC_SEARCH_LIBS([gethostbyname],[nsl])
 136
 137 # Checks for header files.
 138 AC_CHECK_HEADERS_ONCE([arpa/inet.h])
 139 AC_CHECK_HEADERS_ONCE([errno.h])
 140 AC_CHECK_HEADERS_ONCE([execinfo.h])
 141 AC_CHECK_HEADERS_ONCE([fcntl.h])
 142 AC_CHECK_HEADERS_ONCE([features.h])
 143 AC_CHECK_HEADERS_ONCE([fnmatch.h])
 144 AC_CHECK_HEADERS_ONCE([inttypes.h])
 145 AC_CHECK_HEADERS_ONCE([libintl.h])
 146 AC_CHECK_HEADERS_ONCE([limits.h])
 147 AC_CHECK_HEADERS_ONCE([mach/mach.h])
 148 AC_CHECK_HEADERS_ONCE([malloc.h])
 149 AC_CHECK_HEADERS_ONCE([math.h])
 150 AC_CHECK_HEADERS_ONCE([netdb.h])
 151 AC_CHECK_HEADERS_ONCE([netinet/in.h])
 152 AC_CHECK_HEADERS_ONCE([netinet/tcp.h])
 153 AC_CHECK_HEADERS_ONCE([poll.h])
 154 AC_CHECK_HEADERS_ONCE([pthread.h])
 155 AC_CHECK_HEADERS_ONCE([spawn.h])
 156 AC_CHECK_HEADERS_ONCE([stdarg.h])
 157 AC_CHECK_HEADERS_ONCE([stddef.h])
 158 AC_CHECK_HEADERS_ONCE([stdio.h])
 159 AC_CHECK_HEADERS_ONCE([stdlib.h])
 160 AC_CHECK_HEADERS_ONCE([sys/socket.h])
 161 AC_CHECK_HEADERS_ONCE([sys/sysctl.h])
 162 AC_CHECK_HEADERS_ONCE([sys/time.h])
 163 AC_CHECK_HEADERS_ONCE([sys/types.h])
 164 AC_CHECK_HEADERS_ONCE([sys/un.h])
 165 AC_CHECK_HEADERS_ONCE([sys/wait.h])
 166 AC_CHECK_HEADERS_ONCE([syslog.h])
 167 AC_CHECK_HEADERS_ONCE([time.h])
 168 AC_CHECK_HEADERS_ONCE([unistd.h])
 169
 170 # Windows only
 171 AC_CHECK_HEADERS_ONCE([winsock2.h])
 172 AC_CHECK_HEADERS_ONCE([ws2tcpip.h])
 173
 174 # Checks for typedefs, structures, and compiler characteristics.
 175
 176 # Checks for library functions.
 177
 178 AC_CHECK_FUNCS([alarm])
 179 AC_CHECK_FUNCS([atexit])
 180 AC_CHECK_FUNCS([clock_gettime])
 181 AC_CHECK_FUNCS([dup2])
 182 AC_CHECK_FUNCS([fcntl])
 183 AC_CHECK_FUNCS([floor])
 184 AC_CHECK_FUNCS([getcwd])
 185 AC_CHECK_FUNCS([getline])
 186 AC_CHECK_FUNCS([gettimeofday])
 187 AC_CHECK_FUNCS([inet_ntoa])
 188 AC_CHECK_FUNCS([memchr])
 189 AC_CHECK_FUNCS([memmove])
 190 AC_CHECK_FUNCS([memset])
 191 AC_CHECK_FUNCS([pipe2])
 192 AC_CHECK_FUNCS([putenv])
 193 AC_CHECK_FUNCS([select])
 194 AC_CHECK_FUNCS([setenv])
 195 AC_CHECK_FUNCS([sigignore])
 196 AC_CHECK_FUNCS([socket])
 197 AC_CHECK_FUNCS([sqrt])
 198 AC_CHECK_FUNCS([strcasecmp])
 199 AC_CHECK_FUNCS([strchr])
 200 AC_CHECK_FUNCS([strdup])
 201 AC_CHECK_FUNCS([strerror])
 202 AC_CHECK_FUNCS([strstr])
 203 AC_CHECK_FUNCS([strtol])
 204 AC_CHECK_FUNCS([strtoul])
 205 AC_CHECK_FUNCS([strtoull])
 206 AC_FUNC_ALLOCA
 207 AC_FUNC_ERROR_AT_LINE
 208 AC_FUNC_FORK
 209 AC_FUNC_STRERROR_R
 210
 211 AC_CHECK_HEADER([umem.h],
 212                 [AC_DEFINE([HAVE_UMEM_H],[1],[Define this if you have umem.h])
 213                 build_cache=no],
 214                 [build_cache=yes])
 215
 216 AM_CONDITIONAL([BUILD_CACHE],[test "x$build_cache" = "xyes"])
 217
 218 AX_COMPILER_VENDOR
 219
 220 AC_CHECK_TYPES([in_port_t],,,[[
 221                 #ifdef HAVE_SYS_TYPES_H
 222                 # include <sys/types.h>
 223                 #endif
 224                 #ifdef HAVE_NETINET_IN_H
 225                 # include <netinet/in.h>
 226                 #endif
 227                 #ifdef HAVE_NETDB_H
 228                 # include <netdb.h>
 229                 #endif]])
 230 AC_CHECK_TYPES([ptrdiff_t])
 231 AC_HEADER_STDBOOL
 232 AC_TYPE_INT16_T
 233 AC_TYPE_INT32_T
 234 AC_TYPE_INT64_T
 235 AC_TYPE_INT8_T
 236 AC_TYPE_OFF_T
 237 AC_TYPE_PID_T
 238 AC_TYPE_SSIZE_T
 239 AC_TYPE_UINT16_T
 240 AC_TYPE_UINT32_T
 241 AC_TYPE_UINT64_T
 242 AC_TYPE_UINT8_T
 243
 244 AC_C_BIGENDIAN
 245 AC_C_CONST
 246 AC_C_INLINE
 247 AC_C_VOLATILE
 248 AC_C_RESTRICT
 249
 250 AX_CXX_GCC_ABI_DEMANGLE
 251
 252 AX_LIBEVENT
 253
 254 AC_CHECK_LIB([rt],[clock_gettime],
 255              [AC_SUBST([RT_LIB],[-lrt])
 256              AC_DEFINE([HAVE_CLOCK_GETTIME],[1],[Have clock_gettime])],
 257              [AC_DEFINE([HAVE_CLOCK_GETTIME],[0],[Have clock_gettime])])
 258
 259
 260 AC_CHECK_HEADERS([atomic.h])
 261 AS_IF([test "x$ac_cv_header_atomic_h" = "xyes"],
 262       [AC_CHECK_FUNCS([atomic_add_64])
 263       AC_CHECK_FUNCS([atomic_add_32])
 264       AS_IF([test "x$ac_cv_func_atomic_add_64" = "xyes" -a "x$ac_cv_func_atomic_add_32" = "xyes"],
 265             [AC_DEFINE([USE_ATOMIC_H],[1],[Define to true if you want to use functions from atomic.h])])])
 266
 267 AC_DEFINE([HAVE_LIBDRIZZLE],[0],[Support for libdrizzle])
 268 AC_DEFINE([HAVE_DRIZZLED_BINARY],[0],[Support for DrizzleD])
 269 AC_DEFINE([DRIZZLED_BINARY],[0],[Support for DrizzleD])
 270 AC_DEFINE([GEARMAND_BLOBSLAP_WORKER],[0],[Support for Gearman Blobslap worker])
 271 AC_DEFINE([HAVE_LIBPQ],[0],[Support for Postgres])
 272 AC_DEFINE([HAVE_LIBCURL],[0],[Support for libcurl])
 273
 274 # Check for the requirements for running memcached with less privileges
 275 # than the default privilege set. On Solaris we need setppriv and priv.h
 276 # If you want to add support for other platforms you should check for
 277 # your requirements, define HAVE_DROP_PRIVILEGES, and make sure you add
 278 # the source file containing the implementation into memcached_SOURCE
 279 # in Makefile.am
 280 AC_CHECK_FUNCS([setppriv],
 281                [AC_CHECK_HEADER([priv.h],
 282                                 [AC_DEFINE([HAVE_DROP_PRIVILEGES],
 283                                            [1],
 284                                            [Define this if you have an implementation of drop_privileges()])
 285                                 build_solaris_privs=yes])
 286                ])
 287
 288 AM_CONDITIONAL([BUILD_POLL],[test "x$ac_cv_header_poll_h" = "xno"])
 289 AM_CONDITIONAL([BUILD_WIN32_WRAPPERS],[test "x$ac_cv_header_winsock2_h" = "xyes"])
 290 AS_IF([test "x$ac_cv_header_winsock2_h" = "xyes"],
 291       [AM_LDFLAGS="$AM_LDFLAGS -lws2_32"
 292        AM_CFLAGS="$AM_CFLAGS $NO_WERROR"
 293        AM_CXXFLAGS="$AM_CXXFLAGS $NO_WERROR"
 294        ])
 295 SOCKET_SEND_FLAGS
 296
 297 AX_UUID_GENERATE_TIME_SAFE
 298
 299 AC_DEFUN([CHECK_FOR_PTHREAD_AND_SASL],
 300          [AX_PTHREAD(, [AC_MSG_ERROR([could not find libpthread])])
 301          AX_PTHREAD_TIMEDJOIN_NP
 302
 303          # The sasl functions should only be visible if we build with sasl support
 304          #
 305          AX_SASL_OPTION
 306          AS_IF([test "x$ac_enable_sasl" = xyes],
 307                [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 1"],
 308                [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 0"])
 309          AC_SUBST([LIBMEMCACHED_WITH_SASL_SUPPORT])
 310          ])
 311 CHECK_FOR_PTHREAD_AND_SASL
 312
 313 # backtrace(), others require shared builds
 314 AC_DEFUN([__ENABLE_SHARED],
 315          [AC_REQUIRE([AX_PLATFORM])
 316          AS_IF([test "x${TARGET_WINDOWS}" = "xtrue"],[enable_shared=no])
 317          AS_IF([test "x$enable_shared" = "xyes"],
 318                [AC_DEFINE([HAVE_SHARED_ENABLED],[1],[Enable code which requires shared library support. Like backtrace().])])])
 319 AM_CONDITIONAL([SHARED_ENABLED],[test "x$enable_shared" = "xyes"])
 320
 321 PANDORA_ENABLE_DTRACE
 322 HAVE_GCC_ATOMICS
 323 AX_ENDIAN
 324 AX_ASSERT
 325 AX_HARDEN_COMPILER_FLAGS
 326
 327 AX_AM_JOBSERVER([yes])
 328
 329 AC_CONFIG_FILES([Makefile
 330                  docs/conf.py
 331                  libmemcached-1.0/configure.h
 332                  support/libmemcached.pc
 333                  support/libmemcached.spec
 334                  ])
 335 AC_OUTPUT
 336
 337 echo "---"
 338 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 339 echo ""
 340 echo "   * Installation prefix:       $prefix"
 341 echo "   * System type:               $host_vendor-$host_os"
 342 echo "   * Host CPU:                  $host_cpu"
 343 echo "   * C Compiler:                $CC_VERSION"
 344 echo "   * C Flags:                   $CFLAGS"
 345 echo "   * C++ Compiler:              $CXX_VERSION"
 346 echo "   * C++ Flags:                 $CXXFLAGS"
 347 echo "   * CPP Flags:                 $CPPFLAGS"
 348 echo "   * LIB Flags:                 $LIB"
 349 echo "   * Assertions enabled:        $ax_enable_assert"
 350 echo "   * Debug enabled:             $ax_enable_debug"
 351 echo "   * Shared:                    $enable_shared"
 352 echo "   * Warnings as failure:       $ac_cv_warnings_as_errors"
 353 echo "   * SASL support:              $ac_enable_sasl"
 354 echo "   * make -j:                   $enable_jobserver"
 355 echo "   * VCS checkout:              $ac_cv_vcs_checkout"
 356 echo ""
 357 echo "---"
 358
 359 case "$host_os" in
 360   *freebsd*)
 361     echo "*****"
 362     echo "*"
 363     echo "*  NOTE: You are on FreeBSD. BSD make will not work."
 364     echo "*"
 365     echo "*   use 'gmake' To build libmemcached"
 366     echo "*"
 367     echo "*****"
 368   ;;
 369 esac
 370