- PSI_TYPES=""
- dnl PSI_TYPE(type name, basic type, includes)
- AC_DEFUN(PSI_TYPE, [
- ifdef(AC_TYPE_[]patsubst(translit($1,a-z,A-Z),\W,_),AC_TYPE_[]patsubst(translit($1,a-z,A-Z),\W,_))
- AC_CHECK_SIZEOF($1, [], PSI_INCLUDES_DEFAULT($3))
- if test "$2" && test "$ac_cv_sizeof_[]$1" -gt 0; then
- PSI_TYPES="{`psi_type_pair $2 $ac_cv_sizeof_[]$1`, \""$1"\"}, $PSI_TYPES"
- fi
- ])
-
-
- PSI_CONSTS=""
- dnl PSI_COMPUTE_STR(variable, string or expression, includes)
- AC_DEFUN(PSI_COMPUTE_STR, [
- AC_TRY_RUN([
- $3
- int main() {
- return EOF == fputs($2, fopen("conftest.out", "w"));
- }
- ], [
- eval $1=\\\"`cat conftest.out`\\\"
- ])
- ])
-
- dnl PSI_CONST(const name, type, headers to include)
- AC_DEFUN(PSI_CONST, [
- AC_CACHE_CHECK(value of $1, psi_cv_const_$1, [
- psi_const_val=
- case $2 in
- str*|quoted_str*)
- if test "$cross_compiling" = "yes"
- then
- AC_TRY_CPP(PSI_INCLUDES_DEFAULT($3)$1, psi_const_val=`eval "$ac_try|tail -n1"`, psi_const_val=)
- else
- PSI_COMPUTE_STR(psi_const_val, $1, PSI_INCLUDES_DEFAULT($3))
- fi
- ;;
- *)
- AC_COMPUTE_INT(psi_const_val, $1, PSI_INCLUDES_DEFAULT($3))
- ;;
- esac
- psi_cv_const_$1=$psi_const_val
- ])
- if test "$psi_cv_const_$1"
- then
- case $2 in
- str*|quoted_str*)
- PSI_CONSTS="{PSI_T_STRING, \"string\", \"$1\", $psi_cv_const_$1, PSI_T_QUOTED_STRING}, $PSI_CONSTS"
- ;;
- *)
- PSI_CONSTS="{PSI_T_INT, \"int\", \"$1\", \"$psi_cv_const_$1\", PSI_T_NUMBER}, $PSI_CONSTS"
- ;;
- esac
- fi
- ])
-
- AC_DEFUN([AX_CHECK_SIGN], [
- typename=`echo $1 | sed "s/@<:@^a-zA-Z0-9_@:>@/_/g"`
- AC_CACHE_CHECK([whether $1 is signed], ax_cv_decl_${typename}_signed, [
- AC_TRY_COMPILE([$4],
- [ int foo @<:@ 1 - 2 * !((($1) -1) < 0) @:>@ ],
- [ eval "ax_cv_decl_${typename}_signed=\"yes\"" ],
- [ eval "ax_cv_decl_${typename}_signed=\"no\"" ])])
- symbolname=`echo $1 | sed "s/@<:@^a-zA-Z0-9_@:>@/_/g" | tr "a-z" "A-Z"`
- if eval "test \"\${ax_cv_decl_${typename}_signed}\" = \"yes\""; then
- $2
- elif eval "test \"\${ax_cv_decl_${typename}_signed}\" = \"no\""; then
- $3
- fi
- ])
- dnl PSI_CHECK_OFFSETOF(struct, member, include)
- dnl[AS_LITERAL_IF([$1], [], [m4_fatal([$0: requires literal arguments])])]dnl
- dnl[AS_LITERAL_IF([$2], [], [m4_fatal([$0: requires literal arguments])])]dnl
- AC_DEFUN(PSI_CHECK_OFFSETOF, [
- _AC_CACHE_CHECK_INT(
- [offset of $2 in $1],
- [AS_TR_SH([ac_cv_offsetof_$1_$2])],
- [(long int) (offsetof ($1, $2))],
- [AC_INCLUDES_DEFAULT([$3])],
- [AC_MSG_FAILURE([cannot compute offsetof ($1, $2)])]
- )
- AC_DEFINE_UNQUOTED(
- AS_TR_CPP(offsetof_$1_$2),
- $AS_TR_SH([ac_cv_offsetof_$1_$2]),
- [The offset of `$1' in `$2', as computed by offsetof.]
- )
- ])
-
- dnl PSI_STRUCT(name, members, member type cases, includes)
- PSI_STRUCTS=
- AC_DEFUN(PSI_STRUCT, [
- psi_struct_members=
- m4_foreach(member, [$2], [
- AC_CHECK_MEMBER(struct $1.member, [
- case member in
- $3
- *) psi_member_type=int ;;
- esac
- AC_CHECK_SIZEOF(struct_$1[_]member, [], PSI_INCLUDES_DEFAULT($4,
- [#define struct_$1_]member ((struct $1 *)0)->member
- ))
- PSI_CHECK_OFFSETOF(struct $1, member, PSI_INCLUDES_DEFAULT($4))
- # pointer level
- psi_struct_member_pl=`echo $psi_member_type | tr -cd '*' | wc -c`
- # array size
- psi_struct_member_as=`echo $psi_member_type | $AWK -F'\x5b\x5d\x5b\x5d' 'END {print 0} /\\x5b\x5b\x5b:digit:\x5d\x5d+\\x5d/ {print$[]2; exit}'`
- if test $psi_struct_member_as -gt 0
- then
- psi_struct_member_pl=`expr $psi_struct_member_pl + 1`
- fi
- psi_struct_members="{`psi_type_pair $psi_member_type $ac_cv_sizeof_struct_$1[]_[]member`, \"[]member[]\", $ac_cv_offsetof_struct_$1[]_[]member, $ac_cv_sizeof_struct_$1[]_[]member, $psi_struct_member_pl, $psi_struct_member_as}, $psi_struct_members"
- ], [], PSI_INCLUDES_DEFAULT($4))
- ])
- PSI_STRUCTS="{\"$1\", {$psi_struct_members}}, $PSI_STRUCTS"
- ])
-
- AC_TYPE_INT8_T
- AC_CHECK_ALIGNOF(int8_t)
- AC_TYPE_UINT8_T
- AC_CHECK_ALIGNOF(uint8_t)
- AC_TYPE_INT16_T
- AC_CHECK_ALIGNOF(int16_t)
- AC_TYPE_UINT16_T
- AC_CHECK_ALIGNOF(uint16_t)
- AC_TYPE_INT32_T
- AC_CHECK_ALIGNOF(int32_t)
- AC_TYPE_UINT32_T
- AC_CHECK_ALIGNOF(uint32_t)
- AC_TYPE_INT64_T
- AC_CHECK_ALIGNOF(int64_t)
- AC_TYPE_UINT64_T
- AC_CHECK_ALIGNOF(uint64_t)
-
- PSI_TYPE(char, int)
- PSI_TYPE(short, int)
- PSI_TYPE(int, int)
- PSI_TYPE(long, int)
- PSI_TYPE(float)
- PSI_TYPE(double)
- PSI_TYPE(void *)