git.m6w6.name Git - awesomized/libmemcached/blob - m4/pandora_have_libgtest.m4

   1 dnl Copyright (C) 2010 Monty Taylor
   2 dnl This file is free software; Monty Taylor
   3 dnl gives unlimited permission to copy and/or distribute it,
   4 dnl with or without modifications, as long as this notice is preserved.
   5
   6 AC_DEFUN([_PANDORA_SEARCH_LIBGTEST],[
   7   AC_REQUIRE([AC_LIB_PREFIX])
   8
   9   dnl --------------------------------------------------------------------
  10   dnl  Check for libgtest
  11   dnl --------------------------------------------------------------------
  12
  13   AC_ARG_ENABLE([libgtest],
  14     [AS_HELP_STRING([--disable-libgtest],
  15       [Build with libgtest support @<:@default=on@:>@])],
  16     [ac_enable_libgtest="$enableval"],
  17     [ac_enable_libgtest="yes"])
  18
  19   AS_IF([test "x$ac_enable_libgtest" = "xyes"],[
  20     AC_LANG_PUSH(C++)
  21     save_CXXFLAGS="${CXXFLAGS}"
  22     CXXFLAGS="${AM_CXXFLAGS} ${CXXFLAGS}"
  23     AC_LIB_HAVE_LINKFLAGS(gtest,,[
  24       #include <gtest/gtest.h>
  25 TEST(pandora_test_libgtest, PandoraTest)
  26 {
  27   ASSERT_EQ(1, 1);
  28 }
  29     ],[])
  30     CXXFLAGS="${save_CXXFLAGS}"
  31     AC_LANG_POP()
  32   ],[
  33     ac_cv_libgtest="no"
  34   ])
  35
  36   AM_CONDITIONAL(HAVE_LIBGTEST, [test "x${ac_cv_libgtest}" = "xyes"])
  37 ])
  38
  39 AC_DEFUN([PANDORA_HAVE_LIBGTEST],[
  40   AC_REQUIRE([_PANDORA_SEARCH_LIBGTEST])
  41 ])
  42
  43 AC_DEFUN([PANDORA_REQUIRE_LIBGTEST],[
  44   AC_REQUIRE([_PANDORA_SEARCH_LIBGTEST])
  45   AS_IF([test "x${ac_cv_libgtest}" = "xno"],
  46     AC_MSG_ERROR([libgtest is required for ${PACKAGE}]))
  47 ])