git.m6w6.name Git - awesomized/libmemcached/blob - m4/pandora_optimize.m4

   1 dnl  Copyright (C) 2009 Sun Microsystems
   2 dnl This file is free software; Sun Microsystems
   3 dnl gives unlimited permission to copy and/or distribute it,
   4 dnl with or without modifications, as long as this notice is preserved.
   5
   6 AC_DEFUN([PANDORA_OPTIMIZE],[
   7   dnl Build optimized or debug version ?
   8   dnl First check for gcc and g++
   9   AS_IF([test "$GCC" = "yes"],[
  10
  11     dnl The following is required for portable results of floating point
  12     dnl calculations on PowerPC. The same must also be done for IA-64, but
  13     dnl this options is missing in the IA-64 gcc backend.
  14     case "$target_cpu" in
  15       *ppc* | *powerpc*)
  16         AM_CFLAGS="-mno-fused-madd ${AM_CFLAGS}"
  17         AM_CXXFLAGS="-mno-fused-madd ${AM_CXXFLAGS}"
  18       ;;
  19     esac
  20
  21     dnl Once we can use a modern autoconf, we can replace the std=gnu99 here
  22     dnl with using AC_CC_STD_C99 above
  23     CC="${CC} -std=gnu99"
  24
  25     AM_CPPFLAGS="-ggdb3 ${AM_CPPFLAGS}"
  26
  27     DEBUG_CFLAGS="-O0"
  28     DEBUG_CXXFLAGS="-O0"
  29
  30     OPTIMIZE_CFLAGS="-O3"
  31     OPTIMIZE_CXXFLAGS="-O3"
  32   ])
  33   AS_IF([test "$SUNCC" = "yes"],[
  34     dnl Once we can use a modern autoconf, we can replace the -xc99=all here
  35     dnl with using AC_CC_STD_C99 above
  36     CC="${CC} -xc99=all"
  37     CXX="${CXX} -xlang=c99"
  38
  39     AM_CFLAGS="-g -mt -xstrconst -Xa ${AM_CFLAGS}"
  40     AM_CXXFLAGS="-mt -compat=5 -library=stlport4 -template=no%extdef ${AM_CXXFLAGS}"
  41
  42     DEBUG_CXXFLAGS="-g"
  43
  44     dnl TODO: Make a test for -xO4 usability here
  45     OPTIMIZE_FLAGS="-xO3 -xlibmil -xdepend -xbuiltin"
  46     OPTIMIZE_CFLAGS="${OPTIMIZE_FLAGS}"
  47     OPTIMIZE_CXXFLAGS="-g0 ${OPTIMIZE_FLAGS}"
  48
  49   ])
  50
  51   AC_ARG_WITH([debug],
  52     [AS_HELP_STRING([--with-debug],
  53        [Add debug code/turns off optimizations (yes|no) @<:@default=no@:>@])],
  54     [with_debug=$withval],
  55     [with_debug=no])
  56   AS_IF([test "$with_debug" = "yes"],[
  57     # Debugging. No optimization.
  58     AM_CFLAGS="${AM_CFLAGS} ${DEBUG_CFLAGS} -DDEBUG"
  59     AM_CXXFLAGS="${AM_CXXFLAGS} ${DEBUG_CXXFLAGS} -DDEBUG"
  60   ],[
  61     # Optimized version. No debug
  62     AM_CFLAGS="${AM_CFLAGS} ${OPTIMIZE_CFLAGS}"
  63     AM_CXXFLAGS="${AM_CXXFLAGS} ${OPTIMIZE_CXXFLAGS}"
  64   ])
  65 ])