git.m6w6.name Git - awesomized/libmemcached/blob - m4/pandora_have_libdrizzle.m4

   1 dnl  Copyright (C) 2009 Sun Microsystems, Inc.
   2 dnl This file is free software; Sun Microsystems, Inc.
   3 dnl gives unlimited permission to copy and/or distribute it,
   4 dnl with or without modifications, as long as this notice is preserved.
   5
   6 AC_DEFUN([_PANDORA_SEARCH_LIBDRIZZLE],[
   7   AC_REQUIRE([AC_LIB_PREFIX])
   8
   9   dnl --------------------------------------------------------------------
  10   dnl  Check for libdrizzle
  11   dnl --------------------------------------------------------------------
  12
  13   AC_ARG_ENABLE([libdrizzle],
  14     [AS_HELP_STRING([--disable-libdrizzle],
  15       [Build with libdrizzle support @<:@default=on@:>@])],
  16     [ac_enable_libdrizzle="$enableval"],
  17     [ac_enable_libdrizzle="yes"])
  18
  19   AS_IF([test "x$ac_enable_libdrizzle" = "xyes"],[
  20     AC_LIB_HAVE_LINKFLAGS(drizzle,,[
  21       #include <libdrizzle/drizzle_client.h>
  22     ],[
  23       drizzle_st drizzle;
  24       drizzle_version();
  25     ])
  26   ],[
  27     ac_cv_libdrizzle="no"
  28   ])
  29
  30   AM_CONDITIONAL(HAVE_LIBDRIZZLE, [test "x${ac_cv_libdrizzle}" = "xyes"])
  31 ])
  32
  33 AC_DEFUN([PANDORA_HAVE_LIBDRIZZLE],[
  34   AC_REQUIRE([_PANDORA_SEARCH_LIBDRIZZLE])
  35 ])
  36
  37 AC_DEFUN([PANDORA_REQUIRE_LIBDRIZZLE],[
  38   AC_REQUIRE([PANDORA_HAVE_LIBDRIZZLE])
  39   AS_IF([test "x${ac_cv_libdrizzle}" = "xno"],[
  40     AC_MSG_ERROR([libdrizzle is required for ${PACKAGE}])
  41   ],[
  42     dnl We need at least 0.8 on Solaris non-sparc
  43     AS_IF([test "$target_cpu" != "sparc" -a "x${TARGET_SOLARIS}" = "xtrue"],[
  44       PANDORA_LIBDRIZZLE_RECENT
  45     ])
  46   ])
  47 ])
  48
  49 AC_DEFUN([PANDORA_LIBDRIZZLE_RECENT],[
  50   AC_CACHE_CHECK([if libdrizzle is recent enough],
  51     [pandora_cv_libdrizzle_recent],
  52     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  53 #include <libdrizzle/drizzle.h>
  54 drizzle_con_options_t foo= DRIZZLE_CON_EXPERIMENTAL;
  55     ]])],
  56     [pandora_cv_libdrizzle_recent=yes],
  57     [pandora_cv_libdrizzle_recent=no])])
  58   AS_IF([test "$pandora_cv_libdrizzle_recent" = "no"],[
  59     AC_MSG_ERROR([Your version of libdrizzle is too old. ${PACKAGE} requires at least version 0.8])
  60   ])
  61 ])