git.m6w6.name Git - m6w6/libmemcached/blob - m4/pandora_vc_build.m4

   1 dnl  Copyright (C) 2009 Sun Microsystems, Inc.
   2 dnl This file is free software; Sun Microsystems, Inc.
   3 dnl gives unlimited permission to copy and/or distribute it,
   4 dnl with or without modifications, as long as this notice is preserved.
   5
   6 AC_DEFUN([PANDORA_TEST_VC_DIR],[
   7   pandora_building_from_vc=no
   8
   9   if test -d ".bzr" ; then
  10     pandora_building_from_bzr=yes
  11     pandora_building_from_vc=yes
  12   else
  13     pandora_building_from_bzr=no
  14   fi
  15
  16   if test -d ".svn" ; then
  17     pandora_building_from_svn=yes
  18     pandora_building_from_vc=yes
  19   else
  20     pandora_building_from_svn=no
  21   fi
  22
  23   if test -d ".hg" ; then
  24     pandora_building_from_hg=yes
  25     pandora_building_from_vc=yes
  26   else
  27     pandora_building_from_hg=no
  28   fi
  29
  30   if test -d ".git" ; then
  31     pandora_building_from_git=yes
  32     pandora_building_from_vc=yes
  33   else
  34     pandora_building_from_git=no
  35   fi
  36 ])
  37
  38 AC_DEFUN([PANDORA_BUILDING_FROM_VC],[
  39   m4_syscmd(PANDORA_TEST_VC_DIR [
  40
  41     PANDORA_RELEASE_DATE=`date +%Y.%m`
  42     PANDORA_RELEASE_NODOTS_DATE=`date +%Y%m`
  43
  44     # Set some defaults
  45     PANDORA_VC_REVNO="0"
  46     PANDORA_VC_REVID="unknown"
  47     PANDORA_VC_BRANCH="bzr-export"
  48
  49     if test "${pandora_building_from_bzr}" = "yes"; then
  50       echo "# Grabbing changelog and version information from bzr"
  51       PANDORA_BZR_REVNO=`bzr revno`
  52       if test "x$PANDORA_BZR_REVNO" != "x${PANDORA_VC_REVNO}" ; then
  53         PANDORA_VC_REVNO="${PANDORA_BZR_REVNO}"
  54         PANDORA_VC_REVID=`bzr log -r-1 --show-ids | grep revision-id | cut -f2 -d' ' | head -1`
  55         PANDORA_VC_BRANCH=`bzr nick`
  56         if test "x${vcs_changelog}" = "xyes"; then
  57           bzr log --gnu > ChangeLog
  58         fi
  59       fi
  60     fi
  61
  62     if ! test -d config ; then
  63       mkdir -p config
  64     fi
  65
  66     if test "${pandora_building_from_bzr}" = "yes" -o ! -f config/pandora_vc_revinfo ; then
  67       cat > config/pandora_vc_revinfo.tmp <<EOF
  68 PANDORA_VC_REVNO=${PANDORA_VC_REVNO}
  69 PANDORA_VC_REVID=${PANDORA_VC_REVID}
  70 PANDORA_VC_BRANCH=${PANDORA_VC_BRANCH}
  71 PANDORA_RELEASE_DATE=${PANDORA_RELEASE_DATE}
  72 PANDORA_RELEASE_NODOTS_DATE=${PANDORA_RELEASE_NODOTS_DATE}
  73 EOF
  74       if ! diff config/pandora_vc_revinfo.tmp config/pandora_vc_revinfo >/dev/null 2>&1 ; then
  75         mv config/pandora_vc_revinfo.tmp config/pandora_vc_revinfo
  76       fi
  77       rm -f config/pandora_vc_revinfo.tmp
  78     fi
  79   ])
  80 ])
  81
  82 AC_DEFUN([_PANDORA_READ_FROM_FILE],[
  83   $1=`grep $1 $2 | cut -f2 -d=`
  84 ])
  85
  86 AC_DEFUN([PANDORA_VC_VERSION],[
  87   AC_REQUIRE([PANDORA_BUILDING_FROM_VC])
  88
  89   PANDORA_TEST_VC_DIR
  90
  91   AS_IF([test -f ${srcdir}/config/pandora_vc_revinfo],[
  92     _PANDORA_READ_FROM_FILE([PANDORA_VC_REVNO],${srcdir}/config/pandora_vc_revinfo)
  93     _PANDORA_READ_FROM_FILE([PANDORA_VC_REVID],${srcdir}/config/pandora_vc_revinfo)
  94     _PANDORA_READ_FROM_FILE([PANDORA_VC_BRANCH],
  95                             ${srcdir}/config/pandora_vc_revinfo)
  96     _PANDORA_READ_FROM_FILE([PANDORA_RELEASE_DATE],
  97                             ${srcdir}/config/pandora_vc_revinfo)
  98     _PANDORA_READ_FROM_FILE([PANDORA_RELEASE_NODOTS_DATE],
  99                             ${srcdir}/config/pandora_vc_revinfo)
 100   ])
 101   AS_IF([test "x${PANDORA_VC_BRANCH}" != x"${PACKAGE}"],[
 102     PANDORA_RELEASE_COMMENT="${PANDORA_VC_BRANCH}"
 103   ],[
 104     PANDORA_RELEASE_COMMENT="trunk"
 105   ])
 106
 107   PANDORA_RELEASE_VERSION="${PANDORA_RELEASE_DATE}.${PANDORA_VC_REVNO}"
 108   PANDORA_RELEASE_ID="${PANDORA_RELEASE_NODOTS_DATE}${PANDORA_VC_REVNO}"
 109
 110   VERSION="${PANDORA_RELEASE_VERSION}"
 111   AC_DEFINE_UNQUOTED([PANDORA_RELEASE_VERSION],["${PANDORA_RELEASE_VERSION}"],
 112                      [The real version of the software])
 113   AC_SUBST(PANDORA_VC_REVNO)
 114   AC_SUBST(PANDORA_VC_REVID)
 115   AC_SUBST(PANDORA_VC_BRANCH)
 116   AC_SUBST(PANDORA_RELEASE_DATE)
 117   AC_SUBST(PANDORA_RELEASE_NODOTS_DATE)
 118   AC_SUBST(PANDORA_RELEASE_COMMENT)
 119   AC_SUBST(PANDORA_RELEASE_VERSION)
 120   AC_SUBST(PANDORA_RELEASE_ID)
 121 ])
 122
 123 AC_DEFUN([PANDORA_VC_INFO_HEADER],[
 124   AC_REQUIRE([PANDORA_VC_VERSION])
 125   m4_define([PANDORA_VC_PREFIX],m4_toupper(m4_normalize(AC_PACKAGE_NAME))[_])
 126
 127   AC_DEFINE_UNQUOTED(PANDORA_VC_PREFIX[VC_REVNO], [$PANDORA_VC_REVNO], [Version control revision number])
 128   AC_DEFINE_UNQUOTED(PANDORA_VC_PREFIX[VC_REVID], ["$PANDORA_VC_REVID"], [Version control revision ID])
 129   AC_DEFINE_UNQUOTED(PANDORA_VC_PREFIX[VC_BRANCH], ["$PANDORA_VC_BRANCH"], [Version control branch name])
 130   AC_DEFINE_UNQUOTED(PANDORA_VC_PREFIX[RELEASE_DATE], ["$PANDORA_RELEASE_DATE"], [Release date of version control checkout])
 131   AC_DEFINE_UNQUOTED(PANDORA_VC_PREFIX[RELEASE_NODOTS_DATE], [$PANDORA_RELEASE_NODOTS_DATE], [Numeric formatted release date of checkout])
 132   AC_DEFINE_UNQUOTED(PANDORA_VC_PREFIX[RELEASE_COMMENT], ["$PANDORA_RELEASE_COMMENT"], [Set to trunk if the branch is the main $PACKAGE branch])
 133   AC_DEFINE_UNQUOTED(PANDORA_VC_PREFIX[RELEASE_VERSION], ["$PANDORA_RELEASE_VERSION"], [Release date and revision number of checkout])
 134   AC_DEFINE_UNQUOTED(PANDORA_VC_PREFIX[RELEASE_ID], [$PANDORA_RELEASE_ID], [Numeric formatted release date and revision number of checkout])
 135 ])