git.m6w6.name Git - m6w6/libmemcached/blob - m4/pandora_warnings.m4

   1 dnl  Copyright (C) 2009 Sun Microsystems
   2 dnl This file is free software; Sun Microsystems
   3 dnl gives unlimited permission to copy and/or distribute it,
   4 dnl with or without modifications, as long as this notice is preserved.
   5
   6 dnl AC_PANDORA_WARNINGS([less-warnings|warnings-always-on])
   7 dnl   less-warnings turn on a limited set of warnings
   8 dnl   warnings-always-on always set warnings=error regardless of tarball/vc
   9
  10 dnl @TODO: remove less-warnings option as soon as Drizzle is clean enough to
  11 dnl        allow it
  12
  13 AC_DEFUN([PANDORA_WARNINGS],[
  14   m4_define([PW_LESS_WARNINGS],[no])
  15   m4_define([PW_WARN_ALWAYS_ON],[no])
  16   m4_foreach_w([pw_arg],$@,[
  17     m4_case(pw_arg,
  18       [less-warnings],[
  19         m4_undefine([PW_LESS_WARNINGS])
  20         m4_define([PW_LESS_WARNINGS],[yes])
  21       ],
  22       [warnings-always-on],[
  23         m4_undefine([PW_WARN_ALWAYS_ON])
  24         m4_define([PW_WARN_ALWAYS_ON],[yes])
  25     ])
  26   ])
  27
  28   AC_REQUIRE([PANDORA_BUILDING_FROM_VC])
  29   m4_if(PW_WARN_ALWAYS_ON, [yes],
  30     [ac_cv_warnings_as_errors=yes],
  31     AS_IF([test "$ac_cv_building_from_vc" = "yes"],
  32           [ac_cv_warnings_as_errors=yes],
  33           [ac_cv_warnings_as_errors=no]))
  34
  35   AC_ARG_ENABLE([profiling],
  36       [AS_HELP_STRING([--enable-profiling],
  37          [Toggle profiling @<:@default=off@:>@])],
  38       [ac_profiling="$enableval"],
  39       [ac_profiling="no"])
  40
  41   AC_ARG_ENABLE([coverage],
  42       [AS_HELP_STRING([--enable-coverage],
  43          [Toggle coverage @<:@default=off@:>@])],
  44       [ac_coverage="$enableval"],
  45       [ac_coverage="no"])
  46
  47   AS_IF([test "$GCC" = "yes"],[
  48
  49     AS_IF([test "$ac_profiling" = "yes"],[
  50       CC_PROFILING="-pg"
  51       save_LIBS="${LIBS}"
  52       LIBS=""
  53       AC_CHECK_LIB(c_p, read)
  54       LIBC_P="${LIBS}"
  55       LIBS="${save_LIBS}"
  56       AC_SUBST(LIBC_P)
  57     ],[
  58       CC_PROFILING=" "
  59     ])
  60
  61     AS_IF([test "$ac_coverage" = "yes"],
  62           [CC_COVERAGE="-fprofile-arcs -ftest-coverage"])
  63
  64     AS_IF([test "$ac_cv_warnings_as_errors" = "yes"],
  65           [W_FAIL="-Werror"])
  66
  67     AC_CACHE_CHECK([whether it is safe to use -fdiagnostics-show-option],
  68       [ac_cv_safe_to_use_fdiagnostics_show_option_],
  69       [save_CFLAGS="$CFLAGS"
  70        CFLAGS="-fdiagnostics-show-option ${AM_CFLAGS}"
  71        AC_COMPILE_IFELSE(
  72          [AC_LANG_PROGRAM([],[])],
  73          [ac_cv_safe_to_use_fdiagnostics_show_option_=yes],
  74          [ac_cv_safe_to_use_fdiagnostics_show_option_=no])
  75        CFLAGS="$save_CFLAGS"])
  76
  77     AS_IF([test "$ac_cv_safe_to_use_fdiagnostics_show_option_" = "yes"],
  78           [
  79             F_DIAGNOSTICS_SHOW_OPTION="-fdiagnostics-show-option"
  80           ])
  81
  82     AC_CACHE_CHECK([whether it is safe to use -Wconversion],
  83       [ac_cv_safe_to_use_wconversion_],
  84       [save_CFLAGS="$CFLAGS"
  85        dnl Use -Werror here instead of ${W_FAIL} so that we don't spew
  86        dnl conversion warnings to all the tarball folks
  87        CFLAGS="-Wconversion -Werror -pedantic ${AM_CFLAGS}"
  88        AC_COMPILE_IFELSE(
  89          [AC_LANG_PROGRAM([[
  90 #include <stdbool.h>
  91 void foo(bool a)
  92 {
  93   (void)a;
  94 }
  95          ]],[[
  96 foo(0);
  97          ]])],
  98          [ac_cv_safe_to_use_wconversion_=yes],
  99          [ac_cv_safe_to_use_wconversion_=no])
 100        CFLAGS="$save_CFLAGS"])
 101
 102     AS_IF([test "$ac_cv_safe_to_use_wconversion_" = "yes"],
 103       [W_CONVERSION="-Wconversion"
 104       AC_CACHE_CHECK([whether it is safe to use -Wconversion with htons],
 105         [ac_cv_safe_to_use_Wconversion_],
 106         [save_CFLAGS="$CFLAGS"
 107          dnl Use -Werror here instead of ${W_FAIL} so that we don't spew
 108          dnl conversion warnings to all the tarball folks
 109          CFLAGS="-Wconversion -Werror -pedantic ${AM_CFLAGS}"
 110          AC_COMPILE_IFELSE(
 111            [AC_LANG_PROGRAM(
 112              [[
 113 #include <netinet/in.h>
 114              ]],[[
 115 uint16_t x= htons(80);
 116              ]])],
 117            [ac_cv_safe_to_use_Wconversion_=yes],
 118            [ac_cv_safe_to_use_Wconversion_=no])
 119          CFLAGS="$save_CFLAGS"])
 120
 121       AS_IF([test "$ac_cv_safe_to_use_Wconversion_" = "no"],
 122             [NO_CONVERSION="-Wno-conversion"])
 123     ])
 124
 125     NO_STRICT_ALIASING="-fno-strict-aliasing -Wno-strict-aliasing"
 126     NO_SHADOW="-Wno-shadow"
 127
 128     m4_if(PW_LESS_WARNINGS,[no],[
 129       BASE_WARNINGS_FULL="-Wformat=2 ${W_CONVERSION} -Wstrict-aliasing"
 130       CC_WARNINGS_FULL="-Wswitch-default -Wswitch-enum"
 131       CXX_WARNINGS_FULL="-Weffc++ -Wold-style-cast"
 132     ],[
 133       BASE_WARNINGS_FULL="-Wformat ${NO_STRICT_ALIASING}"
 134     ])
 135
 136     BASE_WARNINGS="${W_FAIL} -pedantic -Wall -Wextra -Wundef -Wshadow -Wstrict-aliasing ${F_DIAGNOSTICS_SHOW_OPTION} ${CFLAG_VISIBILITY} ${BASE_WARNINGS_FULL}"
 137     CC_WARNINGS="${BASE_WARNINGS} -Wstrict-prototypes -Wmissing-prototypes -Wredundant-decls -Wmissing-declarations -Wcast-align ${CC_WARNINGS_FULL}"
 138     CXX_WARNINGS="${BASE_WARNINGS} -Woverloaded-virtual -Wnon-virtual-dtor -Wctor-dtor-privacy -Wno-long-long ${CXX_WARNINGS_FULL}"
 139
 140     AC_CACHE_CHECK([whether it is safe to use -Wmissing-declarations from C++],
 141       [ac_cv_safe_to_use_Wmissing_declarations_],
 142       [AC_LANG_PUSH(C++)
 143        save_CXXFLAGS="$CXXFLAGS"
 144        CXXFLAGS="-Werror -pedantic -Wmissing-declarations ${AM_CXXFLAGS}"
 145        AC_COMPILE_IFELSE([
 146          AC_LANG_PROGRAM(
 147          [[
 148 #include <stdio.h>
 149          ]], [[]])
 150       ],
 151       [ac_cv_safe_to_use_Wmissing_declarations_=yes],
 152       [ac_cv_safe_to_use_Wmissing_declarations_=no])
 153       CXXFLAGS="$save_CXXFLAGS"
 154       AC_LANG_POP()
 155     ])
 156     AS_IF([test "$ac_cv_safe_to_use_Wmissing_declarations_" = "yes"],
 157           [CXX_WARNINGS="${CXX_WARNINGS} -Wmissing-declarations"])
 158
 159     AC_CACHE_CHECK([whether it is safe to use -Wlogical-op],
 160       [ac_cv_safe_to_use_Wlogical_op_],
 161       [save_CFLAGS="$CFLAGS"
 162        CFLAGS="${W_FAIL} -pedantic -Wlogical-op ${AM_CFLAGS}"
 163        AC_COMPILE_IFELSE([
 164          AC_LANG_PROGRAM(
 165          [[
 166 #include <stdio.h>
 167          ]], [[]])
 168       ],
 169       [ac_cv_safe_to_use_Wlogical_op_=yes],
 170       [ac_cv_safe_to_use_Wlogical_op_=no])
 171     CFLAGS="$save_CFLAGS"])
 172     AS_IF([test "$ac_cv_safe_to_use_Wlogical_op_" = "yes"],
 173           [CC_WARNINGS="${CC_WARNINGS} -Wlogical-op"])
 174
 175     AC_CACHE_CHECK([whether it is safe to use -Wredundant-decls from C++],
 176       [ac_cv_safe_to_use_Wredundant_decls_],
 177       [AC_LANG_PUSH(C++)
 178        save_CXXFLAGS="${CXXFLAGS}"
 179        CXXFLAGS="${W_FAIL} -pedantic -Wredundant-decls ${AM_CXXFLAGS}"
 180        AC_COMPILE_IFELSE(
 181          [AC_LANG_PROGRAM([
 182 template <typename E> struct C { void foo(); };
 183 template <typename E> void C<E>::foo() { }
 184 template <> void C<int>::foo();
 185           AC_INCLUDES_DEFAULT])],
 186           [ac_cv_safe_to_use_Wredundant_decls_=yes],
 187           [ac_cv_safe_to_use_Wredundant_decls_=no])
 188         CXXFLAGS="${save_CXXFLAGS}"
 189         AC_LANG_POP()])
 190     AS_IF([test "$ac_cv_safe_to_use_Wredundant_decls_" = "yes"],
 191           [CXX_WARNINGS="${CXX_WARNINGS} -Wredundant-decls"],
 192           [CXX_WARNINGS="${CXX_WARNINGS} -Wno-redundant-decls"])
 193
 194     NO_REDUNDANT_DECLS="-Wno-redundant-decls"
 195     PROTOSKIP_WARNINGS="-Wno-effc++ -Wno-shadow"
 196
 197   ])
 198
 199   AS_IF([test "$SUNCC" = "yes"],[
 200
 201     AS_IF([test "$ac_profiling" = "yes"],
 202           [CC_PROFILING="-xinstrument=datarace"])
 203
 204     AS_IF([test "$ac_cv_warnings_as_errors" = "yes"],
 205           [W_FAIL="-errwarn=%all"])
 206
 207     AC_CACHE_CHECK([whether E_PASTE_RESULT_NOT_TOKEN is usable],
 208       [ac_cv_paste_result],
 209       [
 210         save_CFLAGS="${CFLAGS}"
 211         CFLAGS="-errwarn=%all -erroff=E_PASTE_RESULT_NOT_TOKEN ${CFLAGS}"
 212         AC_COMPILE_IFELSE(
 213           [AC_LANG_PROGRAM([
 214             AC_INCLUDES_DEFAULT
 215           ],[
 216             int x= 0;])],
 217           [ac_cv_paste_result=yes],
 218           [ac_cv_paste_result=no])
 219         CFLAGS="${save_CFLAGS}"
 220       ])
 221     AS_IF([test $ac_cv_paste_result = yes],
 222       [W_PASTE_RESULT=",E_PASTE_RESULT_NOT_TOKEN"])
 223
 224
 225     m4_if(PW_LESS_WARNINGS, [no],[
 226       CC_WARNINGS_FULL="-erroff=E_INTEGER_OVERFLOW_DETECTED${W_PASTE_RESULT}"
 227     ],[
 228       CC_WARNINGS_FULL="-erroff=E_ATTRIBUTE_NOT_VAR"
 229       CXX_WARNINGS_FULL="-erroff=attrskipunsup,doubunder,reftotemp,inllargeuse,truncwarn1,signextwarn,inllargeint"
 230     ])
 231
 232     CC_WARNINGS="-v -errtags=yes ${W_FAIL} ${CC_WARNINGS_FULL}"
 233     CXX_WARNINGS="+w +w2 -xwe -xport64 -errtags=yes ${CXX_WARNINGS_FULL} ${W_FAIL}"
 234     PROTOSKIP_WARNINGS="-erroff=attrskipunsup,doubunder,reftotemp,wbadinitl,identexpected,inllargeuse,truncwarn1,signextwarn"
 235     NO_UNREACHED="-erroff=E_STATEMENT_NOT_REACHED"
 236
 237   ])
 238
 239   AC_SUBST(NO_CONVERSION)
 240   AC_SUBST(NO_REDUNDANT_DECLS)
 241   AC_SUBST(NO_UNREACHED)
 242   AC_SUBST(NO_SHADOW)
 243   AC_SUBST(NO_STRICT_ALIASING)
 244   AC_SUBST(PROTOSKIP_WARNINGS)
 245
 246 ])