git.m6w6.name Git - awesomized/libmemcached/blob - CPack.txt

   1 # default options
   2
   3 set(CPACK_ARCHIVE_COMPONENT_INSTALL ${CPACK_COMPONENT_INSTALL})
   4 set(CPACK_SOURCE_IGNORE_FILES "/[.]git/;/[.](idea|settings|c?project);~$;[.]log$;[.]bak$")
   5
   6 macro(cpack_include_if GENERATOR)
   7     message(STATUS "Checking ${GENERATOR} package configuration ...")
   8     if(EXISTS ${CMAKE_SOURCE_DIR}/CPack/${GENERATOR}.txt)
   9         include(${CMAKE_SOURCE_DIR}/CPack/${GENERATOR}.txt)
  10     endif()
  11 endmacro()
  12
  13 # shell installer
  14 set(CPACK_BINARY_STGZ ${UNIX})
  15
  16 # binary archive
  17 set(CPACK_BINARY_TBZ2 0)
  18 set(CPACK_BINARY_TGZ ${UNIX})
  19 set(CPACK_BINARY_TXZ 0)
  20 set(CPACK_BINARY_TZ 0)
  21 set(CPACK_BINARY_ZIP ${WIN32})
  22 set(CPACK_BINARY_NSIS ${WIN32})
  23 set(CPACK_BINARY_NUGET 0)
  24
  25 # source archive
  26 set(CPACK_SOURCE_TBZ2 0)
  27 set(CPACK_SOURCE_TGZ ${UNIX})
  28 set(CPACK_SOURCE_TXZ 0)
  29 set(CPACK_SOURCE_TZ 0)
  30 set(CPACK_SOURCE_ZIP ${WIN32})
  31
  32 # project internals
  33 set(CPACK_PACKAGE_LICENSE "BSD-3-Clause")
  34 set(CPACK_PACKAGE_CONTACT "${PROJECT_CONTACT}")
  35 set(CPACK_PACKAGE_VENDOR "${PROJECT_CONTACT}")
  36 set(CPACK_PACKAGE_DESCRIPTION
  37         "libmemcached-awesome is an open source C/C++ client library and tools
  38 for the memcached server (http://memcached.org/). It has been designed
  39 to be light on memory usage, thread safe, and provide full access to
  40 server side methods.")
  41 set(CPACK_PROJECT_CONFIG ${PROJECT_CONFIG})
  42 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPack/ProjectConfig.txt")
  43 set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_SOURCE_DIR}/README.md")
  44 set(CPACK_PACKAGE_INSTALL_DIRECTORY "${PROJECT_NAME}/${PROJECT_VERSION}")
  45 set(CPACK_PACKAGE_CHECKSUM SHA1)
  46 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/LICENSE")
  47 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/README.md")
  48 set(CPACK_CHANGELOG_FILE "${CMAKE_SOURCE_DIR}/ChangeLog-1.1.md")
  49 set(CPACK_PACKAGE_DIRECTORY "${CMAKE_BINARY_DIR}")
  50
  51 execute_process(
  52         COMMAND git describe --tags --match [0-9]*.*
  53         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
  54         OUTPUT_VARIABLE PROJECT_TAG
  55         ERROR_VARIABLE GIT_ERROR_OUTPUT
  56 )
  57 if(GIT_ERROR_OUTPUT)
  58     message(NOTICE "git describe: ${GIT_ERROR_OUTPUT}")
  59 endif()
  60 string(STRIP "${PROJECT_TAG}" PROJECT_TAG)
  61 if(PROJECT_TAG)
  62     set(CPACK_PACKAGE_FILE_NAME ${PROJECT_NAME}-${PROJECT_TAG})
  63     set(CPACK_PACKAGE_VERSION ${PROJECT_TAG})
  64 else()
  65     set(CPACK_PACKAGE_FILE_NAME ${PROJECT_NAME}-${PROJECT_VERSION})
  66     set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  67 endif()
  68
  69 # dependencies
  70 if(HAVE_LIBSASL)
  71     string(APPEND CPACK_PACKAGE_DEPENDS " libsasl2")
  72 endif()
  73 if(HAVE_TBB)
  74     string(APPEND CPACK_PACKAGE_DEPENDS " tbb")
  75 endif()
  76 if(HAVE_LIBEVENT)
  77     string(APPEND CPACK_PACKAGE_DEPENDS " libevent")
  78 endif()
  79
  80 # DEBs
  81 find_program(DPKG dpkg)
  82 if(DPKG)
  83     cpack_include_if(DEB)
  84 endif()
  85
  86 # WIN
  87 if(WIN32)
  88     cpack_include_if(NSIS)
  89 endif()
  90
  91 # RPMs
  92 find_program(RPMBUILD rpmbuild)
  93 if(RPMBUILD)
  94     cpack_include_if(RPM)
  95 endif()
  96
  97 # keep last
  98 include(CPack)
  99
 100 set(PUSH_ARTIFACTS_SH "${CMAKE_SOURCE_DIR}/scripts/push-artifacts.sh")
 101 if(WIN32)
 102     set(PUSH_ARTIFACTS_CMD msys2 -c '${PUSH_ARTIFACTS_SH} ${CPACK_PACKAGE_VERSION}')
 103 else()
 104     set(PUSH_ARTIFACTS_CMD ${PUSH_ARTIFACTS_SH} ${CPACK_PACKAGE_VERSION})
 105 endif()
 106
 107 add_custom_target(push-artifacts
 108         COMMAND ${PUSH_ARTIFACTS_CMD}
 109         WORKING_DIRECTORY ${CPACK_PACKAGE_DIRECTORY}
 110         )
 111