+AC_C_INLINE
+AC_C_VOLATILE
+AC_C_RESTRICT
+
+AX_CXX_GCC_ABI_DEMANGLE
+
+AX_LIBEVENT
+
+AC_CHECK_LIB([rt],[clock_gettime],
+ [AC_SUBST([RT_LIB],[-lrt])
+ AC_DEFINE([HAVE_CLOCK_GETTIME],[1],[Have clock_gettime])],
+ [AC_DEFINE([HAVE_CLOCK_GETTIME],[0],[Have clock_gettime])])
+
+
+# Check for the ability to call dlopen (used in libhostile)
+AX_DLOPEN
+
+AC_CHECK_HEADERS([atomic.h])
+AS_IF([test "x$ac_cv_header_atomic_h" = "xyes"],
+ [AC_CHECK_FUNCS([atomic_add_64])
+ AC_CHECK_FUNCS([atomic_add_32])
+ AS_IF([test "x$ac_cv_func_atomic_add_64" = "xyes" -a "x$ac_cv_func_atomic_add_32" = "xyes"],
+ [AC_DEFINE([USE_ATOMIC_H],[1],[Define to true if you want to use functions from atomic.h])])])
+
+AC_DEFINE([HAVE_LIBDRIZZLE],[0],[Support for libdrizzle])
+AC_DEFINE([HAVE_DRIZZLED_BINARY],[0],[Support for DrizzleD])
+AC_DEFINE([DRIZZLED_BINARY],[0],[Support for DrizzleD])
+AC_DEFINE([GEARMAND_BLOBSLAP_WORKER],[0],[Support for Gearman Blobslap worker])
+AC_DEFINE([HAVE_LIBPQ],[0],[Support for Postgres])
+AC_DEFINE([HAVE_LIBCURL],[0],[Support for libcurl])
+
+# Check for the requirements for running memcached with less privileges
+# than the default privilege set. On Solaris we need setppriv and priv.h
+# If you want to add support for other platforms you should check for
+# your requirements, define HAVE_DROP_PRIVILEGES, and make sure you add
+# the source file containing the implementation into memcached_SOURCE
+# in Makefile.am
+AC_CHECK_FUNCS([setppriv],
+ [AC_CHECK_HEADER([priv.h],
+ [AC_DEFINE([HAVE_DROP_PRIVILEGES],
+ [1],
+ [Define this if you have an implementation of drop_privileges()])
+ build_solaris_privs=yes])
+ ])
+
+AM_CONDITIONAL([BUILD_POLL],[test "x$ac_cv_header_poll_h" = "xno"])
+AM_CONDITIONAL([BUILD_WIN32_WRAPPERS],[test "x$ac_cv_header_winsock2_h" = "xyes"])
+AS_IF([test "x$ac_cv_header_winsock2_h" = "xyes"],
+ [AM_LDFLAGS="$AM_LDFLAGS -lws2_32"
+ AM_CFLAGS="$AM_CFLAGS $NO_WERROR"
+ AM_CXXFLAGS="$AM_CXXFLAGS $NO_WERROR"
+ ])
+SOCKET_SEND_FLAGS
+
+AX_UUID_GENERATE_TIME_SAFE
+
+AC_DEFUN([CHECK_FOR_PTHREAD_AND_SASL],
+ [AX_PTHREAD(, [AC_MSG_ERROR([could not find libpthread])])
+ AX_PTHREAD_TIMEDJOIN_NP
+
+ # The sasl functions should only be visible if we build with sasl support
+ #
+ AX_SASL_OPTION
+ AS_IF([test "x$ac_enable_sasl" = xyes],
+ [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 1"],
+ [LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 0"])
+ AC_SUBST([LIBMEMCACHED_WITH_SASL_SUPPORT])
+ ])
+CHECK_FOR_PTHREAD_AND_SASL
+
+# backtrace(), others require shared builds
+AC_DEFUN([__ENABLE_SHARED],
+ [AC_REQUIRE([AX_PLATFORM])
+ AS_IF([test "x${TARGET_WINDOWS}" = "xtrue"],[enable_shared=no])
+ AS_IF([test "x$enable_shared" = "xyes"],
+ [AC_DEFINE([HAVE_SHARED_ENABLED],[1],[Enable code which requires shared library support. Like backtrace().])])])
+AM_CONDITIONAL([SHARED_ENABLED],[test "x$enable_shared" = "xyes"])
+
+PANDORA_ENABLE_DTRACE
+HAVE_GCC_ATOMICS
+AX_ENDIAN
+AX_ASSERT
+AX_HARDEN_COMPILER_FLAGS
+
+AX_AM_JOBSERVER([yes])
+
+AC_CONFIG_FILES([Makefile
+ docs/conf.py
+ libmemcached-1.0/configure.h
+ support/libmemcached.pc
+ support/libmemcached.spec
+ ])
+AC_OUTPUT
+
+echo "---"
+echo "Configuration summary for $PACKAGE_NAME version $VERSION"
+echo ""
+echo " * Installation prefix: $prefix"
+echo " * System type: $host_vendor-$host_os"
+echo " * Host CPU: $host_cpu"
+echo " * C Compiler: $CC_VERSION"
+echo " * C Flags: $CFLAGS"
+echo " * C++ Compiler: $CXX_VERSION"
+echo " * C++ Flags: $CXXFLAGS"
+echo " * CPP Flags: $CPPFLAGS"
+echo " * LIB Flags: $LIB"
+echo " * Assertions enabled: $ax_enable_assert"
+echo " * Debug enabled: $ax_enable_debug"
+echo " * Shared: $enable_shared"
+echo " * Warnings as failure: $ac_cv_warnings_as_errors"
+echo " * SASL support: $ac_enable_sasl"
+echo " * make -j: $enable_jobserver"
+echo " * VCS checkout: $ac_cv_vcs_checkout"
+echo ""
+echo "---"
+
+case "$host_os" in
+ *freebsd*)
+ echo "*****"
+ echo "*"
+ echo "* NOTE: You are on FreeBSD. BSD make will not work."
+ echo "*"
+ echo "* use 'gmake' To build libmemcached"
+ echo "*"
+ echo "*****"
+ ;;
+esac
+