+AC_C_INLINE
+AC_C_VOLATILE
+AC_C_RESTRICT
+
+AX_CXX_GCC_ABI_DEMANGLE
+
+AX_SASL_OPTION
+
+dnl
+dnl The sasl functions should only be visible if we build with sasl support
+dnl
+AS_IF([test "x$ac_enable_sasl" = "xyes"], [
+ [ LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 1" ]
+ ], [
+ [ LIBMEMCACHED_WITH_SASL_SUPPORT="#define LIBMEMCACHED_WITH_SASL_SUPPORT 0" ]
+ ])
+AC_SUBST(LIBMEMCACHED_WITH_SASL_SUPPORT)
+
+AX_CHECK_LIBRARY([LIBUUID], [uuid/uuid.h], [uuid],
+ [
+ LIBUUID_LDFLAGS="-luuid"
+ AC_DEFINE([HAVE_LIBUUID], [ 1 ], [Have libuuid])
+ ],
+ [
+ AC_DEFINE([HAVE_LIBUUID], [ 0 ], [Have libuuid])
+ ])
+
+AC_CHECK_LIB([rt], [clock_gettime],
+ [
+ RT_LIB="-lrt"
+ AC_SUBST(RT_LIB)
+ AC_DEFINE([HAVE_LIBRT], [ 1 ], [Have clock_gettime])
+ ],
+ [
+ AC_DEFINE([HAVE_LIBRT], [ 0 ], [Have clock_gettime])
+ ])
+
+AC_CHECK_LIB([m], [floor])
+AC_CHECK_FUNCS([sigignore])
+
+AC_CHECK_HEADERS([atomic.h])
+AS_IF([test "x$ac_cv_header_atomic_h" = "xyes"],[
+ AC_CHECK_FUNCS(atomic_add_64)
+ AC_CHECK_FUNCS(atomic_add_32)
+ AS_IF([test "x$ac_cv_func_atomic_add_64" = "xyes" -a "x$ac_cv_func_atomic_add_32" = "xyes"],[
+ AC_DEFINE([USE_ATOMIC_H],
+ [1],
+ [Define to true if you want to use functions from atomic.h])])])
+
+AC_DEFINE([HAVE_LIBDRIZZLE], [0], [Support for libdrizzle])
+AC_DEFINE([HAVE_DRIZZLED_BINARY], [0], [Support for DrizzleD])
+AC_DEFINE([GEARMAND_BLOBSLAP_WORKER], [0], [Support for Gearman Blobslap worker])
+AC_DEFINE([HAVE_LIBPQ], [0], [Support for Postgres])
+AC_DEFINE([HAVE_LIBCURL], [0], [Support for libcurl])
+
+AC_DEFINE([HAVE_MEMCACHED_LIGHT_BINARY], [1], [Support for memcached_light])
+AC_DEFINE([MEMCACHED_LIGHT_BINARY], ["example/memcached_light"], [Support for memcached_light])
+
+dnl Check for the requirements for running memcached with less privileges
+dnl than the default privilege set. On Solaris we need setppriv and priv.h
+dnl If you want to add support for other platforms you should check for
+dnl your requirements, define HAVE_DROP_PRIVILEGES, and make sure you add
+dnl the source file containing the implementation into memcached_SOURCE
+dnl in Makefile.am
+AC_CHECK_FUNCS(setppriv, [
+ AC_CHECK_HEADER(priv.h, [
+ AC_DEFINE([HAVE_DROP_PRIVILEGES], 1,
+ [Define this if you have an implementation of drop_privileges()])
+ build_solaris_privs=yes
+ ], [])
+],[])
+
+AC_CHECK_HEADERS_ONCE(winsock2.h poll.h sys/wait.h fnmatch.h)
+AM_CONDITIONAL(BUILD_POLL, test "x$ac_cv_header_poll_h" = "xno")
+AM_CONDITIONAL(BUILD_WIN32_WRAPPERS, test "x$ac_cv_header_winsock2_h" = "xyes")
+AS_IF(test "x$ac_cv_header_winsock2_h" = "xyes",
+ [AM_LDFLAGS="$AM_LDFLAGS -lws2_32"
+ AM_CFLAGS="$AM_CFLAGS $NO_WERROR"
+ AM_CXXFLAGS="$AM_CXXFLAGS $NO_WERROR"
+ ])
+SOCKET_SEND_FLAGS
+
+AX_CHECK_LIBRARY([LIBEVENT], [event.h], [event],
+ [
+ LIBEVENT_LDFLAGS="-levent"
+ ],
+ [
+ AC_MSG_WARN([Unable to find libevent])
+ ])
+AM_CONDITIONAL(HAVE_LIBEVENT, test "x${ax_cv_have_LIBEVENT}" = "xyes")
+
+dnl Check if we're a little-endian or a big-endian system, needed by hash code
+AC_DEFUN([AC_C_ENDIAN],
+[AC_CACHE_CHECK(for endianness, ac_cv_c_endian,
+[
+ AC_RUN_IFELSE(
+ [AC_LANG_PROGRAM([], [dnl
+ long val = 1;
+ char *c = (char *) &val;
+ exit(*c == 1);
+ ])
+ ],[
+ ac_cv_c_endian=big
+ ],[
+ ac_cv_c_endian=little
+ ])
+])
+if test $ac_cv_c_endian = big; then
+ AC_DEFINE(ENDIAN_BIG, 1, [machine is bigendian])
+fi
+if test $ac_cv_c_endian = little; then
+ AC_DEFINE(ENDIAN_LITTLE, 1, [machine is littleendian])
+fi
+])
+
+AC_C_ENDIAN
+
+AC_CONFIG_FILES([
+ Makefile
+ docs/conf.py
+ libhashkit-1.0/configure.h
+ libmemcached-1.0/configure.h
+ libmemcached-1.2/configure.h
+ libmemcached-2.0/configure.h
+ support/libmemcached.pc
+ support/libmemcached.spec
+ support/libmemcached-fc.spec
+ libtest/version.h
+ ])
+AC_OUTPUT
+
+echo "---"
+echo "Configuration summary for $PACKAGE_NAME version $VERSION"
+echo ""
+echo " * Installation prefix: $prefix"
+echo " * System type: $host_vendor-$host_os"
+echo " * Host CPU: $host_cpu"
+echo " * C Compiler: $CC_VERSION"
+echo " * Assertions enabled: $ac_cv_assert"
+echo " * Debug enabled: $with_debug"
+echo " * Warnings as failure: $ac_cv_warnings_as_errors"
+echo " * SASL support: $ac_enable_sasl"
+echo ""
+echo "---"
+
+case "$host_os" in
+ *freebsd*)
+ echo "*****"
+ echo "*"
+ echo "* NOTE: You are on FreeBSD. BSD make will not work."
+ echo "*"
+ echo "* use 'gmake' To build libmemcached"
+ echo "*"
+ echo "*****"
+ ;;
+esac
+