git.m6w6.name Git - awesomized/libmemcached/blob - configure.ac

   1 # LibmemcacheD
   2 # Copyright (C) 2011-2013 Data Differential, http://datadifferential.com/
   3 # Copyright (C) 2006-2010 Brian Aker, Monty Taylor, Trond Norbye
   4 # All rights reserved.
   5 #
   6 # Use and distribution licensed under the BSD license.  See
   7 # the COPYING file in this directory for full text.
   8
   9 m4_include([version.m4])
  10 AC_INIT([libmemcached],VERSION_NUMBER,[http://libmemcached.org/])
  11 AC_CONFIG_AUX_DIR([build-aux])
  12 AC_CONFIG_MACRO_DIR([m4])
  13
  14 AC_CANONICAL_TARGET
  15 AC_ARG_PROGRAM
  16 AC_USE_SYSTEM_EXTENSIONS
  17
  18 AM_INIT_AUTOMAKE([1.11 color-tests -Wno-portability subdir-objects foreign tar-ustar])
  19
  20 AC_PREREQ([2.61])
  21
  22 AC_CONFIG_HEADERS([mem_config.h:mem_config.in])dnl Keep filename to 8.3 for MS-DOS.
  23 AC_SUBST([AUTOHEADER_FILE],[mem_config.h])
  24 AC_CONFIG_SRCDIR([libmemcached/memcached.cc])
  25
  26 #shared library versioning
  27 MEMCACHED_UTIL_LIBRARY_VERSION=2:0:0
  28 MEMCACHED_PROTOCAL_LIBRARY_VERSION=0:0:0
  29 MEMCACHED_LIBRARY_VERSION=11:0:0
  30 #                         | | |
  31 #                  +------+ | +---+
  32 #                  |        |     |
  33 #                 current:revision:age
  34 #                  |        |     |
  35 #                  |        |     +- increment if interfaces have been added
  36 #                  |        |        set to zero if interfaces have been removed or changed
  37 #                  |        +- increment if source code has changed
  38 #                  |           set to zero if current is incremented
  39 #                  +- increment if interfaces have been added, removed or changed
  40 AC_SUBST([MEMCACHED_UTIL_LIBRARY_VERSION])
  41 AC_SUBST([MEMCACHED_PROTOCAL_LIBRARY_VERSION])
  42 AC_SUBST([MEMCACHED_LIBRARY_VERSION])
  43
  44 AX_HEX_VERSION([LIBMEMCACHED],[$VERSION])
  45 AX_HEX_VERSION([LIBHASHKIT],[1.0.0])
  46
  47 m4_include([libhashkit/include.m4])
  48
  49 LT_PREREQ([2.2])
  50 LT_INIT([dlopen])
  51 LT_LANG([C++])
  52 LT_LIB_M
  53
  54 AC_SUBST([lt_cv_dlopen_libs])
  55
  56
  57 AC_PROG_CC_C99
  58 AS_IF([test "x${ac_cv_prog_cc_c99}" == "xno"],[AC_MSG_ERROR([No c99 compatible compiler found])])
  59
  60 AC_DEFUN([CHECK_CXX0X],[
  61           AC_LANG_PUSH([C++])
  62           AX_CHECK_COMPILE_FLAG([-std=c++0x],[
  63                                  CXX="$CXX -std=c++0x"])
  64           AC_LANG_POP([C++])
  65           ])
  66 CHECK_CXX0X
  67
  68 AX_ASSERT
  69
  70 AX_PLATFORM
  71
  72 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  73
  74 AC_DEFUN([LIBMEMCACHED_PROTOCOL],
  75          [AC_ARG_ENABLE([libmemcachedprotocol],
  76                         [AS_HELP_STRING([--enable-libmemcachedprotocol],
  77                                         [Enable libmemcachedprotocol])],
  78                                         [ax_enable_libmemcachedprotocol=yes],
  79                                         [ax_enable_libmemcachedprotocol=no])
  80
  81          AM_CONDITIONAL([BUILD_LIBMEMCACHED_PROTOCOL],[test "$ax_enable_libmemcachedprotocol" = "yes"])
  82
  83          AC_MSG_CHECKING([for libmemcachedprotocol])
  84          AC_MSG_RESULT([$ax_enable_libmemcachedprotocol])
  85          ])
  86 LIBMEMCACHED_PROTOCOL
  87
  88 # Adding support for libtest
  89 m4_include([libtest/yatl.m4])
  90
  91 CHECK_FOR_GEARMAND
  92 CHECK_FOR_LIBGEARMAND
  93
  94 AM_CONDITIONAL([BUILDING_LIBMEMCACHED],[true])
  95 AM_CONDITIONAL([HAVE_LIBMEMCACHED],[false])
  96 AM_CONDITIONAL([HAVE_LIBDRIZZLE],[false])
  97 AC_DEFINE([HAVE_LIBMEMCACHED],[1],[Enables libmemcached Support])
  98
  99 AM_CONDITIONAL([BUILDING_GEARMAN],[false])
 100
 101 # Specialty checks
 102 AX_CXX_CINTTYPES
 103 CONFIG_EXTRA
 104 DETECT_BYTEORDER
 105 SETSOCKOPT_SANITY
 106 ENABLE_HSIEH_HASH
 107 ENABLE_MURMUR_HASH
 108 ENABLE_FNV64_HASH
 109 ENABLE_MEMASLAP
 110 PROTOCOL_BINARY_TEST
 111 ENABLE_DEPRECATED
 112
 113 # Checks for programs.
 114 AC_CHECK_PROGS([DPKG_GENSYMBOLS],[dpkg-gensymbols])
 115 AC_CHECK_PROGS([LEX],['flex'],[:])
 116 AC_CHECK_PROGS([PERL],[perl])
 117 AC_CHECK_PROGS([VALGRIND],['valgrind'])
 118 AC_CHECK_PROGS([WINE],['wine'])
 119 AC_CHECK_PROGS([YACC],['bison --warnings=all'],[:])
 120 AC_PROG_AWK
 121 AC_PROG_MKDIR_P
 122 AC_PROG_SED
 123 AX_PROG_MEMCACHED
 124 AX_PROG_SPHINX_BUILD(,[AC_MSG_WARN([sphinx-build version 1.0 or greater is required to build man pages])])
 125 AX_WITH_PROG([LCOV],[lcov])
 126 AX_WITH_PROG([LCOV_GENHTML],[genhtml])
 127 AC_DEFINE([HAVE_MEMCACHED_SASL_BINARY],[0],[If Memcached binary with sasl support is available])
 128
 129 # Checks for libraries.
 130 AC_SEARCH_LIBS([getopt_long],[gnugetopt])
 131 AC_SEARCH_LIBS([gethostbyname],[nsl])
 132
 133 # Checks for header files.
 134 AC_CHECK_HEADERS_ONCE([arpa/inet.h])
 135 AC_CHECK_HEADERS_ONCE([errno.h])
 136 AC_CHECK_HEADERS_ONCE([execinfo.h])
 137 AC_CHECK_HEADERS_ONCE([fcntl.h])
 138 AC_CHECK_HEADERS_ONCE([features.h])
 139 AC_CHECK_HEADERS_ONCE([fnmatch.h])
 140 AC_CHECK_HEADERS_ONCE([inttypes.h])
 141 AC_CHECK_HEADERS_ONCE([libintl.h])
 142 AC_CHECK_HEADERS_ONCE([limits.h])
 143 AC_CHECK_HEADERS_ONCE([mach/mach.h])
 144 AC_CHECK_HEADERS_ONCE([malloc.h])
 145 AC_CHECK_HEADERS_ONCE([math.h])
 146 AC_CHECK_HEADERS_ONCE([netdb.h])
 147 AC_CHECK_HEADERS_ONCE([netinet/in.h])
 148 AC_CHECK_HEADERS_ONCE([netinet/tcp.h])
 149 AC_CHECK_HEADERS_ONCE([poll.h])
 150 AC_CHECK_HEADERS_ONCE([pthread.h])
 151 AC_CHECK_HEADERS_ONCE([spawn.h])
 152 AC_CHECK_HEADERS_ONCE([stdarg.h])
 153 AC_CHECK_HEADERS_ONCE([stddef.h])
 154 AC_CHECK_HEADERS_ONCE([stdio.h])
 155 AC_CHECK_HEADERS_ONCE([stdlib.h])
 156 AC_CHECK_HEADERS_ONCE([sys/socket.h])
 157 AC_CHECK_HEADERS_ONCE([sys/sysctl.h])
 158 AC_CHECK_HEADERS_ONCE([sys/time.h])
 159 AC_CHECK_HEADERS_ONCE([sys/types.h])
 160 AC_CHECK_HEADERS_ONCE([sys/un.h])
 161 AC_CHECK_HEADERS_ONCE([sys/wait.h])
 162 AC_CHECK_HEADERS_ONCE([syslog.h])
 163 AC_CHECK_HEADERS_ONCE([time.h])
 164 AC_CHECK_HEADERS_ONCE([unistd.h])
 165
 166 # Windows only
 167 AC_CHECK_HEADERS_ONCE([winsock2.h])
 168 AC_CHECK_HEADERS_ONCE([ws2tcpip.h])
 169
 170 # Checks for typedefs, structures, and compiler characteristics.
 171
 172 # Checks for library functions.
 173
 174 AC_CHECK_FUNCS([alarm])
 175 AC_CHECK_FUNCS([atexit])
 176 AC_CHECK_FUNCS([clock_gettime])
 177 AC_CHECK_FUNCS([dup2])
 178 AC_CHECK_FUNCS([fcntl])
 179 AC_CHECK_FUNCS([floor])
 180 AC_CHECK_FUNCS([getcwd])
 181 AC_CHECK_FUNCS([getline])
 182 AC_CHECK_FUNCS([gettimeofday])
 183 AC_CHECK_FUNCS([inet_ntoa])
 184 AC_CHECK_FUNCS([memchr])
 185 AC_CHECK_FUNCS([memmove])
 186 AC_CHECK_FUNCS([memset])
 187 AC_CHECK_FUNCS([pipe2])
 188 AC_CHECK_FUNCS([putenv])
 189 AC_CHECK_FUNCS([select])
 190 AC_CHECK_FUNCS([setenv])
 191 AC_CHECK_FUNCS([sigignore])
 192 AC_CHECK_FUNCS([socket])
 193 AC_CHECK_FUNCS([sqrt])
 194 AC_CHECK_FUNCS([strcasecmp])
 195 AC_CHECK_FUNCS([strchr])
 196 AC_CHECK_FUNCS([strdup])
 197 AC_CHECK_FUNCS([strerror])
 198 AC_CHECK_FUNCS([strstr])
 199 AC_CHECK_FUNCS([strtol])
 200 AC_CHECK_FUNCS([strtoul])
 201 AC_CHECK_FUNCS([strtoull])
 202 AC_FUNC_ALLOCA
 203 AC_FUNC_ERROR_AT_LINE
 204 AC_FUNC_FORK
 205 AC_FUNC_STRERROR_R
 206
 207 AC_CHECK_HEADER([umem.h],
 208                 [AC_DEFINE([HAVE_UMEM_H],[1],[Define this if you have umem.h])
 209                 build_cache=no],
 210                 [build_cache=yes])
 211
 212 AM_CONDITIONAL([BUILD_CACHE],[test "x$build_cache" = "xyes"])
 213
 214 AX_COMPILER_VENDOR
 215
 216 AC_CHECK_TYPES([in_port_t],,,[[
 217                 #ifdef HAVE_SYS_TYPES_H
 218                 # include <sys/types.h>
 219                 #endif
 220                 #ifdef HAVE_NETINET_IN_H
 221                 # include <netinet/in.h>
 222                 #endif
 223                 #ifdef HAVE_NETDB_H
 224                 # include <netdb.h>
 225                 #endif]])
 226 AC_CHECK_TYPES([ptrdiff_t])
 227 AC_HEADER_STDBOOL
 228 AC_TYPE_INT16_T
 229 AC_TYPE_INT32_T
 230 AC_TYPE_INT64_T
 231 AC_TYPE_INT8_T
 232 AC_TYPE_OFF_T
 233 AC_TYPE_PID_T
 234 AC_TYPE_SSIZE_T
 235 AC_TYPE_UINT16_T
 236 AC_TYPE_UINT32_T
 237 AC_TYPE_UINT64_T
 238 AC_TYPE_UINT8_T
 239
 240 AC_C_BIGENDIAN
 241 AC_C_CONST
 242 AC_C_INLINE
 243 AC_C_VOLATILE
 244 AC_C_RESTRICT
 245
 246 AX_CXX_GCC_ABI_DEMANGLE
 247
 248 AX_LIBEVENT
 249
 250 AC_CHECK_LIB([rt],[clock_gettime],
 251              [AC_SUBST([RT_LIB],[-lrt])
 252              AC_DEFINE([HAVE_CLOCK_GETTIME],[1],[Have clock_gettime])],
 253              [AC_DEFINE([HAVE_CLOCK_GETTIME],[0],[Have clock_gettime])])
 254
 255
 256 AC_CHECK_HEADERS([atomic.h])
 257 AS_IF([test "x$ac_cv_header_atomic_h" = "xyes"],
 258       [AC_CHECK_FUNCS([atomic_add_64])
 259       AC_CHECK_FUNCS([atomic_add_32])
 260       AS_IF([test "x$ac_cv_func_atomic_add_64" = "xyes" -a "x$ac_cv_func_atomic_add_32" = "xyes"],
 261             [AC_DEFINE([USE_ATOMIC_H],[1],[Define to true if you want to use functions from atomic.h])])])
 262
 263 AC_DEFINE([HAVE_LIBDRIZZLE],[0],[Support for libdrizzle])
 264 AC_DEFINE([HAVE_DRIZZLED_BINARY],[0],[Support for DrizzleD])
 265 AC_DEFINE([DRIZZLED_BINARY],[0],[Support for DrizzleD])
 266 AC_DEFINE([GEARMAND_BLOBSLAP_WORKER],[0],[Support for Gearman Blobslap worker])
 267 AC_DEFINE([HAVE_LIBPQ],[0],[Support for Postgres])
 268 AC_DEFINE([HAVE_LIBCURL],[0],[Support for libcurl])
 269
 270 # Check for the requirements for running memcached with less privileges
 271 # than the default privilege set. On Solaris we need setppriv and priv.h
 272 # If you want to add support for other platforms you should check for
 273 # your requirements, define HAVE_DROP_PRIVILEGES, and make sure you add
 274 # the source file containing the implementation into memcached_SOURCE
 275 # in Makefile.am
 276 AC_CHECK_FUNCS([setppriv],
 277                [AC_CHECK_HEADER([priv.h],
 278                                 [AC_DEFINE([HAVE_DROP_PRIVILEGES],
 279                                            [1],
 280                                            [Define this if you have an implementation of drop_privileges()])
 281                                 build_solaris_privs=yes])
 282                ])
 283
 284 AM_CONDITIONAL([BUILD_POLL],[test "x$ac_cv_header_poll_h" = "xno"])
 285 AM_CONDITIONAL([BUILD_WIN32_WRAPPERS],[test "x$ac_cv_header_winsock2_h" = "xyes"])
 286 AS_IF([test "x$ac_cv_header_winsock2_h" = "xyes"],
 287       [AM_LDFLAGS="$AM_LDFLAGS -lws2_32"
 288        AM_CFLAGS="$AM_CFLAGS $NO_WERROR"
 289        AM_CXXFLAGS="$AM_CXXFLAGS $NO_WERROR"
 290        ])
 291 SOCKET_SEND_FLAGS
 292
 293 AX_UUID_GENERATE_TIME_SAFE
 294
 295 AC_DEFUN([CHECK_FOR_PTHREAD_AND_SASL],
 296          [AC_LANG_PUSH([C++])
 297          AX_PTHREAD(, [AC_MSG_ERROR([could not find libpthread])])
 298          AX_PTHREAD_TIMEDJOIN_NP
 299          AC_LANG_POP([C++])
 300
 301          # The sasl functions should only be visible if we build with sasl support
 302          #
 303          AX_SASL_OPTION
 304          AS_IF([test "x$ac_enable_sasl" = xyes],
 305                [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 1"],
 306                [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 0"])
 307          AC_SUBST([LIBMEMCACHED_WITH_SASL_SUPPORT])
 308          ])
 309 CHECK_FOR_PTHREAD_AND_SASL
 310
 311 # backtrace(), others require shared builds
 312 AC_DEFUN([__ENABLE_SHARED],
 313          [AC_REQUIRE([AX_PLATFORM])
 314          AS_IF([test "x${TARGET_WINDOWS}" = "xtrue"],[enable_shared=no])
 315          AS_IF([test "x$enable_shared" = "xyes"],
 316                [AC_DEFINE([HAVE_SHARED_ENABLED],[1],[Enable code which requires shared library support. Like backtrace().])])])
 317 AM_CONDITIONAL([SHARED_ENABLED],[test "x$enable_shared" = "xyes"])
 318
 319 PANDORA_ENABLE_DTRACE
 320 HAVE_GCC_ATOMICS
 321 AX_ENDIAN
 322 AX_ASSERT
 323 AX_HARDEN_COMPILER_FLAGS
 324
 325 AX_AM_JOBSERVER([yes])
 326
 327 AC_CONFIG_FILES([Makefile
 328                  docs/conf.py
 329                  libmemcached-1.0/configure.h
 330                  support/libmemcached.pc
 331                  support/libmemcached.spec
 332                  ])
 333 AC_OUTPUT
 334
 335 echo "---"
 336 echo "Configuration summary for $PACKAGE_NAME version $VERSION"
 337 echo ""
 338 echo "   * Installation prefix:       $prefix"
 339 echo "   * System type:               $host_vendor-$host_os"
 340 echo "   * Host CPU:                  $host_cpu"
 341 echo "   * C Compiler:                $CC_VERSION"
 342 echo "   * C Flags:                   $CFLAGS"
 343 echo "   * C++ Compiler:              $CXX_VERSION"
 344 echo "   * C++ Flags:                 $CXXFLAGS"
 345 echo "   * CPP Flags:                 $CPPFLAGS"
 346 echo "   * LIB Flags:                 $LIB"
 347 echo "   * Assertions enabled:        $ax_enable_assert"
 348 echo "   * Debug enabled:             $ax_enable_debug"
 349 echo "   * Shared:                    $enable_shared"
 350 echo "   * Warnings as failure:       $ac_cv_warnings_as_errors"
 351 echo "   * SASL support:              $ac_enable_sasl"
 352 echo "   * make -j:                   $enable_jobserver"
 353 echo "   * VCS checkout:              $ac_cv_vcs_checkout"
 354 echo ""
 355 echo "---"
 356
 357 case "$host_os" in
 358   *freebsd*)
 359     echo "*****"
 360     echo "*"
 361     echo "*  NOTE: You are on FreeBSD. BSD make will not work."
 362     echo "*"
 363     echo "*   use 'gmake' To build libmemcached"
 364     echo "*"
 365     echo "*****"
 366   ;;
 367 esac
 368