git.m6w6.name Git - awesomized/libmemcached/blob - m4/pandora_warnings.m4

   1 dnl  Copyright (C) 2009 Sun Microsystems
   2 dnl This file is free software; Sun Microsystems
   3 dnl gives unlimited permission to copy and/or distribute it,
   4 dnl with or without modifications, as long as this notice is preserved.
   5
   6 dnl AC_PANDORA_WARNINGS([less-warnings|warnings-always-on])
   7 dnl   less-warnings turn on a limited set of warnings
   8 dnl   warnings-always-on always set warnings=error regardless of tarball/vc
   9
  10 dnl @TODO: remove less-warnings option as soon as Drizzle is clean enough to
  11 dnl        allow it
  12
  13 AC_DEFUN([PANDORA_WARNINGS],[
  14   m4_define([PW_LESS_WARNINGS],[no])
  15   m4_define([PW_WARN_ALWAYS_ON],[no])
  16   ifdef([m4_define],,[define([m4_define],   defn([define]))])
  17   ifdef([m4_undefine],,[define([m4_undefine],   defn([undefine]))])
  18   m4_foreach([pw_arg],[$*],[
  19     m4_case(pw_arg,
  20       [less-warnings],[
  21         m4_undefine([PW_LESS_WARNINGS])
  22         m4_define([PW_LESS_WARNINGS],[yes])
  23       ],
  24       [warnings-always-on],[
  25         m4_undefine([PW_WARN_ALWAYS_ON])
  26         m4_define([PW_WARN_ALWAYS_ON],[yes])
  27     ])
  28   ])
  29
  30   AC_REQUIRE([PANDORA_BUILDING_FROM_VC])
  31   m4_if(PW_WARN_ALWAYS_ON, [yes],
  32     [ac_cv_warnings_as_errors=yes],
  33     AS_IF([test "$ac_cv_building_from_vc" = "yes"],
  34           [ac_cv_warnings_as_errors=yes],
  35           [ac_cv_warnings_as_errors=no]))
  36
  37   AC_ARG_ENABLE([profiling],
  38       [AS_HELP_STRING([--enable-profiling],
  39          [Toggle profiling @<:@default=off@:>@])],
  40       [ac_profiling="$enableval"],
  41       [ac_profiling="no"])
  42
  43   AC_ARG_ENABLE([coverage],
  44       [AS_HELP_STRING([--enable-coverage],
  45          [Toggle coverage @<:@default=off@:>@])],
  46       [ac_coverage="$enableval"],
  47       [ac_coverage="no"])
  48
  49   AS_IF([test "$GCC" = "yes"],[
  50
  51     AS_IF([test "$ac_profiling" = "yes"],[
  52       CC_PROFILING="-pg"
  53       save_LIBS="${LIBS}"
  54       LIBS=""
  55       AC_CHECK_LIB(c_p, read)
  56       LIBC_P="${LIBS}"
  57       LIBS="${save_LIBS}"
  58       AC_SUBST(LIBC_P)
  59     ],[
  60       CC_PROFILING=" "
  61     ])
  62
  63     AS_IF([test "$ac_coverage" = "yes"],
  64           [CC_COVERAGE="-fprofile-arcs -ftest-coverage"])
  65
  66     AS_IF([test "$ac_cv_warnings_as_errors" = "yes"],
  67           [W_FAIL="-Werror"])
  68
  69     AC_CACHE_CHECK([whether it is safe to use -fdiagnostics-show-option],
  70       [ac_cv_safe_to_use_fdiagnostics_show_option_],
  71       [save_CFLAGS="$CFLAGS"
  72        CFLAGS="-fdiagnostics-show-option ${AM_CFLAGS} ${CFLAGS}"
  73        AC_COMPILE_IFELSE(
  74          [AC_LANG_PROGRAM([],[])],
  75          [ac_cv_safe_to_use_fdiagnostics_show_option_=yes],
  76          [ac_cv_safe_to_use_fdiagnostics_show_option_=no])
  77        CFLAGS="$save_CFLAGS"])
  78
  79     AS_IF([test "$ac_cv_safe_to_use_fdiagnostics_show_option_" = "yes"],
  80           [
  81             F_DIAGNOSTICS_SHOW_OPTION="-fdiagnostics-show-option"
  82           ])
  83
  84     AC_CACHE_CHECK([whether it is safe to use -Wconversion],
  85       [ac_cv_safe_to_use_wconversion_],
  86       [save_CFLAGS="$CFLAGS"
  87        dnl Use -Werror here instead of ${W_FAIL} so that we don't spew
  88        dnl conversion warnings to all the tarball folks
  89        CFLAGS="-Wconversion -Werror -pedantic ${AM_CFLAGS} ${CFLAGS}"
  90        AC_COMPILE_IFELSE(
  91          [AC_LANG_PROGRAM([[
  92 #include <stdbool.h>
  93 void foo(bool a)
  94 {
  95   (void)a;
  96 }
  97          ]],[[
  98 foo(0);
  99          ]])],
 100          [ac_cv_safe_to_use_wconversion_=yes],
 101          [ac_cv_safe_to_use_wconversion_=no])
 102        CFLAGS="$save_CFLAGS"])
 103
 104     AS_IF([test "$ac_cv_safe_to_use_wconversion_" = "yes"],
 105       [W_CONVERSION="-Wconversion"
 106       AC_CACHE_CHECK([whether it is safe to use -Wconversion with htons],
 107         [ac_cv_safe_to_use_Wconversion_],
 108         [save_CFLAGS="$CFLAGS"
 109          dnl Use -Werror here instead of ${W_FAIL} so that we don't spew
 110          dnl conversion warnings to all the tarball folks
 111          CFLAGS="-Wconversion -Werror -pedantic ${AM_CFLAGS} ${CFLAGS}"
 112          AC_COMPILE_IFELSE(
 113            [AC_LANG_PROGRAM(
 114              [[
 115 #include <netinet/in.h>
 116              ]],[[
 117 uint16_t x= htons(80);
 118              ]])],
 119            [ac_cv_safe_to_use_Wconversion_=yes],
 120            [ac_cv_safe_to_use_Wconversion_=no])
 121          CFLAGS="$save_CFLAGS"])
 122
 123       AS_IF([test "$ac_cv_safe_to_use_Wconversion_" = "no"],
 124             [NO_CONVERSION="-Wno-conversion"])
 125     ])
 126
 127     NO_STRICT_ALIASING="-fno-strict-aliasing -Wno-strict-aliasing"
 128     NO_SHADOW="-Wno-shadow"
 129
 130     AS_IF([test "$INTELCC" = "yes"],[
 131       m4_if(PW_LESS_WARNINGS,[no],[
 132         BASE_WARNINGS="-w1 -Wall -Werror -Wcheck -Wformat -Wp64 -Woverloaded-virtual -Wcast-qual"
 133       ],[
 134         BASE_WARNINGS="-w1 -Wall -Wcheck -Wformat -Wp64 -Woverloaded-virtual -Wcast-qual -diag-disable 981"
 135       ])
 136       CC_WARNINGS="${BASE_WARNINGS}"
 137       CXX_WARNINGS="${BASE_WARNINGS}"
 138     ],[
 139       m4_if(PW_LESS_WARNINGS,[no],[
 140         BASE_WARNINGS_FULL="-Wformat=2 ${W_CONVERSION} -Wstrict-aliasing"
 141         CC_WARNINGS_FULL="-Wswitch-default -Wswitch-enum -Wwrite-strings"
 142         CXX_WARNINGS_FULL="-Weffc++ -Wold-style-cast"
 143       ],[
 144         BASE_WARNINGS_FULL="-Wformat ${NO_STRICT_ALIASING}"
 145       ])
 146
 147       AS_IF([test "${ac_cv_assert}" = "no"],
 148             [NO_UNUSED="-Wno-unused-variable -Wno-unused-parameter"])
 149
 150       BASE_WARNINGS="${W_FAIL} -pedantic -Wall -Wextra -Wundef -Wshadow ${NO_UNUSED} ${F_DIAGNOSTICS_SHOW_OPTION} ${CFLAG_VISIBILITY} ${BASE_WARNINGS_FULL}"
 151       CC_WARNINGS="${BASE_WARNINGS} -Wstrict-prototypes -Wmissing-prototypes -Wredundant-decls -Wmissing-declarations -Wcast-align ${CC_WARNINGS_FULL}"
 152       CXX_WARNINGS="${BASE_WARNINGS} -Woverloaded-virtual -Wnon-virtual-dtor -Wctor-dtor-privacy -Wno-long-long ${CXX_WARNINGS_FULL}"
 153
 154       AC_CACHE_CHECK([whether it is safe to use -Wmissing-declarations from C++],
 155         [ac_cv_safe_to_use_Wmissing_declarations_],
 156         [AC_LANG_PUSH(C++)
 157          save_CXXFLAGS="$CXXFLAGS"
 158          CXXFLAGS="-Werror -pedantic -Wmissing-declarations ${AM_CXXFLAGS}"
 159          AC_COMPILE_IFELSE([
 160            AC_LANG_PROGRAM(
 161            [[
 162 #include <stdio.h>
 163            ]], [[]])
 164         ],
 165         [ac_cv_safe_to_use_Wmissing_declarations_=yes],
 166         [ac_cv_safe_to_use_Wmissing_declarations_=no])
 167         CXXFLAGS="$save_CXXFLAGS"
 168         AC_LANG_POP()
 169       ])
 170       AS_IF([test "$ac_cv_safe_to_use_Wmissing_declarations_" = "yes"],
 171             [CXX_WARNINGS="${CXX_WARNINGS} -Wmissing-declarations"])
 172
 173       AC_CACHE_CHECK([whether it is safe to use -Wlogical-op],
 174         [ac_cv_safe_to_use_Wlogical_op_],
 175         [save_CFLAGS="$CFLAGS"
 176          CFLAGS="${W_FAIL} -pedantic -Wlogical-op ${AM_CFLAGS} ${CFLAGS}"
 177          AC_COMPILE_IFELSE([
 178            AC_LANG_PROGRAM(
 179            [[
 180 #include <stdio.h>
 181            ]], [[]])
 182         ],
 183         [ac_cv_safe_to_use_Wlogical_op_=yes],
 184         [ac_cv_safe_to_use_Wlogical_op_=no])
 185       CFLAGS="$save_CFLAGS"])
 186       AS_IF([test "$ac_cv_safe_to_use_Wlogical_op_" = "yes"],
 187             [CC_WARNINGS="${CC_WARNINGS} -Wlogical-op"])
 188
 189       AC_CACHE_CHECK([whether it is safe to use -Wredundant-decls from C++],
 190         [ac_cv_safe_to_use_Wredundant_decls_],
 191         [AC_LANG_PUSH(C++)
 192          save_CXXFLAGS="${CXXFLAGS}"
 193          CXXFLAGS="${W_FAIL} -pedantic -Wredundant-decls ${AM_CXXFLAGS}"
 194          AC_COMPILE_IFELSE(
 195            [AC_LANG_PROGRAM([
 196 template <typename E> struct C { void foo(); };
 197 template <typename E> void C<E>::foo() { }
 198 template <> void C<int>::foo();
 199             AC_INCLUDES_DEFAULT])],
 200             [ac_cv_safe_to_use_Wredundant_decls_=yes],
 201             [ac_cv_safe_to_use_Wredundant_decls_=no])
 202           CXXFLAGS="${save_CXXFLAGS}"
 203           AC_LANG_POP()])
 204       AS_IF([test "$ac_cv_safe_to_use_Wredundant_decls_" = "yes"],
 205             [CXX_WARNINGS="${CXX_WARNINGS} -Wredundant-decls"],
 206             [CXX_WARNINGS="${CXX_WARNINGS} -Wno-redundant-decls"])
 207
 208       AC_CACHE_CHECK([whether it is safe to use -Wattributes from C++],
 209         [ac_cv_safe_to_use_Wattributes_],
 210         [AC_LANG_PUSH(C++)
 211          save_CXXFLAGS="${CXXFLAGS}"
 212          CXXFLAGS="${W_FAIL} -pedantic -Wattributes -fvisibility=hidden ${AM_CXXFLAGS}"
 213          AC_COMPILE_IFELSE(
 214            [AC_LANG_PROGRAM([
 215 #include <google/protobuf/message.h>
 216 #include <google/protobuf/descriptor.h>
 217
 218
 219 const ::google::protobuf::EnumDescriptor* Table_TableOptions_RowType_descriptor();
 220 enum Table_TableOptions_RowType {
 221   Table_TableOptions_RowType_ROW_TYPE_DEFAULT = 0,
 222   Table_TableOptions_RowType_ROW_TYPE_FIXED = 1,
 223   Table_TableOptions_RowType_ROW_TYPE_DYNAMIC = 2,
 224   Table_TableOptions_RowType_ROW_TYPE_COMPRESSED = 3,
 225   Table_TableOptions_RowType_ROW_TYPE_REDUNDANT = 4,
 226   Table_TableOptions_RowType_ROW_TYPE_COMPACT = 5,
 227   Table_TableOptions_RowType_ROW_TYPE_PAGE = 6
 228 };
 229
 230 namespace google {
 231 namespace protobuf {
 232 template <>
 233 inline const EnumDescriptor* GetEnumDescriptor<Table_TableOptions_RowType>() {
 234   return Table_TableOptions_RowType_descriptor();
 235 }
 236 }
 237 }
 238             ])],
 239             [ac_cv_safe_to_use_Wattributes_=yes],
 240             [ac_cv_safe_to_use_Wattributes_=no])
 241           CXXFLAGS="${save_CXXFLAGS}"
 242           AC_LANG_POP()])
 243       AS_IF([test "$ac_cv_safe_to_use_Wattributes_" = "yes"],
 244             [],
 245             [CXX_WARNINGS="${CXX_WARNINGS} -Wno-attributes"])
 246
 247       NO_REDUNDANT_DECLS="-Wno-redundant-decls"
 248       dnl TODO: Figure out a better way to deal with this:
 249       PROTOSKIP_WARNINGS="-Wno-effc++ -Wno-shadow -Wno-missing-braces -Wno-attributes"
 250       NO_WERROR="-Wno-error"
 251       INNOBASE_SKIP_WARNINGS="-Wno-shadow -Wno-cast-align"
 252
 253     ])
 254   ])
 255
 256   AS_IF([test "$SUNCC" = "yes"],[
 257
 258     AS_IF([test "$ac_profiling" = "yes"],
 259           [CC_PROFILING="-xinstrument=datarace"])
 260
 261     AS_IF([test "$ac_cv_warnings_as_errors" = "yes"],
 262           [W_FAIL="-errwarn=%all"])
 263
 264     AC_CACHE_CHECK([whether E_PASTE_RESULT_NOT_TOKEN is usable],
 265       [ac_cv_paste_result],
 266       [
 267         save_CFLAGS="${CFLAGS}"
 268         CFLAGS="-errwarn=%all -erroff=E_PASTE_RESULT_NOT_TOKEN ${CFLAGS}"
 269         AC_COMPILE_IFELSE(
 270           [AC_LANG_PROGRAM([
 271             AC_INCLUDES_DEFAULT
 272           ],[
 273             int x= 0;])],
 274           [ac_cv_paste_result=yes],
 275           [ac_cv_paste_result=no])
 276         CFLAGS="${save_CFLAGS}"
 277       ])
 278     AS_IF([test $ac_cv_paste_result = yes],
 279       [W_PASTE_RESULT=",E_PASTE_RESULT_NOT_TOKEN"])
 280
 281
 282     m4_if(PW_LESS_WARNINGS, [no],[
 283       CC_WARNINGS_FULL="-erroff=E_INTEGER_OVERFLOW_DETECTED${W_PASTE_RESULT}"
 284       CXX_WARNINGS_FULL="-erroff=inllargeuse"
 285     ],[
 286       CC_WARNINGS_FULL="-erroff=E_ATTRIBUTE_NOT_VAR"
 287       CXX_WARNINGS_FULL="-erroff=attrskipunsup,doubunder,reftotemp,inllargeuse,truncwarn1,signextwarn,inllargeint"
 288     ])
 289
 290     CC_WARNINGS="-v -errtags=yes ${W_FAIL} ${CC_WARNINGS_FULL}"
 291     CXX_WARNINGS="+w +w2 -xwe -xport64 -errtags=yes ${CXX_WARNINGS_FULL} ${W_FAIL}"
 292     PROTOSKIP_WARNINGS="-erroff=attrskipunsup,doubunder,reftotemp,wbadinitl,identexpected,inllargeuse,truncwarn1,signextwarn,partinit,notused,badargtype2w,wbadinit"
 293     NO_UNREACHED="-erroff=E_STATEMENT_NOT_REACHED"
 294     NO_WERROR="-errwarn=%none"
 295
 296   ])
 297
 298   AC_SUBST(NO_CONVERSION)
 299   AC_SUBST(NO_REDUNDANT_DECLS)
 300   AC_SUBST(NO_UNREACHED)
 301   AC_SUBST(NO_SHADOW)
 302   AC_SUBST(NO_STRICT_ALIASING)
 303   AC_SUBST(PROTOSKIP_WARNINGS)
 304   AC_SUBST(INNOBASE_SKIP_WARNINGS)
 305   AC_SUBST(NO_WERROR)
 306
 307 ])