git.m6w6.name Git - awesomized/libmemcached/blob - m4/pandora_have_libboost_thread.m4

   1 dnl Copyright (C) 2010 Monty Taylor
   2 dnl This file is free software; Monty Taylor
   3 dnl gives unlimited permission to copy and/or distribute it,
   4 dnl with or without modifications, as long as this notice is preserved.
   5
   6 AC_DEFUN([_PANDORA_SEARCH_BOOST_THREAD],[
   7   AC_REQUIRE([AC_LIB_PREFIX])
   8   AC_REQUIRE([ACX_PTHREAD])
   9
  10   dnl --------------------------------------------------------------------
  11   dnl  Check for boost::thread
  12   dnl --------------------------------------------------------------------
  13
  14   save_CFLAGS="${CFLAGS}"
  15   save_CXXFLAGS="${CXXFLAGS}"
  16   CFLAGS="${PTHREAD_CFLAGS} ${CFLAGS}"
  17   CXXFLAGS="${PTHREAD_CFLAGS} ${CXXFLAGS}"
  18
  19   AC_LANG_PUSH(C++)
  20   AC_LIB_HAVE_LINKFLAGS(boost_thread-mt,,[
  21     #include <boost/thread.hpp>
  22   ],[
  23     boost::thread id;
  24   ])
  25   AS_IF([test "x${ac_cv_libboost_thread_mt}" = "xno"],[
  26     AC_LIB_HAVE_LINKFLAGS(boost_thread,,[
  27       #include <boost/thread.hpp>
  28     ],[
  29       boost::thread id;
  30     ])
  31   ])
  32   AC_LANG_POP()
  33   CFLAGS="${save_CFLAGS}"
  34   CXXFLAGS="${save_CXXFLAGS}"
  35
  36
  37   AM_CONDITIONAL(HAVE_BOOST_THREAD,
  38     [test "x${ac_cv_libboost_thread}" = "xyes" -o "x${ac_cv_libboost_thread_mt}" = "xyes"])
  39   BOOST_LIBS="${BOOST_LIBS} ${LTLIBBOOST_THREAD_MT} ${LTLIBBOOST_THREAD}"
  40   AC_SUBST(BOOST_LIBS)
  41 ])
  42
  43 AC_DEFUN([PANDORA_HAVE_BOOST_THREAD],[
  44   PANDORA_HAVE_BOOST($1)
  45   _PANDORA_SEARCH_BOOST_THREAD($1)
  46 ])
  47
  48 AC_DEFUN([PANDORA_REQUIRE_BOOST_THREAD],[
  49   PANDORA_REQUIRE_BOOST($1)
  50   _PANDORA_SEARCH_BOOST_THREAD($1)
  51   AS_IF([test "x${ac_cv_libboost_thread}" = "xno" -a "x${ac_cv_libboost_thread_mt}" = "xno"],
  52       AC_MSG_ERROR([boost::thread is required for ${PACKAGE}]))
  53 ])
  54