git.m6w6.name Git - awesomized/libmemcached/blob - m4/pandora_warnings.m4

   1 dnl  Copyright (C) 2009 Sun Microsystems
   2 dnl This file is free software; Sun Microsystems
   3 dnl gives unlimited permission to copy and/or distribute it,
   4 dnl with or without modifications, as long as this notice is preserved.
   5
   6 dnl AC_PANDORA_WARNINGS([less-warnings|warnings-always-on])
   7 dnl   less-warnings turn on a limited set of warnings
   8 dnl   warnings-always-on always set warnings=error regardless of tarball/vc
   9
  10 dnl @TODO: remove less-warnings option as soon as Drizzle is clean enough to
  11 dnl        allow it
  12
  13 AC_DEFUN([PANDORA_WARNINGS],[
  14   m4_define([PW_LESS_WARNINGS],[no])
  15   m4_define([PW_WARN_ALWAYS_ON],[no])
  16   ifdef([m4_define],,[define([m4_define],   defn([define]))])
  17   ifdef([m4_undefine],,[define([m4_undefine],   defn([undefine]))])
  18   m4_foreach([pw_arg],[$*],[
  19     m4_case(pw_arg,
  20       [less-warnings],[
  21         m4_undefine([PW_LESS_WARNINGS])
  22         m4_define([PW_LESS_WARNINGS],[yes])
  23       ],
  24       [warnings-always-on],[
  25         m4_undefine([PW_WARN_ALWAYS_ON])
  26         m4_define([PW_WARN_ALWAYS_ON],[yes])
  27     ])
  28   ])
  29
  30   AC_REQUIRE([PANDORA_BUILDING_FROM_VC])
  31   m4_if(PW_WARN_ALWAYS_ON, [yes],
  32     [ac_cv_warnings_as_errors=yes],
  33     AS_IF([test "$ac_cv_building_from_vc" = "yes"],
  34           [ac_cv_warnings_as_errors=yes],
  35           [ac_cv_warnings_as_errors=no]))
  36
  37   AC_ARG_ENABLE([profiling],
  38       [AS_HELP_STRING([--enable-profiling],
  39          [Toggle profiling @<:@default=off@:>@])],
  40       [ac_profiling="$enableval"],
  41       [ac_profiling="no"])
  42
  43   AC_ARG_ENABLE([coverage],
  44       [AS_HELP_STRING([--enable-coverage],
  45          [Toggle coverage @<:@default=off@:>@])],
  46       [ac_coverage="$enableval"],
  47       [ac_coverage="no"])
  48
  49   AS_IF([test "$GCC" = "yes"],[
  50
  51     AS_IF([test "$ac_profiling" = "yes"],[
  52       CC_PROFILING="-pg"
  53       save_LIBS="${LIBS}"
  54       LIBS=""
  55       AC_CHECK_LIB(c_p, read)
  56       LIBC_P="${LIBS}"
  57       LIBS="${save_LIBS}"
  58       AC_SUBST(LIBC_P)
  59     ],[
  60       CC_PROFILING=" "
  61     ])
  62
  63     AS_IF([test "$ac_coverage" = "yes"],
  64           [CC_COVERAGE="-fprofile-arcs -ftest-coverage"])
  65
  66     AS_IF([test "$ac_cv_warnings_as_errors" = "yes"],
  67           [W_FAIL="-Werror"])
  68
  69     AC_CACHE_CHECK([whether it is safe to use -fdiagnostics-show-option],
  70       [ac_cv_safe_to_use_fdiagnostics_show_option_],
  71       [save_CFLAGS="$CFLAGS"
  72        CFLAGS="-fdiagnostics-show-option ${AM_CFLAGS} ${CFLAGS}"
  73        AC_COMPILE_IFELSE(
  74          [AC_LANG_PROGRAM([],[])],
  75          [ac_cv_safe_to_use_fdiagnostics_show_option_=yes],
  76          [ac_cv_safe_to_use_fdiagnostics_show_option_=no])
  77        CFLAGS="$save_CFLAGS"])
  78
  79     AS_IF([test "$ac_cv_safe_to_use_fdiagnostics_show_option_" = "yes"],
  80           [
  81             F_DIAGNOSTICS_SHOW_OPTION="-fdiagnostics-show-option"
  82           ])
  83
  84     AC_CACHE_CHECK([whether it is safe to use -Wconversion],
  85       [ac_cv_safe_to_use_wconversion_],
  86       [save_CFLAGS="$CFLAGS"
  87        dnl Use -Werror here instead of ${W_FAIL} so that we don't spew
  88        dnl conversion warnings to all the tarball folks
  89        CFLAGS="-Wconversion -Werror -pedantic ${AM_CFLAGS} ${CFLAGS}"
  90        AC_COMPILE_IFELSE(
  91          [AC_LANG_PROGRAM([[
  92 #include <stdbool.h>
  93 void foo(bool a)
  94 {
  95   (void)a;
  96 }
  97          ]],[[
  98 foo(0);
  99          ]])],
 100          [ac_cv_safe_to_use_wconversion_=yes],
 101          [ac_cv_safe_to_use_wconversion_=no])
 102        CFLAGS="$save_CFLAGS"])
 103
 104     AS_IF([test "$ac_cv_safe_to_use_wconversion_" = "yes"],
 105       [W_CONVERSION="-Wconversion"
 106       AC_CACHE_CHECK([whether it is safe to use -Wconversion with htons],
 107         [ac_cv_safe_to_use_Wconversion_],
 108         [save_CFLAGS="$CFLAGS"
 109          dnl Use -Werror here instead of ${W_FAIL} so that we don't spew
 110          dnl conversion warnings to all the tarball folks
 111          CFLAGS="-Wconversion -Werror -pedantic ${AM_CFLAGS} ${CFLAGS}"
 112          AC_COMPILE_IFELSE(
 113            [AC_LANG_PROGRAM(
 114              [[
 115 #include <netinet/in.h>
 116              ]],[[
 117 uint16_t x= htons(80);
 118              ]])],
 119            [ac_cv_safe_to_use_Wconversion_=yes],
 120            [ac_cv_safe_to_use_Wconversion_=no])
 121          CFLAGS="$save_CFLAGS"])
 122
 123       AS_IF([test "$ac_cv_safe_to_use_Wconversion_" = "no"],
 124             [NO_CONVERSION="-Wno-conversion"])
 125     ])
 126
 127     NO_STRICT_ALIASING="-fno-strict-aliasing -Wno-strict-aliasing"
 128     NO_SHADOW="-Wno-shadow"
 129
 130     m4_if(PW_LESS_WARNINGS,[no],[
 131       BASE_WARNINGS_FULL="-Wformat=2 ${W_CONVERSION} -Wstrict-aliasing"
 132       CC_WARNINGS_FULL="-Wswitch-default -Wswitch-enum -Wwrite-strings"
 133       CXX_WARNINGS_FULL="-Weffc++ -Wold-style-cast"
 134     ],[
 135       BASE_WARNINGS_FULL="-Wformat ${NO_STRICT_ALIASING}"
 136     ])
 137
 138     AS_IF([test "${ac_cv_assert}" = "no"],
 139           [NO_UNUSED="-Wno-unused-variable -Wno-unused-parameter"])
 140
 141     BASE_WARNINGS="${W_FAIL} -pedantic -Wall -Wextra -Wundef -Wshadow ${NO_UNUSED} ${F_DIAGNOSTICS_SHOW_OPTION} ${CFLAG_VISIBILITY} ${BASE_WARNINGS_FULL}"
 142     CC_WARNINGS="${BASE_WARNINGS} -Wstrict-prototypes -Wmissing-prototypes -Wredundant-decls -Wmissing-declarations -Wcast-align ${CC_WARNINGS_FULL}"
 143     CXX_WARNINGS="${BASE_WARNINGS} -Woverloaded-virtual -Wnon-virtual-dtor -Wctor-dtor-privacy -Wno-long-long ${CXX_WARNINGS_FULL}"
 144
 145     AC_CACHE_CHECK([whether it is safe to use -Wmissing-declarations from C++],
 146       [ac_cv_safe_to_use_Wmissing_declarations_],
 147       [AC_LANG_PUSH(C++)
 148        save_CXXFLAGS="$CXXFLAGS"
 149        CXXFLAGS="-Werror -pedantic -Wmissing-declarations ${AM_CXXFLAGS}"
 150        AC_COMPILE_IFELSE([
 151          AC_LANG_PROGRAM(
 152          [[
 153 #include <stdio.h>
 154          ]], [[]])
 155       ],
 156       [ac_cv_safe_to_use_Wmissing_declarations_=yes],
 157       [ac_cv_safe_to_use_Wmissing_declarations_=no])
 158       CXXFLAGS="$save_CXXFLAGS"
 159       AC_LANG_POP()
 160     ])
 161     AS_IF([test "$ac_cv_safe_to_use_Wmissing_declarations_" = "yes"],
 162           [CXX_WARNINGS="${CXX_WARNINGS} -Wmissing-declarations"])
 163
 164     AC_CACHE_CHECK([whether it is safe to use -Wlogical-op],
 165       [ac_cv_safe_to_use_Wlogical_op_],
 166       [save_CFLAGS="$CFLAGS"
 167        CFLAGS="${W_FAIL} -pedantic -Wlogical-op ${AM_CFLAGS} ${CFLAGS}"
 168        AC_COMPILE_IFELSE([
 169          AC_LANG_PROGRAM(
 170          [[
 171 #include <stdio.h>
 172          ]], [[]])
 173       ],
 174       [ac_cv_safe_to_use_Wlogical_op_=yes],
 175       [ac_cv_safe_to_use_Wlogical_op_=no])
 176     CFLAGS="$save_CFLAGS"])
 177     AS_IF([test "$ac_cv_safe_to_use_Wlogical_op_" = "yes"],
 178           [CC_WARNINGS="${CC_WARNINGS} -Wlogical-op"])
 179
 180     AC_CACHE_CHECK([whether it is safe to use -Wredundant-decls from C++],
 181       [ac_cv_safe_to_use_Wredundant_decls_],
 182       [AC_LANG_PUSH(C++)
 183        save_CXXFLAGS="${CXXFLAGS}"
 184        CXXFLAGS="${W_FAIL} -pedantic -Wredundant-decls ${AM_CXXFLAGS}"
 185        AC_COMPILE_IFELSE(
 186          [AC_LANG_PROGRAM([
 187 template <typename E> struct C { void foo(); };
 188 template <typename E> void C<E>::foo() { }
 189 template <> void C<int>::foo();
 190           AC_INCLUDES_DEFAULT])],
 191           [ac_cv_safe_to_use_Wredundant_decls_=yes],
 192           [ac_cv_safe_to_use_Wredundant_decls_=no])
 193         CXXFLAGS="${save_CXXFLAGS}"
 194         AC_LANG_POP()])
 195     AS_IF([test "$ac_cv_safe_to_use_Wredundant_decls_" = "yes"],
 196           [CXX_WARNINGS="${CXX_WARNINGS} -Wredundant-decls"],
 197           [CXX_WARNINGS="${CXX_WARNINGS} -Wno-redundant-decls"])
 198
 199     NO_REDUNDANT_DECLS="-Wno-redundant-decls"
 200     PROTOSKIP_WARNINGS="-Wno-effc++ -Wno-shadow"
 201
 202   ])
 203
 204   AS_IF([test "$SUNCC" = "yes"],[
 205
 206     AS_IF([test "$ac_profiling" = "yes"],
 207           [CC_PROFILING="-xinstrument=datarace"])
 208
 209     AS_IF([test "$ac_cv_warnings_as_errors" = "yes"],
 210           [W_FAIL="-errwarn=%all"])
 211
 212     AC_CACHE_CHECK([whether E_PASTE_RESULT_NOT_TOKEN is usable],
 213       [ac_cv_paste_result],
 214       [
 215         save_CFLAGS="${CFLAGS}"
 216         CFLAGS="-errwarn=%all -erroff=E_PASTE_RESULT_NOT_TOKEN ${CFLAGS}"
 217         AC_COMPILE_IFELSE(
 218           [AC_LANG_PROGRAM([
 219             AC_INCLUDES_DEFAULT
 220           ],[
 221             int x= 0;])],
 222           [ac_cv_paste_result=yes],
 223           [ac_cv_paste_result=no])
 224         CFLAGS="${save_CFLAGS}"
 225       ])
 226     AS_IF([test $ac_cv_paste_result = yes],
 227       [W_PASTE_RESULT=",E_PASTE_RESULT_NOT_TOKEN"])
 228
 229
 230     m4_if(PW_LESS_WARNINGS, [no],[
 231       CC_WARNINGS_FULL="-erroff=E_INTEGER_OVERFLOW_DETECTED${W_PASTE_RESULT}"
 232     ],[
 233       CC_WARNINGS_FULL="-erroff=E_ATTRIBUTE_NOT_VAR"
 234       CXX_WARNINGS_FULL="-erroff=attrskipunsup,doubunder,reftotemp,inllargeuse,truncwarn1,signextwarn,inllargeint"
 235     ])
 236
 237     CC_WARNINGS="-v -errtags=yes ${W_FAIL} ${CC_WARNINGS_FULL}"
 238     CXX_WARNINGS="+w +w2 -xwe -xport64 -errtags=yes ${CXX_WARNINGS_FULL} ${W_FAIL}"
 239     PROTOSKIP_WARNINGS="-erroff=attrskipunsup,doubunder,reftotemp,wbadinitl,identexpected,inllargeuse,truncwarn1,signextwarn"
 240     NO_UNREACHED="-erroff=E_STATEMENT_NOT_REACHED"
 241
 242   ])
 243
 244   AC_SUBST(NO_CONVERSION)
 245   AC_SUBST(NO_REDUNDANT_DECLS)
 246   AC_SUBST(NO_UNREACHED)
 247   AC_SUBST(NO_SHADOW)
 248   AC_SUBST(NO_STRICT_ALIASING)
 249   AC_SUBST(PROTOSKIP_WARNINGS)
 250
 251 ])