git.m6w6.name Git - m6w6/libmemcached/blob - m4/pandora_shared_ptr.m4

   1 dnl  Copyright (C) 2009 Sun Microsystems
   2 dnl This file is free software; Sun Microsystems
   3 dnl gives unlimited permission to copy and/or distribute it,
   4 dnl with or without modifications, as long as this notice is preserved.
   5
   6 dnl We check two things: where is the memory include file, and in what
   7 dnl namespace does shared_ptr reside.
   8 dnl We include AC_COMPILE_IFELSE for all the combinations we've seen in the
   9 dnl wild:
  10 dnl
  11 dnl  GCC 4.3: namespace: std::  #include <memory>
  12 dnl  GCC 4.2: namespace: tr1::  #include <tr1/memory>
  13 dnl  GCC 4.2: namespace: boost::  #include <boost/shared_ptr.hpp>
  14 dnl
  15 dnl We define one of HAVE_HAVE_TR1_SHARED_PTR or HAVE_BOOST_SHARED_PTR
  16 dnl depending on location, and SHARED_PTR_NAMESPACE to be the namespace in
  17 dnl which shared_ptr is defined.
  18 dnl
  19
  20 AC_DEFUN([PANDORA_SHARED_PTR],[
  21   AC_REQUIRE([PANDORA_CHECK_CXX_STANDARD])
  22   AC_LANG_PUSH(C++)
  23   AC_CHECK_HEADERS(memory tr1/memory boost/shared_ptr.hpp)
  24   AC_CACHE_CHECK([the location of shared_ptr header file],
  25     [ac_cv_shared_ptr_h],[
  26       for namespace in std tr1 std::tr1 boost
  27       do
  28         AC_COMPILE_IFELSE(
  29           [AC_LANG_PROGRAM([[
  30 #if defined(HAVE_MEMORY)
  31 # include <memory>
  32 #endif
  33 #if defined(HAVE_TR1_MEMORY)
  34 # include <tr1/memory>
  35 #endif
  36 #if defined(HAVE_BOOST_SHARED_PTR_HPP)
  37 # include <boost/shared_ptr.hpp>
  38 #endif
  39 #include <string>
  40
  41 using $namespace::shared_ptr;
  42 using namespace std;
  43             ]],[[
  44 shared_ptr<string> test_ptr(new string("test string"));
  45             ]])],
  46             [
  47               ac_cv_shared_ptr_namespace="${namespace}"
  48               break
  49             ],[ac_cv_shared_ptr_namespace=missing])
  50        done
  51   ])
  52   AC_DEFINE_UNQUOTED([SHARED_PTR_NAMESPACE],
  53                      ${ac_cv_shared_ptr_namespace},
  54                      [The namespace in which SHARED_PTR can be found])
  55   AC_LANG_POP()
  56 ])