git.m6w6.name Git - m6w6/libmemcached/blob - src/libmemcached/CMakeLists.txt

   1
   2 find_package(FLEX)
   3 find_package(BISON 2.3)
   4
   5 if(${BISON_VERSION} VERSION_GREATER_EQUAL 3.0)
   6         set(BISON_WARNINGS -Wno-deprecated)
   7 endif()
   8
   9 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/csl)
  10 bison_target(CSL_PARSER csl/parser.yy ${CMAKE_CURRENT_BINARY_DIR}/csl/parser.cc
  11         DEFINES_FILE ${CMAKE_CURRENT_BINARY_DIR}/csl/parser.h
  12         COMPILE_FLAGS ${BISON_WARNINGS}
  13         )
  14 set_source_files_properties(${BISON_CSL_PARSER_OUTPUTS} PROPERTIES SKIP_UNITY_BUILD_INCLUSION ON)
  15 flex_target(CSL_SCANNER csl/scanner.l ${CMAKE_CURRENT_BINARY_DIR}/csl/scanner.cc
  16         DEFINES_FILE ${CMAKE_CURRENT_BINARY_DIR}/csl/scanner.h
  17         )
  18 set_source_files_properties(${FLEX_CSL_SCANNER_OUTPUTS} PROPERTIES SKIP_UNITY_BUILD_INCLUSION ON)
  19 add_flex_bison_dependency(CSL_SCANNER CSL_PARSER)
  20
  21 if(HAVE_DTRACE)
  22         add_custom_command(
  23                 OUTPUT dtrace_probes.h
  24                 COMMAND ${DTRACE_EXECUTABLE}
  25                 ARGS -h -o dtrace_probes.h -s ${CMAKE_CURRENT_SOURCE_DIR}/libmemcached_probes.d
  26                 MAIN_DEPENDENCY libmemcached_probes.d
  27         )
  28         add_custom_command(
  29                 OUTPUT libmemcached_probes.o
  30                 COMMAND ${DTRACE_EXECUTABLE}
  31                 ARGS -o libmemcached_probes.o -G -s ${CMAKE_CURRENT_SOURCE_DIR}/libmemcached_probes.d
  32                 MAIN_DEPENDENCY dtrace_probes.h
  33         )
  34         set(DTRACE_GENERATED_OUTPUT libmemcached_probes.o)
  35 endif()
  36
  37 set(LIBMEMCACHED_SOURCES
  38         csl/context.cc
  39         ${BISON_CSL_PARSER_OUTPUTS}
  40         ${FLEX_CSL_SCANNER_OUTPUTS}
  41         ${DTRACE_GENERATED_OUTPUT}
  42         allocators.cc
  43         analyze.cc
  44         array.c
  45         auto.cc
  46         backtrace.cc
  47         behavior.cc
  48         byteorder.cc
  49         callback.cc
  50         common.h
  51         connect.cc
  52         delete.cc
  53         do.cc
  54         dump.cc
  55         encoding_key.cc
  56         error.cc
  57         exist.cc
  58         fetch.cc
  59         flag.cc
  60         flush.cc
  61         flush_buffers.cc
  62         get.cc
  63         hash.cc
  64         hosts.cc
  65         initialize_query.cc
  66         instance.cc
  67         io.cc
  68         key.cc
  69         memcached.cc
  70         namespace.cc
  71         options.cc
  72         parse.cc
  73         poll.cc
  74         purge.cc
  75         quit.cc
  76         response.cc
  77         result.cc
  78         sasl.cc
  79         server.cc
  80         server_list.cc
  81         stats.cc
  82         storage.cc
  83         strerror.cc
  84         string.cc
  85         touch.cc
  86         udp.cc
  87         verbosity.cc
  88         version.cc
  89         virtual_bucket.c)
  90
  91 add_library(libmemcached SHARED
  92         ${LIBMEMCACHED_SOURCES})
  93 add_library(memcached ALIAS libmemcached)
  94 set_target_properties(libmemcached PROPERTIES
  95         LIBRARY_OUTPUT_NAME memcached
  96         LIBRARY_OUTPUT_NAME_DEBUG memcached-dbg
  97         SOVERSION ${LIBMEMCACHED_SO_VERSION}
  98         VERSION v${LIBMEMCACHED_VERSION})
  99 target_compile_definitions(libmemcached PRIVATE -DBUILDING_LIBMEMCACHED)
 100 target_link_libraries(libmemcached PUBLIC libhashkit Threads::Threads ${LIBSASL_LIBRARIES} ${CMAKE_DL_LIBS})
 101 target_include_directories(libmemcached PRIVATE ${LIBSASL_INCLUDEDIR})
 102 target_include_directories(libmemcached PRIVATE
 103         ${CMAKE_SOURCE_DIR}/src
 104         ${CMAKE_BINARY_DIR}/src
 105         ${CMAKE_BINARY_DIR})
 106 target_include_directories(libmemcached PUBLIC
 107         $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/include>
 108         $<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/include>
 109         $<INSTALL_INTERFACE:include>)
 110
 111 install(TARGETS libmemcached EXPORT libmemcached-targets
 112         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
 113 export(EXPORT libmemcached-targets NAMESPACE libmemcached::)
 114 install(EXPORT libmemcached-targets NAMESPACE libmemcached:: DESTINATION ${CMAKE_INSTALL_DATADIR}/${PROJECT_NAME}/cmake)
 115
 116 install_public_headers(
 117         libmemcached
 118
 119         memcached.h
 120         memcached.hpp
 121         util.h
 122         )
 123
 124 add_library(libmemcachedinternal STATIC
 125         ${LIBMEMCACHED_SOURCES})
 126 add_library(memcachedinternal ALIAS libmemcachedinternal)
 127 set_target_properties(libmemcachedinternal PROPERTIES LIBRARY_OUTPUT_NAME memcachedinternal)
 128 target_compile_definitions(libmemcachedinternal PRIVATE -DBUILDING_LIBMEMCACHEDINTERNAL)
 129 target_link_libraries(libmemcachedinternal PUBLIC libhashkit Threads::Threads ${LIBSASL_LIBRARIES} ${CMAKE_DL_LIBS})
 130 target_include_directories(libmemcachedinternal PRIVATE ${LIBSASL_INCLUDEDIR})
 131 target_include_directories(libmemcachedinternal PRIVATE
 132         ${CMAKE_SOURCE_DIR}/src
 133         ${CMAKE_BINARY_DIR}/src
 134         ${CMAKE_BINARY_DIR})
 135 target_include_directories(libmemcachedinternal PUBLIC
 136         $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/include>
 137         $<BUILD_INTERFACE:${CMAKE_BINARY_DIR}/include>
 138         $<INSTALL_INTERFACE:include>)
 139
 140 # let libmemcached depend on libmemcachedinternal to ensure that they do not
 141 # compete for the same generated dependencies
 142 add_dependencies(libmemcached libmemcachedinternal)